How to get a file only? - vb6

Question

How to get a file name only from file's full path?
MY path - C:\Documents and Settings\Arshad\My Documents\ravi.txt

Answer 1

Have a look at this: Retrieve Filename without Path or Extension.
Here's the function from the above link:
Public Function GetFileName(flname As String) As String
'Get the filename without the path or extension.
'Input Values:
' flname - path and filename of file.
'Return Value:
' GetFileName - name of file without the extension.
Dim posn As Integer, i As Integer
Dim fName As String
posn = 0
'find the position of the last "\" character in filename
For i = 1 To Len(flname)
If (Mid(flname, i, 1) = "\") Then posn = i
Next i
'get filename without path
fName = Right(flname, Len(flname) - posn)
'get filename without extension
posn = InStr(fName, ".")
If posn <> 0 Then
fName = Left(fName, posn - 1)
End If
GetFileName = fName
End Function
When inputting
C:\Documents and Settings\Arshad\My Documents\ravi.txt
this function returns
ravi
The function is called as such:
Dim FileName As String
FileName = GetFileName("C:\Documents and Settings\Arshad\My Documents\ravi.txt")

Answer 2

This is the shortest way:
Public Function GetFileName(FilePath As String) As String
Dim l() as string
l=split(FilePath,"\")
GetFileName=l(UBound(l))
End Function
Tell me, if you can find shorter code;)

Answer 3

Here you go:
http://www.vbforums.com/showthread.php?t=475667

Answer 4

-
Here are the better and short way.
Return file name from FullPath
' ** C:\Windows\System32\calc.exe > Ret: calc.exe
Private Function GetFilenameFromPath(FullPath As String) As String
GetFilenameFromPath = Right(FullPath, Len(FullPath) - InStrRev(FullPath, "\"))
End Function
Return Path from FullPath
' C:\Windows\System32\calc.exe > Ret: C:\Windows\System32\
Private Function GetDirectoryFromPath(FullPath As String) As String
GetDirectoryFromPath = Left(FullPath, InStrRev(FullPath, "\"))
End Function