How can I add a nested collection to an extension - gradle

Question

new to Gradle. I have this simple plugin with an extension that allows me to write custom DSL:
import org.gradle.api.NamedDomainObjectContainer
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.DefaultTask
import org.gradle.api.tasks.TaskAction
apply plugin: NeighborhoodPlugin
class Street {
String name
String type
public Street(name) {
this.name = name
}
}
class Neighborhood {
final NamedDomainObjectContainer<Street> streets
def name
public Neighborhood(streets) {
this.streets = streets
}
def streets(Closure closure) {
streets.configure(closure)
}
}
// Plugin
class NeighborhoodPlugin implements Plugin<Project> {
void apply(Project project) {
// Create the NamedDomainObjectContainers
def streets = project.container(Street);
//https://docs.gradle.org/current/dsl/org.gradle.api.plugins.ExtensionAware.html
def neighborhoodExt = project.extensions.create( 'neighborhood', Neighborhood, streets )
}
}
neighborhood {
name = 'My neighborhood'
streets {
street1 {
type = 'T'
}
street2 {
type = 'round'
}
}
}
task show {
doLast {
println "${neighborhood.name} has ${neighborhood.streets.toArray().length} streets"
}
}
The above seems to work. But I would like to expand on the DSL to add Houses to Streets. Something like this:
import org.gradle.api.NamedDomainObjectContainer
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.DefaultTask
import org.gradle.api.tasks.TaskAction
apply plugin: NeighborhoodPlugin
class House {
String name
String address
public House(name) {
this.name = name
}
}
class Street {
final NamedDomainObjectContainer<House> houses
String name
String type
public Street(name) {
this.name = name
}
}
class Neighborhood {
final NamedDomainObjectContainer<Street> streets
def name
public Neighborhood(streets) {
this.streets = streets
}
def streets(Closure closure) {
streets.configure(closure)
}
}
// Plugin
class NeighborhoodPlugin implements Plugin<Project> {
void apply(Project project) {
// Create the NamedDomainObjectContainers
def streets = project.container(Street);
//https://docs.gradle.org/current/dsl/org.gradle.api.plugins.ExtensionAware.html
def neighborhoodExt = project.extensions.create( 'neighborhood', Neighborhood, streets )
}
}
neighborhood {
name = 'My neighborhood'
streets {
street1 {
type = 'T'
houses {
blueHouse {
address = '100 main'
}
}
}
street2 {
type = 'round'
}
}
}
task show {
doLast {
println "${neighborhood.name} has ${neighborhood.streets.toArray().length} streets"
}
}
I tried different combinations of things but I can never get to it to work. The error is always: No signature of method: build_ch0yxyi3isqke8j97jxnsaw72.neighborhood() is applicable for argument types.
Any help is really appreciated.

Answer 1

This works and I got it from: https://mrhaki.blogspot.com/2016/02/gradle-goodness-using-nested-domain.html:
import org.gradle.api.NamedDomainObjectContainer
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.DefaultTask
import org.gradle.api.tasks.TaskAction
apply plugin: NeighborhoodPlugin
class House {
String name
String address
public House(name) {
this.name = name
}
}
class Street {
NamedDomainObjectContainer<House> houses
String name
String type
public Street(name) {
this.name = name
}
def houses(Closure closure) {
houses.configure(closure)
}
}
class Neighborhood {
final NamedDomainObjectContainer<Street> streets
def name
public Neighborhood(streets) {
this.streets = streets
}
def streets(Closure closure) {
streets.configure(closure)
}
}
// Plugin
class NeighborhoodPlugin implements Plugin<Project> {
void apply(Project project) {
// Create the NamedDomainObjectContainers
def streets = project.container(Street);
streets.all {
houses = project.container(House)
}
//https://docs.gradle.org/current/dsl/org.gradle.api.plugins.ExtensionAware.html
def neighborhoodExt = project.extensions.create( 'neighborhood', Neighborhood, streets )
}
}
neighborhood {
name = 'My neighborhood'
streets {
main {
type = 'Cul de-sac'
houses {
blueHouse {
address = '100 main'
}
pinkHouse {
address = '101 main'
}
greenHouse {
address = '103 main'
}
}
}
round {
type = 'Round'
houses {
yellowHouse {
address = '100 round'
}
greenHouse {
address = '101 round'
}
}
}
}
}
task show {
doLast {
println "${neighborhood.name} has ${neighborhood.streets.toArray().length} streets"
neighborhood.streets.all {
println "--> name: ${name}"
houses.all {
println "--> --> name: ${name} address: ${address}"
}
}
}
}