E2153 ';' not allowed before 'ELSE' [duplicate] - delphi-xe

Question

This question already has answers here:
Can I use an If statement inside a While statement?
(3 answers)
Closed last year.
When I compile my schedule:
procedure TForm1.FormCreate(Sender: TObject);
var
Speed: Double;
myStringList: TStringList;
b: array[0..512] of Char;
Memory: tMemoryStatus;
i : Integer;
begin
Speed := GetCPUSpeed;
myStringList := TStringList.Create;
TIdStack.IncUsage;
GetTempPath(511,b);
memory.dwLength := sizeof(memory);
GlobalMemoryStatus(memory);
i := Languages.IndexOf(SysLocale.DefaultLCID);
try
myStringList.Add('IP: ' + GStack.LocalAddress);
finally
TIdStack.DecUsage;
end;
If waveOutGetNumDevs > 0 then myStringList.Add('Scheda Audio: Presente');
else myStringList.Add('Scheda Audio: Assente');
myStringList.Add('');
Memo1.Lines.Assign(myStringList);
myStringList.Free;
end;
It gives me this error:
[DCC Error] Unit1.pas(198): E2153 ';' not allowed before 'ELSE'
on this line:
else myStringList.Add('Scheda Audio: Assente');

Answer 1

This is covered in Delphi's documentation:
Declarations and Statements (Delphi): If Statements
Notice that a semicolon between the then clause and the word else is never used. You can place a semicolon after an entire if statement to separate it from the next statement in its block, but the then and else clauses require nothing more than a space or carriage return between them. Placing a semicolon immediately before else (in an if statement) is a common programming error.
Also related:
Declarations and Statements (Delphi): Compound_Statements
A compound statement is a sequence of other (simple or structured) statements to be executed in the order in which they are written. The compound statement is bracketed by the reserved words begin and end, and its constituent statements are separated by semicolons. For example:
begin
Z := X;
X := Y;
X := Y;
end;
The last semicolon before end is optional. So this could have been written as:
begin
Z := X;
X := Y;
Y := Z
end;
A common misconception for Delphi is that semicolon is a statement terminator. In some languages, like C/C++, that is true. But in Delphi, that is not true. Semicolon is a statement separator instead. There is a subtle difference. You have to place a semicolon between consecutive statements, but you DO NOT need to place a semicolon at the end of a statement when it is the last statement in an enclosing block.
This is even mentioned in the documentation for the error message in question:
E2153 ';' not allowed before 'ELSE' (Delphi)
You have placed a ';' directly before an ELSE in an IF-ELSE statement. The reason for this is that the ';' is treated as a statement separator, not a statement terminator - IF-ELSE is one statement, a ';' cannot appear in the middle (unless you use compound statements).
...
The Delphi language does not allow a ';' to be placed directly before an ELSE statement. In the code above, an error will be flagged because of this fact.
...
There are two easy solutions to this problem. The first is to remove the offending ';'. The second is to create compound statements for each part of the IF-ELSE...
On a side note: you need to protect your TStringList with a try..finally block. And the call to TIdStack.IncUsage() should be moved directly above the try of the finally that calls TIdStack.DecUsage().
Try something more like this:
procedure TForm1.FormCreate(Sender: TObject);
var
Speed: Double;
myStringList: TStringList;
b: array[0..MAX_PATH] of Char;
Memory: tMemoryStatus;
i : Integer;
begin
myStringList := TStringList.Create;
try
Speed := GetCPUSpeed;
// add Speed to myStringList as needed...
GetTempPath(MAX_PATH, b);
// add b to myStringList as needed...
memory.dwLength := sizeof(memory);
GlobalMemoryStatus(memory);
// add memory info to myStringList as needed...
i := Languages.IndexOf(SysLocale.DefaultLCID);
// add language info to myStringList as needed...
TIdStack.IncUsage;
try
myStringList.Add('IP: ' + GStack.LocalAddress);
finally
TIdStack.DecUsage;
end;
if waveOutGetNumDevs > 0 then
myStringList.Add('Scheda Audio: Presente')
else
myStringList.Add('Scheda Audio: Assente');
myStringList.Add('');
Memo1.Lines.Assign(myStringList);
finally
myStringList.Free;
end;
end;