How do I make text grow then shrink while still keeping the same midpoint? - processing

Question

I'm making a bit of a late father's day present. I need some sort of ____Mode(CENTER) for text. I am trying to make a piece of text expand, then shrink, then expand again, then shrink again, on a loop. However, what I attempt seems to grow and shrink sparatically, making the text move around, and not staying centered. Is there an easy way to do this with text?
Code:
String msg = "Happy Father's Day";
int ts = 50;
float textX = 165;
float textY = 312.5;
float tSize = 50;
boolean flip;
void setup() {
size(800, 600);
}
void draw() {
background(0);
fill(255);
textSize(tSize);
text(msg, textX, textY);
if (flip == false) {
tSize += 0.5;
textX -= 1;
textY -= 1;
} else if (flip == true) {
tSize -= 0.5;
textX += 1;
textY += 1;
}
if (tSize == 35) flip = false;
else if (tSize == 65) flip = true;
}

Answer 1

Rather than constantly modifying textX and textY, you can use textAlign if you want to keep the text centered. In this case, you can simply drop those 2 variables:
String msg = "Happy Father's Day";
int ts = 50;
float tSize = 50;
boolean flip;
void setup() {
size(800, 600);
textAlign(CENTER,CENTER);
}
void draw() {
background(0);
fill(255);
textSize(tSize);
text(msg, width/2, height/2);
if (!flip) {
tSize += 0.5;
} else {
tSize -= 0.5;
}
if (tSize == 35) flip = false;
if (tSize == 65) flip = true;
}
You can streamline your code by making flip a number which is always 1 or -1 rather than a Boolean. This reduces the amount of conditional logic required. Note also how the following code replaced the equality comparisons (==) with inequalities (<= and >=). Something like tSize == 65 does work with steps of size 0.5 (since 0.5 has a finite base-2 expansion) but if you changed 0.5 to e.g. 0.1 to try to make it slower, the value 65 would be skipped over entirely due to floating-point round-off error. Since tSize is declared to be a float, using == with it is asking for trouble.
String msg = "Happy Father's Day";
int ts = 50;
float tSize = 50;
float flip = -1;
void setup() {
size(800, 600);
textAlign(CENTER,CENTER);
}
void draw() {
background(0);
fill(255);
textSize(tSize);
text(msg, width/2, height/2);
tSize += flip * 0.5;
if (tSize <= 35 || tSize >= 65 ) flip *= -1;
}