I have a problem with zebra printer ZT410, i'm trying to print in latin characters such as ñ, ç and ò and so on.
^XA
^CI28
^MMT
^PW1040
^LL840
^A#N,50,49,E:STI000.FNT^FT50,-230^FH\^FDRajoy^FS
^A#N,50,49,E:STI000.FNT^FB1040,2,25,C^FT0,-421^FH\^FDThañk yòú fôr showing me that there are people^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-509^FH\^FDlike you in this world.^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-572^FH\^FD^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-635^FH\^FDLoveç you.^FS
^A#N,50,49,E:STI000.FNT^FB1040,1,0,C^FT0,-698^FH\^FDMarta.^FS
^A#N,50,49,E:STI000.FNT^FT50,-790^FH\^FDDavid^FS
^XZ
But instead of printing the special characters, they are omited, I've checked that the special font used (Stingray) contains all those characters, I don't know how to print them. Any help would be appreciated. Thanks
Edit: I actually fixed it by using ^CI27 instead of ^CI28 since I have an older version of the Zebra firmware that doesn't support ^CI28
Here's something simple that works with some of the text you have:
^XA
^CI28
^FO50,20^A0N,40,40^FDThañk yòú fôr showing me that there are people^FS
^XZ
Related
I am trying to print Vietnamese text on my Zebra label using Zpl coding.
But i am getting issues in vietnamese characters. For example, i am trying to print a label with text "Nhập khẩu" but it is giving me the output "Nh p kh u", thus missing the Vietnamese fonts.
I have tried using Andale and Swiss font and also declaring the ^CI28 tag for printing various characters in utf-8 encoding.
If anyone else has any other inputs, please let me know.. thanks in advance..
EDIT:
This is the code i am using..
^XA^CWZ,E:TT0003M_.TTF^FS^XZ
^XA
^CF01,20,15
^CI28
^FO20,20^FDNhập khẩu - LOẠI:For Fujifilm^FS
^XZ
Have you tried google's Noto fonts?
https://fonts.google.com/specimen/Noto+Sans
I have used them to render Vietnamese. If that doesn't work, post the sample ZPL you have tried and we can work through it.
Here is some example ZPL. This assumes the Noto Sans font is saved to the printer as E:NOTOSANS.TTF:
^XA^CI28
^A#N,32,32,E:NOTOSANS.TTF
^FO50,50
^FDNhập khẩu^FS
^XZ
I am new to ZPL coding and am not sure how to include miscellaneous symbols like Recycle, Rain on the ZPL files for printing labels.
I tried a bit of coding in UTF-8 encoding by using ^CI28 command and converted the recycle and rain logos to hexadecimal and tried escaping the default underscores using ^FH command but no avail.
^XA
^CI28
^CFT,30,30
^FO50,50^FH^FDTesting^FS
^FO50,100^FH^FD_e2_99_b2^FS
^XZ
In UTF-16, it is printing &72 instead of recycle logo
^XA
^CI29
^CFT,30,30
^FO50,50^FH^FDTesting^FS
^FO50,100^FH^FD_2672^FS
^XZ
Also the results i checked are from simulator available in http://labelary.com/viewer.html. Not sure if there is an issue with my code or simulator in which i am seeing the output.It will be great if any ZPL coding experts can provide some pointers on this regard. Thanks in advance!
Store the images on the printer's memory, and call them up as you need them with the image command.
I am using ZQ520, its already supports Unicode and I am loading the font as follows:
^XA ^CWZ,E:TT0003M_.FNT^FS^XZ
I can use the font to print Arabic as follows:
^FO100,50^CI28^AZN,0,25^FD ARABIC TEXT HERE ^FS
It works fine but when I use ^FB with ^FO, the Arabic letters get messed up and gets separated (In Arabic, they are connected), here an example:
^FO100,50^FB200,,,R,^CI28^AZN,0,25^FD ARABIC TEXT HERE^FS
so it seems that ^FB does not support the Unicode font. on page 187 of the manual its mention this
The ^FB command does not support complex text. For complex text
support, use ^TB.
And 179
The Field Block (^FB) command cannot support the large TrueType fonts.
Is there a way around this? Because Arabic is right to left, so I am trying to make the text right aligned and multi-line as some strings are long.
I managed to print out word wrapping Arabic text using ^TB using the following code. It may be useful to adapt for your own purposes.
^XA^LRN^CI28^CWZ,E:TT0003M_.FNT^FS
^FO600,10,2
^AZN,50,40
^TBN,600,100
^FH
^FD
arabic text here
^FS
^PQ1
^XZ
Useful links:
TB command (some extra info compared to below link): https://support.zebra.com/cpws/docs/zpl/TB_Command.pdf
Please note that it states the ^TB command must be issued after any ^Ax (font selection) command
ZPL Manual: https://www.zebra.com/content/dam/zebra/manuals/en-us/software/zpl-zbi2-pm-en.pdf
My question is about printing French characters with an acute like: é è à ô etc. with a Zebra P4t printer.
Consider the ZPL instructions below:
^XA
^FO20,20
^CI28
^A0,20,20
^FD
Amitié
^FS
^XZ
I have put these instructions into a file encoded as UTF-8.
When I send this file to a Zebra GK420t printer, I get the expected result concerning the character with an acute é at the end of the French word Amitié that you can see above. It is printed properly.
Now, when I send this very same file to a Zebra P4t printer it prints something like |-® instead of the é character.
The firmware of the printer is SHCPT11z48.
Alos, if you consider the ZPL instructions below:
^XA
^FO20,60
^A0,20,20
^FD
Amitié
^FS
^XZ
I have put these instructions into a file encoded as ANSI.
Now, when I send this very same file to a Zebra P4t printer it prints Ú instead of the é character.
I really don't see where this character Ú is coming from.
What can I do to solve that problem?
Is a font missing in the printer?
Am I not sending compatible ZPL instructions?
Thank you and best regards.
You have to prefix the field with UTF-8 characters with ^FH (Field Hexadecimal Indicator) and replace every UTF-8 character with their unicode hexadecimal code prefixed by an _ (list, example for é):
^XA
^FO20,20
^CI28
^A0,20,20
^FD
Amiti_C3_A9
^FS
^XZ
Simple solution without having to replace anything:
After the opening tag ^XA add ^CI28.
^XA^CI28
your content
^XZ
Zebra support talking about it here.
I have simple label created in ZPL language for Zebra printer.
I want to enlarge the size of the text below the barcode.
I tried to find solution in web and I used command ^ADN,40 - text was moved to the left position.
My label is here:
http://sunpic.me/vIzoilyu/barcodemale.jpg
^XA^JZN
^BY3^FS
^FO68,35^ADN,40^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ
Here is the ZPL code to print a barcode without human readable content:
^XA
^FXAutorizacao de Usuario
^FO50,35
^BY4,10,100
^BC,126,N,N,N,N
^FD0123456789
^FS
^CF0,40
^FO50,200^GB700,1,3^FS
^CF0,50
^FO50,220^FDBRUNO LEITAO^FS
^XZ
You can also test it online
Labelary Online ZPL Viewer
According to Zebra's ZPL docs:
The font specified by command ^A is used only once for that ^FD entry.
If a value for ^A is not specified again, the default ^CF font is used
for the next ^FD entry.
So, I suggest you to try the following code:
^XA^JZN
^BY3^FS
^FO68,35^ADN,40^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^ADN,40^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ
If necessary, you can also change the "D" font by another bigger bitmapped font, as "F", "Q", etc.
Another suggestion:
^XA^JZN
^BY3^FS
^CFD,40^FO68,35^FD TRW ORS 34186401A^FS
^FO30,69^GB568,0,6^FS
^FO30,55^GB0,20,6^FS
^FO591,55^GB0,20,6^FS
^FO49,83
^BC,126,Y,N,N,N
^FD>;8640>61AAH44300E
^FS
^PQ1,,,
^XZ