I am trying to print greek text inside field box ^FB with ^CI34.
For example lets print this one that works:
^XA
^CF0,34
^CI34^FO5,5
^FH^FD Theta: _C8 ^FS
^XZ
It prints: Theta: θ
The code I use for ^FB:
^XA
^CF0,34
^CI34^FO5,5
^FB300,2,0,L
^FH^FD Theta: _C8^FS
^XZ
It prints: Theta:
So where is the mistake?
According to ZPL Programming guide The ^FB command does not support complex text. For complex text support, use ^TB
So in my case an example like this works:
^XA
^CF0,34
^CI34^FO5,5
^TBN,250,250
^FH^FD Theta: _C8^FS
^XZ
Related
This is my code for the ZPL label:
^XA^FS^FT215,210^A0N,28,28^FH^FD300 mg (1 ½ tablet)^XZ
but it shows like this:
I want it to be shown as ½, any suggestions?
You need to switch to UTF-8 encoding using ^CI28:
^XA^CI28^FT215,210^A0N,28,28^FD300 mg (1 ½ tablet)^FS^XZ
This label is shown correct in the Labelary Online ZPL Viewer, but the printer Zebra ZD410 doesn't print the ½ symbol...is it a problem of compatibility?
^XA
^MMT
^PW400
^LL200
^LS-40
^CI28
^FO60,20^ADN,15,10^FD35663_AVE^FS
^FO210,20^A0N,25,25^FD37 ½^FS
^FO60,45^BY2^BEN,60,N,N^FD8445087656818^FS
^FO170,130^ADN,30,15^FD199^FS
^FO250,130^ADN,20,10^FDEUR^FS
^XZ
I'm creating "labels" for our Zebra ZT410 300Dpi printer. Those are simple ones that contains just Name (variable size max 15 chars) and QR code (Usually same).
So far, I've done this:
^XA^LH0,0^FWb
^MUd,150,300
^A0,65,75^FO100,150^FD
Test
^FS
^FO275,400^BQN,2,10,H^FDMM,A
Test
^FS^XZ
look at picture 1. Text tends to align to right side.
So I tried to modify it like this
^XA^LH0,0^FWb
^MUd,150,300
^A0,65,75^FO100,150^FB0,350,15,C^FD
Test
^FS
^FO275,400^BQN,2,10,H^FDMM,A
Test
^FS^XZ
But instead of centering against label Height, it centers against width and text is now vertical. Look at picture 2.
You can use the ^FB command to center text => https://imgur.com/a/yRKwV7s
^XA
^LH0,0^FWb
^MUd,150,300
^A0,65,75^FO100,0^FB1800,1,0,C,0^FDTest^FS
^A0,65,75^FO200,0^FB1800,1,0,C,0^FDThis is a center text^FS
^FO275,400^BQN,2,10,H^FDMM,ATest^FS
^XZ
I have a problem with zebra printer ZT410, i'm trying to print in latin characters such as ñ, ç and ò and so on.
^XA
^CI28
^MMT
^PW1040
^LL840
^A#N,50,49,E:STI000.FNT^FT50,-230^FH\^FDRajoy^FS
^A#N,50,49,E:STI000.FNT^FB1040,2,25,C^FT0,-421^FH\^FDThañk yòú fôr showing me that there are people^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-509^FH\^FDlike you in this world.^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-572^FH\^FD^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-635^FH\^FDLoveç you.^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-698^FH\^FDMarta.^FS
^A#N,50,49,E:STI000.FNT^FT50,-790^FH\^FDDavid^FS
^XZ
But instead of printing the special characters, they are omited, I've checked that the special font used (Stingray) contains all those characters, I don't know how to print them. Any help would be appreciated. Thanks
Edit: I actually fixed it by using ^CI27 instead of ^CI28 since I have an older version of the Zebra firmware that doesn't support ^CI28
Here's something simple that works with some of the text you have:
^XA
^CI28
^FO50,20^A0N,40,40^FDThañk yòú fôr showing me that there are people^FS
^XZ
Is there a way to use ZPL to print text with a strikethrough (a line through the text)?
I need to be able to print something and indicate that it was there. I have looked through the ZPL programming guide and I have not found any way to alter the font....
An alternative approach would be to draw a line through your text. Here is a sample. You would need to calculate the points of the line based on the coordinates of the text:
^XA
^FT62,93^A0N,42,40^FH\^FDstrikethrough^FS
^FO41,76^GB268,0,5^FS
^PQ1
^XZ
AFAIAA, No.
Could you simply draw a line over the required text? Perhaps you could use or manufacture a downloaded bitmap font which is "struck through?"
OTOH...
To underline - use a monospaced font like AA,AC,AD,AF or AG
Use
^FO350,50^AGR^FDwhatever,milk,butter,salt^FS
^FO340,50^AGR^FD ____ ______^FS
where the underline here is under milk and butter, you can adjust the offset by trimming the FO's X and Y positions by a few dots (10 X here). Naturally, that can be raised for strikethrough, too...
I have simple label created in ZPL language for Zebra printer.
I want to enlarge the size of the text below the barcode.
I tried to find solution in web and I used command ^ADN,40 - text was moved to the left position.
My label is here:
http://sunpic.me/vIzoilyu/barcodemale.jpg
^XA^JZN
^BY3^FS
^FO68,35^ADN,40^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ
Here is the ZPL code to print a barcode without human readable content:
^XA
^FXAutorizacao de Usuario
^FO50,35
^BY4,10,100
^BC,126,N,N,N,N
^FD0123456789
^FS
^CF0,40
^FO50,200^GB700,1,3^FS
^CF0,50
^FO50,220^FDBRUNO LEITAO^FS
^XZ
You can also test it online
Labelary Online ZPL Viewer
According to Zebra's ZPL docs:
The font specified by command ^A is used only once for that ^FD entry.
If a value for ^A is not specified again, the default ^CF font is used
for the next ^FD entry.
So, I suggest you to try the following code:
^XA^JZN
^BY3^FS
^FO68,35^ADN,40^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^ADN,40^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ
If necessary, you can also change the "D" font by another bigger bitmapped font, as "F", "Q", etc.
Another suggestion:
^XA^JZN
^BY3^FS
^CFD,40^FO68,35^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ