Type Creation and Execution - oracle

Question

I have created a type to print experience of employees from employees table for 5 employees with one incorrect id. I have created an exception to skip it but I am not getting the result for it. What mistake have I done? Please refer my query and tell the error.
CREATE OR REPLACE TYPE emp_id_typ IS TABLE OF NUMBER;
/
CREATE OR REPLACE TYPE emp_exp_typ IS TABLE OF NUMBER;
/
CREATE OR REPLACE PROCEDURE exp_sp ( p_empid IN emp_id_typ
, p_exp OUT emp_exp_typ)
IS
v_exp NUMBER;
BEGIN
FOR i IN p_empid.FIRST..p_empid.COUNT
LOOP
p_exp.EXTEND;
SELECT ROUND(MONTHS_BETWEEN(SYSDATE, hire_date)/12) INTO v_exp FROM employees
WHERE employee_id = p_empid(i);
p_exp(p_exp.LAST) := v_exp;
END LOOP;
EXCEPTION
WHEN OTHERS THEN
v_exp := NVL(v_exp, 'NULL');
END exp_sp;
/
DECLARE
v_empid emp_id_typ := emp_id_typ( );
v_exp emp_exp_typ := emp_exp_typ( );
BEGIN
v_empid := emp_id_typ(101, 102, 52, 100, 206);
FOR i IN v_empid.FIRST..v_empid.COUNT
LOOP
exp_sp(v_empid(i), v_exp(i));
dbms_output.put_line(v_empid(i), v_exp(i));
END LOOP;
END;
/
Thanks in advance...

Answer 1

You have several errors in both the procedure and the anonymous block. In the procedure:
You haven't initialised the OUT p_exp collection. As it's an OUT parameter you have to do it inside the procedure. (Alternatively make it IN OUT).
Your exception handler terminates the loop, so the v_exp you set in there is never used, and the p_exp collection is incomplete. (It's also bad practise to use when others.)
You can't assign a string like ``NULL'` to a number variable or collection. Either assign an a magic number that represents an error to the caller, or leave it null.
CREATE OR REPLACE PROCEDURE exp_sp ( p_empid IN emp_id_typ
, p_exp OUT emp_exp_typ)
IS
v_exp NUMBER;
BEGIN
-- have to initialise p_exp
p_exp := emp_exp_typ();
-- better to use either 1..count, or first..last; don't mix them
--FOR i IN p_empid.FIRST..p_empid.COUNT
FOR i IN p_empid.FIRST..p_empid.LAST
LOOP
p_exp.EXTEND;
-- you want the exception handler to deal with this row then continue,
-- so use a nested block
BEGIN
SELECT ROUND(MONTHS_BETWEEN(SYSDATE, hire_date)/12) INTO v_exp FROM employees
WHERE employee_id = p_empid(i);
EXCEPTION
WHEN OTHERS THEN
-- you can't assign a string to a number
--v_exp := NVL(v_exp, 'NULL');
-- just an example as not clear what you need
v_exp := -1;
END; -- nested block with exception handler
p_exp(p_exp.LAST) := v_exp;
END LOOP;
END exp_sp;
/
And in your anonymous block:
The initialisation of v_exp is redundant as the procedure argument is OUT. Not an error but pointless.
You are calling the procedure inside the loop, passing a single element; it should be called once outside the loop and passed the whole collection(s).
Your call to dbms_output.put_line is wrong; that only takes a single argument, so you have to build a string up e.g. with concatenation.
DECLARE
v_empid emp_id_typ := emp_id_typ( );
-- assignment is redundant
-- v_exp emp_exp_typ := emp_exp_typ( );
v_exp emp_exp_typ;
BEGIN
v_empid := emp_id_typ(101, 102, 52, 100, 206);
-- moved this call up, without indexing
exp_sp(v_empid, v_exp);
-- better to use either 1..count, or first..last; don't mix them
-- FOR i IN v_empid.FIRST..v_empid.COUNT
FOR i IN v_empid.FIRST..v_empid.LAST
LOOP
--exp_sp(v_empid(i), v_exp(i));
-- fixed call to dbms_output
dbms_output.put_line(v_empid(i) ||': '|| v_exp(i));
END LOOP;
END;
/
which gets:
101: 28
102: 25
52: -1
100: 30
206: 24
PL/SQL procedure successfully completed.
I need not to print the third variable as it is not in the table.
You can test the v_exp value for the magic number (or null, which is safer, but the procedure needs to be modified slightly for that), and only print the results which you need:
...
FOR i IN v_empid.FIRST..v_empid.LAST
LOOP
IF v_exp(i) != -1 THEN
dbms_output.put_line(v_empid(i) ||': '|| v_exp(i));
END IF;
END LOOP;
...
which gets:
101: 28
102: 25
100: 30
206: 24
PL/SQL procedure successfully completed.