BATCH Comparing two folders recursively - windows

Question

i'm updating a big save script and i need to compare 2 folders recursively. I think i'm pretty close but can't understand what's missing...
The code is the following :
set Rep1=f:\album1
set Rep2=f:\album2
set logfile=f:\logfile.txt
for /r "%Rep1%\" %%i in (*) do (
fc "%%i" "%Rep2%\%%~nxi"
iF ERRORLEVEL == 1 echo "%%i" et "%Rep2%\%%~nxi" Sont differents >> %logfile%
iF ERRORLEVEL == 2 echo "%%i" et "%Rep2%\%%~nxi" Un des fichier est manquant >> %logfile%
)
pause
The problem is that it compares all files like f:\album1\folder1\file1.txt with f:\album2\file1.txt so the comparing is always wrong... You can see the result in the picture:
If any of you find a solution, thank you a lot !
Vincs

Answer 1

#ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "targetdir=U:\destdir"
FOR /f "delims=" %%a IN (
'dir /s /b /a-d "%sourcedir%\*" '
) DO (
SET "foundfile="
FOR /f "delims=" %%c IN (
'dir /s /b /a-d "%targetdir%\%%~nxa" 2^>nul'
) DO (
SET foundfile=Y
FC /b "%%a" "%%c" >NUL
IF ERRORLEVEL 1 ECHO different "%%a" "%%c"
)
IF NOT DEFINED foundfile ECHO missing "%%a" from "%targetdir%"
)
FOR /f "delims=" %%a IN (
'dir /s /b /a-d "%targetdir%\*" '
) DO (
SET "foundfile="
FOR /f "delims=" %%c IN (
'dir /s /b /a-d "%sourcedir%\%%~nxa" 2^>nul'
) DO (
SET foundfile=Y
)
IF NOT DEFINED foundfile ECHO missing "%%a" from "%sourcedir%"
)
GOTO :EOF
You would need to change the settings of sourcedir and targetdir to suit your circumstances.
One problem with your approach is that the file %%i is compared to "%Rep2%\%%~nxi" which means only in %rep2%, not in the subdirectory.
Another problem is
IF ERRORLEVEL == 1 echo "%%i" et "%Rep2%\%%~nxi" Sont differents >> %logfile%
which compares the literal string ERRORLEVEL to the literal string 1 so will not find a match. To use your method, you would have to turn delayedexpansion on with a setlocal enabledelayedexpansion statement and then use IF !ERRORLEVEL!==1 ...
The solution posted above compares files that have the same name and extension wherever they are found on the tree, so if file1.txt is anywhere in the first tree, then it will be compared to all the file1.txt files found anywhere in the second tree.
Note also that there is a standard anomaly when dealing with a standard system that gives files both a long and a short name. Each file potentially has two names - and dir matches on either name.

Answer 2

Magoo's answer already points out the major problems of your code.
However, the solution he provided uses only the file names for finding the files to compare, so it will fail if files with equal names occur at different locations in the source and target directories, or if multiple files with equal names occur within any of the directory trees.
Here is a similar solution, based on the dir /S command, which also requires each file name in the trees to be unique and to occur at the same location within source and target (it does not check for files present in only one of the source or target trees):
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem Provide source and target directory paths here:
set "SOURCE=.\source"
set "TARGET=.\target"
rem Convert relative paths to absolute ones:
for %%D in ("%SOURCE%") do set "SOURCE=%%~fD"
for %%D in ("%TARGET%") do set "TARGET=%%~fD"
for /F "eol=| delims=" %%I in ('
2^> nul dir /B /S /A:-D "%SOURCE%\*.*"
') do (
set "SRC=%%~fI"
for /F "eol=| delims=" %%J in ('
2^> nul dir /B /S /A:-D "%TARGET%\%%~nxI"
') do (
set "TRG=%%~fJ"
setlocal EnableDelayedExpansion
> nul fc /B "!SRC!" "!TRG!" || echo "!SRC!" and "!TRG!" differ.
endlocal
)
)
endlocal
exit /B
This code snippet compares only files which occur in both source and target directory trees. If respective files are different, a related message is returned.
To overcome the issue with equal file names at different locations, let us use the xcopy /L command, because this is capable of returning a list of paths relative to the source directory (the /L option prevents xcopy from copying any files; the appended find command filters out the ? File(s) summary lines):
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem Provide source and target directory paths here:
set "SOURCE=.\source"
set "TARGET=.\target"
rem Convert relative paths to absolute ones:
for %%D in ("%SOURCE%") do set "SOURCE=%%~fD"
for %%D in ("%TARGET%") do set "TARGET=%%~fD"
pushd "%SOURCE%"
for /F "eol=| delims=" %%I in ('
2^> nul xcopy /L /S /Y ".\*.*" "%TEMP%\" ^| find ".\"
') do (
set "SRC=%%~fI"
pushd "%TARGET%"
for /F "eol=| delims=" %%J in ('
2^> nul xcopy /L /Y "%%~I" "%TEMP%\" ^| find ".\"
') do (
set "TRG=%%~fJ"
setlocal EnableDelayedExpansion
> nul fc /B "!SRC!" "!TRG!" || echo "!SRC!" and "!TRG!" differ.
endlocal
)
popd
)
popd
endlocal
exit /B
This code snippet also compares only files which occur in both source and target directory trees. If you also want to check whether each fils is present in both source and target trees, check out Magoo's answer which provides a good idea of how to accomplish that (two-loop approach).