Best way to add items to a list in VBScript? - vbscript

Question

Essentially, I want to get the names of all .zip files in a given directory and unzip them. Right now, I'm working on just getting the names of the files into some sort of array or list. It's grabbing the files correctly, but I don't know a whole lot about VBScript, could someone point me in the right direction?
Dim fileList
Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\Test"
Set objFolder = objFSO.GetFolder(objStartFolder)
Wscript.Echo objFolder.Path
Set colFiles = objFolder.Files
For Each objFile in colFiles
If UCase(objFSO.GetExtensionName(objFile.name)) = "ZIP" Then
Wscript.Echo objFile.Name
'Add file names to fileList variable
End If
Next

Answer 1

There is...
' using vbArray
ReDim fileArray(-1)
Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\Test"
Set objFolder = objFSO.GetFolder(objStartFolder)
For Each objFile In objFolder.Files
If UCase(objFSO.GetExtensionName(objFile.Name)) = "ZIP" Then
ReDim Preserve fileArray(UBound(fileArray) + 1)
fileArray(UBound(fileArray)) = objFile.Name
End If
Next
WScript.Echo Join(fileArray, vbNewLine)
' using .NET ArrayList (as no biult-in Lists in VBScript)
Dim fileList
Set fileList = CreateObject("System.Collections.ArrayList")
For Each objFile In objFolder.Files
If UCase(objFSO.GetExtensionName(objFile.Name)) = "ZIP" Then
fileList.Add objFile.Name
End If
Next
WScript.Echo Join(fileList.ToArray, vbNewLine)
P.P.S:
Is Files collection dynamic:
Set oFSO = CreateObject("Scripting.FileSystemObject")
curDir = CreateObject("WScript.Shell").CurrentDirectory
Set oFolder = oFSO.GetFolder(curDir)
Set oFiles = oFolder.Files
WScript.Echo "Files count: " & oFiles.Count
Set oFile = oFSO.CreateTextFile(oFSO.GetTempName)
oFile.Close
WScript.Echo "Files count: " & oFiles.Count
[EDIT] But looks like then iterate VBS use snapshot of Files collection, so we can presume that unzip may go safety without need of file list.

Answer 2

As you have the files in a collection already (colFiles), the first reason to have a collection of items - process them in turn - does not make you put them in a second list. Why not just unzip each file instead of putting it in a list? To unzip a file A you don't need info about/access to the other files X in the folder. So the second reason for a collection - needing all elements at the same time/when processing one item - doesn't apply either.
If you insist on a second list, all depends on what you want to do with it/the items. If you just want a list of names, the easiest way would be to put the names/pathes as keys in a Dictionary. If you want the names sorted, a System.Collections.ArrayList/SortedList will be more convenient. If you want to work with more properties/attributes of the files - size, dates, access rights, ... - a Disconnected ADODB Recordset will allow you to store all those properties in a (SQL) Table.
Last, but not least, a simple native VBScript Array (dimensioned for the attributes for each file) could be used: As you know the possible number of elements (colFiles.Count), you can define the size of the array before the loop, assign the items in the loop, and ReDim Preserve it after looping.
Take your pick, and I'll add sample code to this posting.
P.S.:
As #Panayot gave you sample code for Arrays and ArrayLists, it would make sense to ask for an ADO Recordset.
P.P.S:
For worriers:
Dim oFS : Set oFS = CreateObject( "Scripting.FileSystemObject" )
Dim sDir : sDir = "..\testdata\testFilesCollection"
Dim nFile, sFile, oFile, i
If oFS.FolderExists( sDir ) Then oFS.DeleteFolder sDir
oFS.CreateFolder sDir
WScript.Echo "----- Creating", cnMax, "files"
For nFile = 1 To cnMax
sFile = nFile & ".txt"
oFS.CreateTextFile oFS.BuildPath( sDir, sFile )
WScript.Echo sFile, "created"
Next
WScript.Echo "----- Looping over", cnMax, "files and creating", cnMax, "more"
i = 0
For Each oFile In oFS.GetFolder( sDir ).Files
If i <= cnMax Then
sFile = Chr(65 + i) & ".txt"
oFS.CreateTextFile oFS.BuildPath( sDir, sFile )
End If
i = i + 1
WScript.Echo oFile.Name, "seen", sFile, "created"
Next
WScript.Echo "----- Looping over", 2 * cnMax, "files"
For Each oFile In oFS.GetFolder( sDir ).Files
WScript.Echo oFile.Name, "seen"
Next
output:
----- Creating 3 files
1.txt created
2.txt created
3.txt created
----- Looping over 3 files and creating 3 more
2.txt seen A.txt created
3.txt seen B.txt created
1.txt seen C.txt created
----- Looping over 6 files
B.txt seen
2.txt seen
C.txt seen
A.txt seen
3.txt seen
1.txt seen
[The files collection is a snapshot] == #Panayot's argument/evidence ==> The For Each loops over a snapshot of the Files collection - at least wrt additions. Testing for deletions is left as an exercise.