Printing with loops in sql - oracle

Question

Hi I wrote a procedure to accomplish a task and it looks like this
create or replace procedure myproc
is
begin
for rec_ in (
select
case
when highest_ = 1 then
'Most profit in ' || category || ' -> ' || carname || ': ' || aprofit
when lowest_ = 1 then
'Least profit in ' || category || ' -> ' || carname || ': ' || aprofit
end report
from (
select
category
, carname
, aprofit
, rank() over ( partition by category order by aprofit asc ) lowest_
, rank() over ( partition by category order by aprofit desc ) highest_
from (
select unique
C.category
, C.carname
, avg( R.rentalrate - C.suggesteddealerrentalprice )
over ( partition by C.category, C.carname ) as aprofit
from rentals R
join car C on R.carid = C.carid
join cardealers CD on CD.dealerid = C.dealerid
where CD.state = 'IN'
)
)
where lowest_ = 1 or highest_ = 1
order by case when lowest_ > 1 then 2 else 1 end, category, carname
)
loop
dbms_output.put_line( rec_.report ) ;
end loop ;
end ;
/
begin
myproc ;
end ;
/
This prints out the output that looks like this
Least profit in compact -> Nissan Versa: 4
Least profit in compact -> Toyota Yaris: 4
Least profit in luxury -> Porsche: 40
Least profit in van -> Chrysler: 2
Most profit in compact -> Chevy Spark: 5
Most profit in luxury -> Audi: 45
Most profit in van -> Honda Odyssey: 9
I want it to print out like this that if a car category has more than one car inside it it only prints the heading one time. But as you can see in my output the heading for "Least profit in compact" is being printed two times. I want an output that looks like this
Least Profit in compact
- Nissan Versa: 4
- Toyota Yaris: 4
Least Profit in luxury
- Porsche: 40
Least Profit in van
- Chrysler: 2
Most Profit in compact
- Chevy Spark: 5
Most Profit in luxury
- Audi: 45
Most Profit in van
- Honda Odyssey: 9
The tables and data files are
Data file
Tables file

Answer 1

You may select the columns Least/Most,category,carname,aprofit separately from your select query and then use DBMS_OUTPUT conditionally.
I have used your sample dataset from the output in the below code as I do not have your table/ definitions.
DECLARE
v_high_low VARCHAR2(40) := 'DUMMY';
v_category VARCHAR2(40) := 'DUMMY';
BEGIN
for rec_ IN
(
with t (high_low,category,carname,aprofit) AS
(
select 'Least profit in ','compact', 'Nissan Versa', 4 from dual union all
select 'Least profit in ','compact','Toyota Yaris', 4 from dual union all
select 'Least profit in ','luxury','Porsche', 40 from dual union all
select 'Least profit in ','van','Chrysler', 2 from dual union all
select 'Most profit in ','compact','Chevy Spark', 5 from dual union all
select 'Most profit in ','luxury','Audi', 45 from dual union all
select 'Most profit in ','van', 'Honda Odyssey', 9 from dual
)
SELECT * FROM t order by high_low,category,carname
)
LOOP
IF rec_.high_low != v_high_low OR rec_.category != v_category
THEN
DBMS_OUTPUT.PUT(rec_.high_low);
v_high_low := rec_.high_low;
END IF;
IF rec_.category != v_category
THEN
DBMS_OUTPUT.PUT_LINE(rec_.category);
v_category := rec_.category;
END IF;
DBMS_OUTPUT.PUT_LINE(' - '||rec_.carname||': '|| rec_.aprofit);
END LOOP;
END;
/
DEMO
EDIT - Adding this demo link with the procedure with actual tables provided :
DEMO2