solving kakuro in prolog using predicate - prolog

Question

I want to predicate solve Kakuro.
My kakuro is this
I have to create a predicate using the word solve (solve/1) for the game kakuro. I tried 3-4 codes and all of them have errors. The variables have to be between 1-9(A value is between 1-9) and all the variables have to be different in one rows&columns(24=A+B+C not 24=A+A+C).
First code is:
:- use_module(library(clpfd)).
solve(L):-
L= [A,B,C,E,F,G,J,K,L,N,O,P],
all_different(L),
L ins 1..9,
A #= 24-B-C,
B #= 26-F-J-N,
C #= 15-G-K-O,
E #= 11-F-G,
E #= 17-A,
J #= 22-K-L,
N #= 14-O-P,
L #= 13-P.
Second code:
:- use_module(library(clpfd)).
sum_list([],0).
sum_list([Head|Tail], Sum):-sum_list(Tail, Sum1),Sum is Head+Sum1.
go:-
Vars=[A,B,C,E,F,G,J,K,L,N,O,P],
Vars ins 1..9,
word([A,B,C],24),
word([B,F,J,N],26),
word([C,G,K,O],15),
word([E,F,G],11),
word([A,E],17),
word([J,K,L],22),
word([N,O,P],14),
word([L,P],13),
labeling(Vars),
writeln(Vars).
word(L,Sum):-
sum_list(L,X),
X=:=Sum,
all_different(L).
Third code:
:- use_module(library(clpfd)).
kakuro(L):-
L = [A,B,C,E,F,G,J,K,L,N,O,P],
L ins 1..9,
Z1 = [A,B,C],
all_different(Z1),
A =:= 24-B-C,
Z2 = [B,F,J,N],
all_different(Z2),
B =:=26-F-J-N,
Z3 = [C,G,K,O],
all_different(Z3),
C =:= 15-G-K-O,
Z4 = [E,F,G],
all_different(Z4),
E =:= 11-F-G,
Z5 = [A,E],
all_different(Z5),
E =:= 17-A,
Z6 = [J,K,L],
all_different(Z6),
J =:=22-K-L,
A1 = [N,O,P],
all_different(A1),
N =:= 14-O-P,
A2 = [L,P],
all_different(A2),
L =:=13-P,
labeling([], L).
Also how do I start the solving process? Will it be like: ?-solve(L). ?? Also the L ins 1..9 is not working.

Answer 1

The following is a solution based on DuDa's, but using the sum/3 constraint and delaying labeling to the end. This makes for a more efficient and more declarative solution.
:- use_module(library(clpfd)).
kakuro(Vars):-
Vars=[A,B,C,E,F,G,J,K,L,N,O,P],
Vars ins 1..9,
word([A,B,C],24),
word([B,F,J,N],26),
word([C,G,K,O],15),
word([E,F,G],11),
word([A,E],17),
word([J,K,L],22),
word([N,O,P],14),
word([L,P],13),
labeling([],Vars).
word(L,Sum):-
all_different(L),
sum(L,#=,Sum).

Answer 2

At first before fixing the ins/labeling problem: there are issues with your code #1 and #3. In code #1 you state that all your variables need to have different values. This will not provide a valid solution. In code #1 and #3 you have used the variable L once as container for the variables and once as one element.
I have tested my code with Swish. This is the code:
:- use_module(library(clpfd)).
sum_list([],0).
sum_list([Head|Tail], Sum):-
sum_list(Tail, Sum1),
Sum is Head+Sum1.
kakuro(Vars):-
Vars=[A,B,C,E,F,G,J,K,L,N,O,P],
Vars ins 1..9,
word([A,B,C],24),
word([B,F,J,N],26),
word([C,G,K,O],15),
word([E,F,G],11),
word([A,E],17),
word([J,K,L],22),
word([N,O,P],14),
word([L,P],13),
writeln(Vars).
word(L,Sum):-
labeling([],L),
all_different(L),
sum_list(L,Sum).
This is the (only) output for ?- kakuro(L).:
[9, 8, 7, 8, 2, 1, 9, 5, 8, 7, 2, 5]
At first you need to have the ins/2 predicate running. This should work with SWI prolog. Second you know what to do with the labeling/2 predicate. This one will set values given from their domain (given via ins/2) to the entry. In SWI Prolog the first attribute is a list of options, no need to worry. AFTER labeling your variables you can "test" them and put constraints on them. You can do the labeling once for all variables at the beginning but this is pretty slow because all your progress is lost. So I recommend to do it in the word/2 predicate. If a dead end occurs the backtracking goes back to the word/2 predicate and not to the beginning of the kakuro/1 predicate.