Arabic word search tool [closed] - vb6

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 8 years ago.
Improve this question
I want to make a search tool to find a specific word in the Arabic language that i can find just the word for example:
ذهب الولد إلى المدرسة من البيت و منهم الى البيت
If I try to find the word "من", the code not only finds the word "من", but also finds part of the word " منهم". I don't want the program to do that. I want to find the word " من" and every word like it and make whole case to the word.
To make things more clear (using an English example), if I were to search for the word 'to' in the following sentence, I would only want whole words to be found, and not words that contain the word 'to' such as 'toward' to become a part of the result.
Sentence: I want to go towards the bus.

Answer 1

Searches like this can be frustrating. What I usually do is to add a space at the front of the search string and also at the end and then search for SearchString.
So... "I want to go towards the bus." becomes " I want to go towards the bus. ". Then I search for " to ". The problem with this method is that punctuation can cause a problem. For example, if you wanted to search for "bus", you would use:
" I want to go towards the bus. " and search for " bus ". This would not be found because there is punctuation after the word bus.
I would encourage you to use regular expressions for this functionality. VB6 does not have regular expressions built in, but you can use the Microsoft VBScript Regular Expressions functionality to accomplish this. Please take a look at this page to help you get started: http://support.microsoft.com/kb/818802
Edit based on your comment
You have this line of code:
pos = InStr(start_at, txtBody.Text, target)
try changing that line to this:
pos = InStr(start_at, " " & txtBody.Text & " ", " " & target & " ", vbBinaryCompare)
By adding spaces in the code, you are actually checking for (space)target(space). So that you don't miss potential matches at the beginning or end of txtBody.Text, spaces are added there (for comparison purposes only). By adding vbBinaryCompare, InStr will now perform a case sensitive search.

Answer 2

The only completely thorough way of doing this is to use the Instr() function, and then check that the next character is a punctuation character, a newline, or the word is at the end of the string, e.g.
Option Explicit
Private Declare Function GetStringTypeW Lib "Kernel32.dll" ( _
ByVal dwInfoType As Long, _
ByVal lpSrcStr As Long, _
ByVal cchSrc As Long, _
ByRef lpCharType As Integer _
) As Long
Private Const CT_CTYPE1 As Long = &H1
Private Const C1_UPPER As Long = &H1 ' Uppercase
Private Const C1_LOWER As Long = &H2 ' Lowercase
Private Const C1_DIGIT As Long = &H4 ' Decimal digits
Private Const C1_SPACE As Long = &H8 ' Space characters
Private Const C1_PUNCT As Long = &H10 ' Punctuation
Private Const C1_CNTRL As Long = &H20 ' Control characters
Private Const C1_BLANK As Long = &H40 ' Blank characters
Private Const C1_XDIGIT As Long = &H80 ' Hexadecimal digits
Private Const C1_ALPHA As Long = &H100 ' Any linguistic character: alphabetical, syllabary, or ideographic
Private Const C1_DEFINED As Long = &H200 ' A defined character, but not one of the other C1_* types
Function FindFullWord(ByVal in_lStartPos As Long, ByRef in_sText As String, ByRef in_sSearch As String, Optional ByVal in_eCompareMethod As VbCompareMethod = vbBinaryCompare) As Long
Dim nLenText As Long
Dim nLenSearch As Long
Dim sNextChar As String
Dim iCharType As Integer
FindFullWord = InStr(in_lStartPos, in_sText, in_sSearch, in_eCompareMethod)
' Did we find the search string in the text?
If (FindFullWord > 0) Then
' Save the length of the text.
nLenText = Len(in_sText)
nLenSearch = Len(in_sSearch)
Do
' Does this position mean that the search is the end of the string?
If (FindFullWord + nLenSearch - 1) = nLenText Then
' If so, we can exit now - there are no following characters.
Exit Function
End If
' Look at the next character.
sNextChar = Mid$(in_sText, FindFullWord + nLenSearch, 1)
' Is this next char a space, punctuation character, or a blank?
If (GetStringTypeW(CT_CTYPE1, StrPtr(sNextChar), 1, iCharType)) Then
If (iCharType And C1_SPACE) = C1_SPACE Then
Exit Function
ElseIf (iCharType And C1_PUNCT) = C1_PUNCT Then
Exit Function
ElseIf (iCharType And C1_BLANK) = C1_BLANK Then
Exit Function
End If
End If
' Find the position of the search string in the text.
FindFullWord = InStr(FindFullWord + nLenSearch, in_sText, in_sSearch, in_eCompareMethod)
Loop Until FindFullWord = 0
End If
End Function
I originally started doing a test for every character which could follow a word and would not be part of that word, but the code started getting very long. And, of course, I know absolutely nothing about Arabic. So I wondered whether there was a standard way of finding out the general "type" of a character, regardless of language. And as it happens, there was.
The GetStringTypeW() method is documented in the Win32 documentation, and essentially can retrieve information about all the characters in a string. In my case, I am only looking at the character which follows the search word in a piece of text. The variable iCharType which returns the value from the string is a bitfield, and contains a number of values OR'ed together. I am using the AND operator to isolate just the values I am interested in.