Find Nth Occurrence of Largest Value in a row - google-sheets-formula

Question

I have some basic data on a rugby game, to be used in a scouting report. I need to:
Show which players have the highest PITA count (sum of all their other actions)
And
Show those players' 3 highest count actions - column headers are the different actions.
Pic of Dataset
The first half of my task was accomplished by the following index formula:
=if(C25=C24,index(C3:C17,small(if(large(B3:B17,2)=B3:B17,row(B3:B17)-2),2)), vlookup(large(B3:B17,2),B3:C17,2,false))
I've gotten the 3 players ranked by highest PITA count, which also includes tied values, as seen in the pink/salmon colored box. I was able to take the "Nth" value, so Player #2 and Player #8 are both shown correctly in 2nd and 3rd place, even though they have the same PITA value. Rather than Player #2 be shown twice since the Large function is looking for the same value.
I'd like to achieve similar to above, but display which type of action (column headers) is the player's 1st, 2nd, and 3rd most completed actions (blue columns). I am having trouble replicating the above formula to work horizontally and choose the correct column. Similar to above, I need it to be able to take the Nth value. The yellow highlighted row is an example of my problem, as I'd like it to show Ruck Disruption and then Tackler in the 1st Highest Action and 2nd Highest Action column, rather than it showing Ruck Disruption twice.
This is where I've gotten with said formula:
=if(large($E4:$L4,1)=0,"",index($E$2:$L$2,,match(large($E4:$L4,2),$E4:$L4,0)))
Link to spreadsheet: https://docs.google.com/spreadsheets/d/1P2msjxofWR8wfwjbfPYQexEzLEMSwVCwX5wNJUACZHI/edit?usp=sharing
Thanks in advance for any help.
Tried:
=if(large($E4:$L4,1)=0,"",index($E$2:$L$2,,match(large($E4:$L4,2),$E4:$L4,0)))
but keeps returning the first instance of "1" and therefore giving me Ruck Disruption instead of Tackler.

Answer 1

The way the get the player place seems may not have considered situation such as when there are two 1st place and two 2nd place, or even three 1st place, etc.
the formula below will take in all combinations and return PITA rank, PITA Count, and PlayerNumber as an arrary, it gives dinamic result, so that when player score the same PITA, they will be named as the same place, and can exceed 3 place if more than 3 same score appears:
=
LAMBDA(PLAYER,PITA,
LAMBDA(UPITA,
LAMBDA(UPITACOUNT,
LAMBDA(UPITACOUNT,
LAMBDA(RESULT_1,RESULT_2,RESULT_3,
LAMBDA(FIRST,SECOND,THIRD,
QUERY({
FIRST;
IF(COUNTA(INDEX(FIRST,,1))<3,SECOND,{"","",""});
IF(COUNTA(INDEX(FIRST,,1))+COUNTA(INDEX(SECOND,,1))<3,THIRD,{"","",""})
},"WHERE Col1 IS NOT NULL LABEL Col1'PITA rank',Col2'PITA Count',Col3'PlayerNumber'",0)
)(
MAKEARRAY(COUNTA(INDEX(RESULT_1,,1)),3,LAMBDA(ROW,COL,IFS(COL=1,"1st",TRUE,INDEX(RESULT_1,ROW,COL-1)))),
MAKEARRAY(COUNTA(INDEX(RESULT_2,,1)),3,LAMBDA(ROW,COL,IFS(COL=1,"2nd",TRUE,INDEX(RESULT_2,ROW,COL-1)))),
MAKEARRAY(COUNTA(INDEX(RESULT_3,,1)),3,LAMBDA(ROW,COL,IFS(COL=1,"3rd",TRUE,INDEX(RESULT_3,ROW,COL-1))))
)
)(
FILTER({PITA,PLAYER},PITA=INDEX(UPITACOUNT,1,1)),
FILTER({PITA,PLAYER},PITA=INDEX(UPITACOUNT,2,1)),
FILTER({PITA,PLAYER},PITA=INDEX(UPITACOUNT,3,1))
)
)(SORT({UPITA,COUNTIF(PITA,INDEX(UPITA,,SEQUENCE(UPITACOUNT)))},1,0))
)(COUNTA(UPITA))
)(UNIQUE(PITA))
)($C$3:$C$17,$D$3:$D$17)
one 1st and three 2nd:
two 1st and one 2nd:
five top:
more than one 3rd:
And this formula will return 3 results of the highest score actions of each player:
=ArrayFormula(
LAMBDA(DATA,
LAMBDA(TITLES,VALUES,
LAMBDA(RESULTS,
RESULTS
)(
BYROW(VALUES,LAMBDA(SCORE,
TRANSPOSE(IFNA(QUERY(SORT(TRANSPOSE({TITLES;SCORE}),2,0),"SELECT Col1 WHERE Col2>0 LIMIT 3",0),""))
))
)
)(INDEX(DATA,1),MAKEARRAY(COUNTA(INDEX(DATA,,1))-1,COUNTA(INDEX(DATA,1)),LAMBDA(ROW,COL,INDEX(DATA,ROW+1,COL))))
)($E$2:$L$17)
)