XQUERY: Finding number of occurences from one query in another - xpath

Question

I know there should be a simple solution to this but I can't seem to figure it out. Suppose I have a query which returns something like:
xs:untypedAtomic("A"),
xs:untypedAtomic("B"),
xs:untypedAtomic("C")
and I have another one which returns something like:
xs:untypedAtomic("B"),
xs:untypedAtomic("B"),
xs:untypedAtomic("B"),
xs:untypedAtomic("A"),
xs:untypedAtomic("C"),
xs:untypedAtomic("A")
How do I get the number of occurences for each letter in the second table?

Answer 1

Use:
for $s in $vMySeq
return
($s, count(index-of($vSeq, $s)))
where $vMySeq is the result of the first query and $vSeq is the result of the second query.
A complete example:
let $vMySeq := ('A', 'B', 'C'),
$vSeq := ('B', 'B', 'B', 'A', 'C', 'A')
return
for $s in $vMySeq
return
($s, count(index-of($vSeq, $s)))
The result is:
A 2 B 3 C 1

Answer 2

I propose two variants, one containing a group by clause, that happens to show the wanted characteristics for the non-grouping variable $cntr (see http://www.w3.org/TR/xquery-30/#id-group-by for details on how grouping is performed):
let $seq := ("B", "B","B","A","C","A")
let $cntr := 1
for $it in $seq
group by $it
return <el>{
attribute num {count($cntr)},
$it
}</el>
My second, maybe more obvious, variant would be:
let $seq := ("B", "B","B","A","C","A")
for $v in distinct-values($seq)
return <el>{
attribute num {count($seq[. = $v])},
$v
}</el>
As my answer has been a little imprecise, here comes a minor correction inspired by Dimitre Novatchev answer.
Instead of using:
for $v in distinct-values($seq)
you may as well use
for $v in ("A", "B", "C") (: this is sequence 1 as stated in the question:)
which more closely resembles the questions two sequences, given that this very sequence contains distinct values only.