Get Source of Current Tab in Google Chrome via Applescript - macos

Question

It's child's play to do this in Safari, which has good Applescript support. Google Chrome's AS support has just arrived so I'm giving them the benefit of the doubt. I am basically trying to grab the current HTML via the clipboard so I can get information out. We have some nifty commands like this:
tell application "Google Chrome"
view source of active tab of window 1
save active tab of window 1
print active tab of window 1
reload active tab of window 1
go back active tab of window 1
go forward active tab of window 1
copy selection of active tab of window 1
paste selection active tab of window 1
end tell
but alas you can't say "set X to source of active tab of window 1". Anyone have any suggestions for me? My current ideas are to load the code I need in the background in Safari (pretty ugly) or try to display source and grab it with UI script, but that's also ugly. Also I keep encountering scripting bugs that keep it from working.
Any help would be appreciated.

Answer 1

Since google chrome supports Javascript
--Applescript code
tell active tab of window 1
set sourcehtml to execute javascript
document.getElementsByTagName('html')[0].innerHTML
end tell

Answer 2

Chrome's AppleScript library can execute JavaScript.
This will assign the full source of the page to source and return it
tell application "Google Chrome"
set source to execute front window's active tab javascript "document.documentElement.outerHTML"
end tell

Answer 3

I'm very excited to learn that Chrome has AppleScript support now. It's unfortunate that it's minimal as yet, but I'm sure (I hope!) it'll get better. Since there's no way to get the source directly, I'd choose the following hackish route:
tell application "Google Chrome"
view source of active tab of window 1 -- Or whichever tab you want
delay 3
repeat while loading of active tab of window 1
delay 3
end repeat
select all of active tab of window 1 -- Must *always* be the active tab
copy selection of active tab of window 1
delete tab (active tab index of window 1) of window 1
end tell
delay 1
return the clipboard
Yes, it's hackish, but that's unavoidable, given the current state of the scripting dictionary. The script should be straightforward: open a source tab, wait for it to load, select the contents, copy it, and close the tab. You can play with the delay 3s to see what works best. Note that the first active tab of window 1 is arbitrary, the rest explicitly refer to the source tab. Also, apparently there's no way to close a tab from within Chrome's scripting dictionary (oy vey), so I had to use JavaScript instead. Also, the last delay 1 shouldn't be necessary, but if it wasn't there, my tests would sometimes return the wrong thing, even though the clipboard contents were correct when I pasted them in. I think it's because there was enough text that it took a noticeable amount of time to update the clipboard.
Edit 1: I replaced execute the active tab of window 1 javascript "window.close()" with the delete tab line, as was suggested to me. Unfortunately, delete tab active tab of window 1 doesn't work, so you need this slightly more convoluted construction.

Answer 4

-- This script copies the HTML of a tab to a TextEdit document.
tell application "Chromium"
tell tab 1 of window 1 to view source
repeat while (loading of tab 2 of window 1)
end repeat
tell tab 2 of window 1 to select all
tell tab 2 of window 1 to copy selection
end tell
tell application "TextEdit"
set text of document 1 to the clipboard
end tell
Explanation: The script is put in a tight loop waiting for the tab to load, Then just copies the HTML to clipboard.
tell application "Google Chrome"
set t to active tab index of window 1
tell active tab of window 1 to view source
set t to t + 1
repeat while (loading of tab t of window 1)
end repeat
tell tab t of window 1 to select all
tell tab t of window 1 to copy selection
delete tab t of window 1
end tell
EDIT1: the above script should do exaclt what you want

Answer 5

The simple answer is:
set sourcehtml to execute javascript "document.getElementsByTagName('html')[0].innerHTML"
Seems, other posts are really close but still no clear/working solution. The code working to me:
tell application "Google Chrome"
activate
tell active tab of window 1
set sourcehtml to execute javascript "document.getElementsByTagName('html')[0].innerHTML"
return sourcehtml
end tell
end tell

Answer 6

Seeing as how Chrome's AS support has "just arrived" it is bound to be "exciting" to use. In trying some of the commands they have available in their dictionary, it looks as though they still have some kinks to work out. Until Google exposes a way in the API to get the source code more easily (and/or works out the related kinks), you'll have to use one of the alternatives you mention in your post.