why I am getting error in this bellow code? - oracle

Question

Tables:
CREATE TABLE bus_details
(
bus_name CHAR (15) PRIMARY KEY,
total_seats NUMBER (3),
reserved_seats NUMBER (3)
);
CREATE TABLE busreservation_status
(
bus_name CHAR (15) REFERENCES bus_details (bus_name),
seat_id NUMBER (3),
reserved CHAR (2) CHECK (reserved IN ('y', 'n')),
customer_name CHAR (15)
);
PL/SQL code:
DECLARE
bname CHAR (15);
tot NUMBER (3);
resv NUMBER (3);
total_seats NUMBER (3);
CURSOR cur IS SELECT * FROM bus_details;
BEGIN
INSERT INTO bus_details
VALUES ('&bus_name', total_seats, 0);
OPEN cur;
LOOP
FETCH cur INTO bname, tot, resv;
IF cur%FOUND
THEN
FOR i IN 1 .. tot
LOOP
INSERT INTO busreservation_status
VALUES (bname,
i,
'n',
NULL);
END LOOP;
ELSE
EXIT;
END IF;
END LOOP;
CLOSE cur;
END;
/
Error:
ORA-06502: PL/SQL: numeric or value error

Answer 1

PL/SQL isn't supposed to be interactive with users. If you want to pass something to it, use a procedure with appropriate parameter(s).
If you rewrite code so that it looks like this
note cursor FOR loop instead of explicitly declared cursor which requires opening, declaring cursor variables, fetching, exiting the loop, closing the cursor
setting all required values for bus_details
don't use CHAR datatype unless it makes sense. For e.g. bus name it doesn't, as that datatype right-pads value with spaces up to max column length
Then it works:
SQL> DECLARE
2 l_bus_name VARCHAR2 (15) := 'BMW';
3 l_total_seats NUMBER := 20;
4 l_reserved_seats NUMBER := 5;
5 BEGIN
6 INSERT INTO bus_details (bus_name, total_seats, reserved_seats)
7 VALUES (l_bus_name, l_total_seats, l_reserved_seats);
8
9 FOR cur_r
10 IN (SELECT bus_name, total_seats, reserved_seats FROM bus_details)
11 LOOP
12 FOR i IN 1 .. cur_r.total_seats
13 LOOP
14 INSERT INTO busreservation_status
15 VALUES (cur_r.bus_name,
16 i,
17 'n',
18 NULL);
19 END LOOP;
20 END LOOP;
21 END;
22 /
PL/SQL procedure successfully completed.
Result is:
SQL> select * From bus_details;
BUS_NAME TOTAL_SEATS RESERVED_SEATS
--------------- ----------- --------------
BMW 20 5
SQL> SELECT * FROM busreservation_status;
BUS_NAME SEAT_ID RE CUSTOMER_NAME
--------------- ---------- -- ---------------
BMW 1 n
BMW 2 n
BMW 3 n
BMW 4 n
BMW 5 n
<snip>
BMW 19 n
BMW 20 n
20 rows selected.
SQL>

Answer 2

you have to set some value to the variable total_seats number(3); or prompt input value for total_seats when inserting operation in process:
for example:
Declare
bname Char(15);
tot Number(3);
resv Number(3);
total_seats Number(3) := 15;
Cursor cur Is
Select * From bus_details;
Begin
Insert Into bus_details Values ('&bus_name', total_seats, 0);
Open cur;
Loop
Fetch cur
Into bname, tot, resv;
If cur%Found Then
For i In 1 .. tot Loop
Insert Into busreservation_status Values (bname, i, 'n', Null);
End Loop;
Else
Exit;
End If;
End Loop;
Close cur;
End;
/
OR
Declare
bname Char(15);
tot Number(3);
resv Number(3);
total_seats Number(3);
Cursor cur Is
Select * From bus_details;
Begin
Insert Into bus_details Values ('&bus_name', '&total_seats', 0);
Open cur;
Loop
Fetch cur
Into bname, tot, resv;
If cur%Found Then
For i In 1 .. tot Loop
Insert Into busreservation_status Values (bname, i, 'n', Null);
End Loop;
Else
Exit;
End If;
End Loop;
Close cur;
End;
/

Answer 3

Yes you would need to insert bus_details first, the FK on busreservation_status to bus_details requires it. Further there are additional suggested changed.
Drop column reserved_seats from bus_details. This column is fully
derivable from busreservation_status and typically maintaining a
running count is just not worth the effort. But having it and not
maintaining leads to data errors. For Example: you can have more
seats reserved then the bus has seats.
Drop the column reserved from busreservation_status. This is
derivable from customer_name; if customer_name is not null the seat
is reserved. But assuming you "must keep it" then define is a
virtual column bases on customer_name. This would keep the column in
sync with there being a customer for the seat.
Change char columns to varchar2, and I would change number to
integer.
Create a procedure for setting up a bus (IMO better). The procedure
can be parameterized, not an attempt at user interaction - which
plsql can not do anyway. But whether you create a procedure or keep an anonymous block, there is no need for a loop; a single insert is all that is needed.
With the above in place we arrive at:
create table bus_details
(
bus_name varchar2 (15) primary key
, total_seats number (3)
);
create table busreservation_status
(
bus_name varchar2 (15) references bus_details (bus_name)
, seat_id number (3)
, customer_name varchar2 (15)
, reserved varchar2 (1) generated always as
( case when customer_name is null then 'n' else 'y' end) virtual
, constraint busreservation_status_pk
primary key (bus_name,seat_id)
);
create or replace
procedure define_bus(bus_name_in bus_details.bus_name%type
,seats_in bus_details.total_seats%type
)
is
begin
insert into bus_details(bus_name, total_seats)
values (bus_name_in, seats_in);
insert into busreservation_status(bus_name, seat_id)
select bus_name_in, level
from dual connect by level <= seats_in;
end ;
For quick look at the bus states at summary and detail level you can create views. The demo also includes a couple.