ColorFunctionScaling example from Mathematica help fails - why? - wolfram-mathematica

Question

There is an example in the Mathematica 7 help for Plot > Options > ColorFunctionScaling.
Table[Plot[Sin[4 Pi x], {x, 0, 1/2}, PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, Hue[x]],
ColorFunctionScaling -> cf], {cf, {False, True}}]
When I evaluate it myself on Mathematica 7, both output plots look like the one on the left.
However, if I evaluate this, I get the plot on the right, as shown above:
Plot[Sin[4 Pi x], {x, 0, 1/2}, PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, Hue[x]],
ColorFunctionScaling -> True]
Why might the example as given fail?
Alexey and Simon demonstrated that this is not the result of HoldAll, as I presumed before.
The existence of the example leads me to suspect it once worked, and the information that it works on version 8 tells me that the behavior has changed. What precisely has changed?

Answer 1

Your question is really interesting. The mentioned method of supplying option values to built-in functions is widely used in the Documentation. The fact that it fails only for ColorFunctionScaling looks like a bug. And information that in v.8 this problem does not exist confirms that this is a bug in v.7.
In any way consider the following:
In[1]:= SetAttributes[f, HoldAll]
f[__, OptionsPattern[ColorFunctionScaling -> False]] :=
OptionValue[ColorFunctionScaling]
Table[f[Sin[4 Pi x], {x, 0, 1/2},
ColorFunctionScaling -> cf], {cf, {False, True}}]
Out[3]= {False, True}
You can see that HoldAll attribute in really does not prevent substituting of cf.
In this way, it is really interesting what was the cause of described buggy behavior of Plot with Table in v.7?

Answer 2

The evaluation order seems slightly out. It works if you force cf to be substituted in before the Plot command is looked at. To do this we use the With[{x=x},...] construct:
Table[With[{cf = cf},
Plot[Sin[4 Pi x], {x, 0, 1/2}, PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, Hue[x]],
ColorFunctionScaling -> cf]], {cf, {False, True}}]
It's strange that you don't need such a kludge in Mathematica version 8.
It's even stranger that the Mathematica 7 documentation has an example where the pre-evaluated graphics does not match what is produced by that version. (Nice find, btw)

Answer 3

This bug in fact is related to the HoldAll attribute, but I was fooled by this auto-load issue into thinking it was not. This can be seen by executing this:
Plot[Sin[x], {x, 0, Pi}];
Unprotect[Plot]
ClearAttributes[Plot, HoldAll]
Table[Plot[Sin[4 Pi x], {x, 0, 1/2}, PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, Hue[x]],
ColorFunctionScaling -> cf], {cf, {False, True}}]
The first Plot is needed to activate the package load.
One can therefore get the correct behavior by wrapping ColorFunctionScaling -> ... in Evaluate:
Table[Plot[Sin[4 Pi x], {x, 0, 1/2}, PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, Hue[x]],
Evaluate[ColorFunctionScaling -> cf]], {cf, {False, True}}]