vfox pro expression to check string exist - visual-foxpro

Question

I have the following expression
IIF(LABELS.NAME==PARTS.ANAME,IIF(!EMPTY(PARTS.BNAME),"B NAME IS:"+PARTS.BNAME,""),"A NAME IS :" +PARTS.ANAME)
The expression check two fields for matching words for example
field LABELS.NAME: hello
field PARTS.BNAME: hello
field PARTS.ANAME: value
if a match is found it will print "B Name IS: " + the value of BNAME else it will print whatever value is in ANAME.
I am trying to do something so that it will still find a match if
1- the word hello is in BNAME but upper case or mix upper and lower case, and if there is another word or more next to it so for example
field LABELS.NAME: hello world!
field PARTS.BNAME: hello
then it's a match!
or vice versa
field LABELS.NAME: hello
field PARTS.BNAME: hello world

Answer 1

your expression and your explanation are not clear nor correct. Let's break down your expression:
IF LABELS.NAME is an EXACT match of PARTS.ANAME:
Select "B NAME IS:"+PARTS.BNAME or if blank select ""
ELSE:
"A NAME IS :" +PARTS.ANAME
Basically, you are saying if name and aname match, select bname.
As for your explanation, it is unclear whether you are checking for one-word match only, or each word matching?
Try running this and see if it is more in line with what you are looking for:
CLEAR
CREATE CURSOR labels (name c(20))
INSERT INTO labels VALUES ("hello WORLD!")
INSERT INTO labels VALUES ("hello")
CREATE CURSOR parts (aname c(20), bname c(20))
INSERT INTO parts VALUES ("aname value","hello")
INSERT INTO parts VALUES ("aname value2","hello world")
GOTO TOP IN labels
GOTO TOP IN parts
=domatch()
SKIP IN parts
=domatch()
SKIP IN labels
SKIP -1 IN parts
=domatch()
SKIP IN parts
=domatch()
FUNCTION domatch()
? "LABELS Record " + TRANSFORM(RECNO("labels")) + " " + "PARTS Record " + TRANSFORM(RECNO("parts"))
? "LABELS.Name:" + labels.name
? "PARTS.Aname:" + parts.aname
? "PARTS.Bname:" + parts.bname
? "---------------------------"
? IIF(ALLTRIM(UPPER(labels.name)) $ UPPER(parts.bname),"B NAME IS: " + parts.bname + " (name is contained in labels bname)", "A NAME IS: " + parts.aname+ " (NO match, here's aname value)")
? IIF(ALLTRIM(UPPER(parts.bname)) $ UPPER(labels.name),"B NAME IS: " + parts.bname + " (bname is contained in labels name)", "A NAME IS: " + parts.aname+ " (NO match, here's aname value)")
?
The key to the above example is the use of:
$ operator : cSearchFor $ cSearchIn
ALLTRIM() : left and right trim
UPPER() : convert both strings to uppercase for matching
HTH

Answer 2

Your problem is not very clear.
Likely it is not something that you can solve using operators like $, and functions like trim(), upper() etc. BUT it may be and you might have failed to explain it clearly. For eaxample, if BName is "Chello" and Labels have "Hello" or "Hello World" is it a match for BName? I thought it is not. "Hello" is a match but "Chello" is not, right? Unfortunately you didn't give any sample data.
The solution sounds to be scary, using VFP and be very slow. Hoping your parts and labels data do not have much data in them, it could be solved with xbase + alines or using regular expressions.
Although this looks very ugly and would be slow, I think the original design of data is ugly.
Create Cursor labels (Name c(20))
Insert Into labels Values ("hello WORLD!")
Insert Into labels Values ("HellO")
Insert Into labels Values ("way")
Create Cursor parts (Id i Autoinc, aname c(20), bname c(20))
Insert Into parts (aname, bname) Values ("aname value1","hello")
Insert Into parts (aname, bname) Values ("aname value2","hello world")
Insert Into parts (aname, bname) Values ("aname value3","HeLlo world")
Insert Into parts (aname, bname) Values ("aname value4","Hello World")
Insert Into parts (aname, bname) Values ("aname value5","Hello There")
Insert Into parts (aname, bname) Values ("aname value6","My World")
Insert Into parts (aname, bname) Values ("aname value7","World Fair")
Insert Into parts (aname, bname) Values ("aname value8","Two way")
Insert Into parts (aname, bname) Values ("aname value9","Chello")
Insert Into parts (aname, bname) Values ("aname value10","worlds")
Local oRegEx
oRegEx = Createobject("VBScript.RegExp")
oRegEx.IgnoreCase = .T.
oRegEx.Global = .T.
Select p.ID, p.AName, p.BName, ;
Cast(Iif(IsNull(tmp.Id), 'AName is:' + AName, 'BName is:' + BName) as c(30)) dummy ;
from parts p ;
left join ;
(Select distinct p2.ID from parts p2 ;
inner join labels lb ;
on IsSpecialMatch(m.oRegEx, p2.bname, lb.Name)) tmp ;
on tmp.Id = p.Id
Procedure IsSpecialMatch(toRX, tcValue1, tcValue2)
Local IsMatch
toRX.Pattern = '\b'+Trim(m.tcValue1)+'\b'
IsMatch = toRX.Test( m.tcValue2 )
If !IsMatch
toRX.Pattern = '\b'+Trim(m.tcValue2)+'\b'
IsMatch = toRX.Test( m.tcValue1 )
Endif
Return m.IsMatch
Endproc