Dropping observations in Stata based on age and panel round - panel

Question

I have a panel dataset and I want to drop those respondents that were aged 40 years and over in their first round of the survey.
I tried doingdrop if age>40 and also drop if age>40 & t==1 where t is an identifier of the survey wave the person is in. However when I do the second I am left with people over the age of 40.
Here is an example of how my data looks like:
pid age wave year of survey
1 20 1 2005
1 21 2 2006
1 22 3 2007
1 23 4 2008
2 37 1 2006
2 38 2 2007
2 39 3 2008
2 40 4 2009
3 40 1 2008
3 41 2 2009
3 42 3 2010
3 43 4 2011
My aim is not to lose the 3rd respondent given that he/she was within my target age group when they were first surveyed but they were not in the following survey years (rather than just being left with his/her first wave of data and dropping the other 3 that is what is being done if I simply do drop if age<=40).
Is there another way so as to be left with only people up to the age of 40 while keeping those who were 40 in their first wave even if they turn 41, 42 etc in subsequent waves? I basically want to constrain my panel into the up to 40 years of age group while keeping those who were 40 in their wave but might be over 40 in subsequent waves (I only have 4 waves).

Answer 1

Stata gives you exactly what you're asking for. With drop if age > 40 you simply lose any observation for which age > 40. With drop if age > 40 & wave == 1 you add an additional condition: drop it if it simultaneously has wave == 1. I think that's clear.
I find your explanation somewhat contradictory. You don't want to lose any observation from respondent 3 because in her first wave she's not over 40, although she is in her following waves. But then you say you want to be left with only people up to the age of 40.
The following just drops all observations for any person who in her first wave is over 40. Let us know if this is not what you seek.
clear all
set more off
input ///
pid age wave survyear
1 20 1 2005
1 21 2 2006
1 22 3 2007
1 23 4 2008
2 37 1 2006
2 38 2 2007
2 39 3 2008
2 40 4 2009
3 40 1 2008
3 41 2 2009
3 42 3 2010
3 43 4 2011
4 42 1 2009
4 43 2 2010
4 44 3 2011
4 45 4 2012
end
list, sepby(pid)
*-----
bysort pid (age): drop if age[1] > 40
list, sepby(pid)
You probably want to read Speaking Stata: How to move step by: step, by Nick Cox. See also help subscripting.
Edit
With no knowledge of the database structure, sorting by wave should be a more general approach. That involves bysort pid (wave): ... in the previous code. Imagine a case where a person has the same age for two consecutive waves. If so, sorting by age would not give consistent results. The wave variable is likely to be the one that uniquely identifies cases, for each person. Read help sort and help isid carefully, including the manual entries.