trying to understand nested brackets in sed script - bash

Question

/^Host.*latency.*/{
$!N
/MAC Address/{
s/.*(\(.*\)) .*MAC Address: \(.*\) .*/\1 -> \2/
}
}
/[Nn]map/d
s/^Host .*is up/& but MAC Address cannot be found/
I am trying to understand sed script as above.Can some one help me to understand I never used sed as above.
Its use is
nmap -sP 192.168.1.0/20 | sed -f sedcript.sh

Answer 1

If you mean the nested parentheses in (\(.*\)). The outer pair are literal and the inner, escaped pair capture the string matched by the enclosed regular expression. The backreference \1 outputs this captured string. The \2 backreference outputs the string captured by the second pair of escaped parentheses.
If you mean the curly braces, they surround blocks of commands. The outer group says that if the line matches ^Host.*latency.* then execute the enclosed command. The $!N command appends the next line of the file if the current line isn't the last. If the combination of the lines matches MAC Address then the block inside the next pair of curly braces is executed (the substitution is performed).
You can read it like this:
/^Host.*latency.*/{ - If the line matches this regex, then
$!N - Append the next line if the current line isn't the last line
/MAC Address/{ - If the combined lines match this regex, then
s/.*(\(.*\)) .*MAC Address: \(.*\) .*/\1 -> \2/ - Make this substitution
} - End if
} - End if
/[Nn]map/d - If the pattern space (combined lines) matches this, then delete it
s/^Host .*is up/& but MAC Address cannot be found/ - Make this substitution