What's the best SAS PROC SURVEYSELECT options for accomplishing a semi-controlled random set? - random

Question

The scenario I'm working with is creating a macro that takes in a data set and produces a random stratified sample, the stratification should be by the column STATE that also needs equal total number of representation (when possible) when creating the random sample.
The size of the sample needed has some set rules that we have to abide by which are:
If the total data set size is <= 50 then let the sample size = the entire data set
Else if the total data set size is between 51 and 500 then let the sample size = 50
Else if the total data set size is between 501 and 999 then let the sample size = 10% of the total data set size (n*.10) given that n = the total data set size.
Else if the total data set size is > 999 then let the sample size = 100
SAMPLESIZE is currently defined in code as:
/*sets sample size in accordance to standards*/
%if &num>=0 and &num<=50 %then %let samplesize=&num;
%else %if &num<501 %then %let samplesize=50;
%else %if &num<1000 %then %let samplesize=%sysevalf((&num*.10),ceil);
%else %let samplesize=100;
The data set I used for testing has a total number of records of 550 (so the sample size needed would be 55) with each state totaling the following number:
IN = 100
KY = 217
MO = 189
OH = 8
WI = 36
Applying the STRATA option for SURVEYSELECT works great when each state has the minimum number needed to satisfy the sample size. In this case the SAMPLESIZE for each STRATA would be 11
You can see that the OH STRATUM does not satisfy the minimum requirement for the SAMPLESIZE here since there is only 8 records with OH in the data set, hence leading to the following error:
ERROR: The sample size, 11, is greater than the number of sampling units, 8.
UPDATE (7/14/21) I was able to resolve the error by using the SELECTALL option, I was also able to grab from other states to fill in the missing records for OH using the ALLOC option for STRATA, so my updated SURVEYSELECT statement now looks like this.
```PROC SURVEYSELECT DATA=UniqueList OUT=UniqueListsamp METHOD=SRS SAMPSIZE=&samplesize
SELECTALL NOPRINT;
STRATA PROVIDER_STATE / ALLOC=(.2 .2 .2 .2 .2) ;
RUN;```
What I would like to achieve in this scenario is to make the ALLOC option function in a way that would be able to handle any number of states found in the input file. My understanding is the option requires hard coded decimals that add up to 1, dependent on the number of strata used (in this case 5, so 1/5 would be 5 instances of .2 that add up to a total of 1). This works great if we know the total number of states ahead of time, but that will not be the case when the code gets implemented for use. Is there a way to do a calculation (1 / num of states = .2) then input that value as many times as the number of states found seperated by a comma or a space (.2 .2 .2 .2 .2) into the ALLOC option?

Answer 1

You can pass a dataset as the argument to SAMPSIZE in surveyselect. I think that's what you need here.
Taking your counts as a starting point, I first just create a dataset matching your actual input. Then I run a tabulate to get your counts back. Then I parse the tabulate to figure out how many to pull, and how many per state, and make sure it's not asking for too many. This gives us a first idea of what's going to be pulled per state, and gives us a dataset that lets us modify that number.
The question of how to pull those last 3 is complicated, because it's not straightforward - how do you want to pull those 3? Should you pick the states "randomly" to add one to? What if a state only had 1 left, and you actually want 3 per state? It gets a bit messy to do this, and if you're not doing this frequently, it might be easier to just do it analytically. A proper system will have detailed checks, several passes, and the assumption that everything that can go wrong, will.
In this example I just go ahead and take the "extra" - so I sample 56. That gets you very close to your sample desired while sticking to your sampling plan ratios evenly and not having different amounts per state (among those states that can). If you want to actually sample 55 exactly, you need to decide how to allocate that 12th - to the 3 largest states? To three random states? Up to you, but the work is similar.
data for_gen;
input state $ count;
do id = 1 to count;
state_id = cats(state,put(id,z3.));
output;
end;
keep state state_id;
datalines;
IN 100
KY 217
MO 189
OH 8
WI 36
;;;;
run;
*create a listing, including the overall row (which will be on top);
proc tabulate data=for_gen out=state_counts(keep=state n);
class state;
table (all state),n;
run;
*now distribute the sample, first pass;
data sample_counts;
set state_counts nobs=statecount end=eof;
retain total_sample sample_per_state states_left;
if _n_ = 1 then do;
*the sample size rules;
if n lt 500 then total_sample = min(50,n);
else total_sample = min(100,floor(n/10));
*how many per state;
sample_per_state = ceil(total_sample/(statecount-1)); *or maybe floor?;
end;
else do;
*here we are in the per-state section;
_NSIZE_ = min(n,sample_per_state);
*allocate sample amounts, remove the used sample quantity from the total quantity, and keep track of how many states still have sample remaining;
total_sample = total_sample - _NSIZE_;
if n ne _nsize_ then states_left+1;
end;
*save the remaining info in macro variables to use later;
if eof then do;
call symputx('sample_left',total_sample);
call symputx('states_left',states_left);
end;
if state ne ' ' then output;
run;
*allocate the remaining sample - we assume we want "at least" the sample count;
data sample_secondpass;
set sample_counts end=eof;
retain total_sample_left &sample_left.
total_states_left &states_left.
leftover 0
;
if total_sample_left gt 0 and total_states_left gt 0 then do;
per_state = ceil(total_sample_left/total_states_left);
if n gt (_nsize_ + per_State) then do;
_nsize_ = _nsize_ + per_state;
end;
else do;
leftover = leftover + (_nsize_ + per_state - n);
_nsize_ = n;
end;
end;
if eof then call symputx('leftover',leftover);
run;
* Use the sample counts dataset to run the surveyselect;
proc surveyselect sampsize=sample_secondpass data=for_gen;
strata state;
run;