In Perl, best way to insert a char every N chars - algorithm

Question

I would like to find the best way in Perl to insert a char every N chars in a string.
Suppose I have the following :
my $str = 'ABCDEFGH';
I would like to insert a space every two chars, so that I get:
my $finalstr = 'AB CD EF GH';
The innocent way would be:
my $finalstr;
while ($str =~ s/(..)//) {
$finalstr .= $1.' ';
}
(But the last space does not make me happy.)
Can we do better? Is it possible using a single substitution pattern s///, especially to use that same string $str (and not using $finalstr)?
The next step: do the same but with text before and after patterns to be cut (and to be kept, for sure), say for example '<<' and '>>':
my $str = 'blah <<ABCDEFGH>> blah';
my $finalstr1 = 'blah <<AB CD EF GH>> blah';
my $finalstr2 = 'blah << AB CD EF GH >> blah'; # alternate

Answer 1

Using positive lookahead and lookbehind assertions to insert a space:
my $str = 'ABCDEFGH';
$str =~ s/..\K(?=.)/ /sg;
use Data::Dump;
dd $str;
Outputs:
"AB CD EF GH"
Enhancement for limiting the Translation
If you want to apply this modification to only part of the string, break it into steps:
my $str = 'blah <<ABCDEFGH>> blah';
$str =~ s{<<\K(.*?)(?=>>)}{$1 =~ s/..\K(?=.)/ /sgr}esg;
use Data::Dump;
dd $str;
Outputs:
"blah <<AB CD EF GH>> blah"

Answer 2

The best solution using substitutions would probably be s/\G..\K/ /sg. Why?
The \G anchores at the current “position” of the string. This position is where the last match ended (usually this is set to the beginning of the string. If in doubt, set pos($str) = 0). Because we use the /g modifier, this will be where the previous substitution ended.
The .. matches any two characters. Note that we also use the /s modifier which causes . to really match any character, and not just the [^\n] character class.
The \K treats the previous part of the regex as a look-behind, by not including the previously matched part of the string in the substring that will be substituted. So \G..\K matches the zero length string after two arbitrary characters.
We substitute that zero length string with a single space.
I'd let the regex engine handle the substitution, rather than manually appending $1 . " ". Also, my lookbehind solution avoids the cost of using captures like $1.

Answer 3

You want the //g modifier with its many capabilities. See e.g. here for an introduction to the intricacies of global matching.

Answer 4

Do you mean something like...
$str =~ s/(..)/$1 /sg;
update: For more complex substitutions as the one you are asking in the second part of your question, you can use the e modifier that allows you to evaluate arbitrary perl code:
sub insert_spcs {
my $str = shift;
join ' ', $str =~ /(..?)/sg
}
my $str = 'blah <<ABCDEFGH>> blah';
$str =~ s/<<(.*?)>>/'<< '.insert_spcs($1).' >>'/se;

Answer 5

Personally I'd split the text with m//g and use join:
my $input = "ABCDEFGH";
my $result = join " ", ( $input =~ m/(..)/g );
say "RESULT <$result>";'
Yields
RESULT <AB CD EF GH>

Answer 6

The other answers are better, but just for giggles:
join ' ', grep length, split /(..)/, 'ABCDEFGH';