How to implement a decision matrix in Delphi - algorithm

Question

I have to implement a decision matrix in Delphi 7.
The function is
CalcNewStatus( actionCode: string; reportType: string; currentStatus: string): string;
ActionCode can have the values 'A' and 'N'
ReportType can have the values 'I' and 'F'
CurrentStatus can have the values 'P', 'I', 'F'.
In C# I would use a dictionary, for example. How can I do this in Delphi 7?

Answer 1

Normalize your input characters to zero-based ordinal values and things become much easier. Start with a few type declarations:
type
TActionCode = (acA, acN);
TReportType = (rtI, rtF);
TStatus = (sP, sI, sF);
Then you can define an array using those types with all possible status values. Replace sX with whichever status value belongs in each spot.
const
NextStatus: array[TActionCode, TReportType, TStatus] of TStatus = (
{acA} (// sP, sI, sF
{rtI} ( sX, sX, sX),
{rtF} ( sX, sX, sX)
),
{acN} (
{rtI} ( sX, sX, sX),
{rtF} ( sX, sX, sX)
)
);
Then your function is simply this:
function CalcNewStatus(const actionCode, reportType, currentStatus: string): string;
var
ac: TActionCode;
rt: TReportType;
s: TStatus;
const
StateChars: array[TState] of Char = ('P', 'I', 'F');
begin
Assert(actionCode <> ''); Assert(reportType <> ''); Assert(currentStatus <> '');
Assert(actionCode[1] in ['A', 'N']);
Assert(reportType[1] in ['I', 'F']);
Assert(currentStatus[1] in ['P', 'I', 'F']);
if actionCode[1] = 'A' then ac := acA else ac := acN;
if reportType[1] = 'I' then rt := rtI else rt := rtF;
if currentStatus[1] = 'P' then s := sP
else if currentStatus[1] = 'I' then s := sI
else s := sF;
Result := StateChars[NextStatus[ac, rt, s]];
end;
As you can see, most of this code is spent converting between strings and the enum types. If you can, avoid strings in this case. Switch to the enum types as early in your program as possible, and only convert back to strings or characters when you absolutely need to. Strings can have arbitrary length, which you really shouldn't have to deal with, and strings can also have values outside the range you've defined. Enums can't, unless you do something weird. Furthermore, the compiler won't let you accidentally use a TState value where a TReportType is expected, which will help you from confusing your I's and F's.

Answer 2

First of all in such a limited case (2 ActionCodes, 2 ReportTypes, 3 Statuses) I should definitely use enumerated types instead of strings.
And for the decision matrix ... a matrix:
Type
TActionCode = (taA, taN);
TReprotType = (rtI, rtF);
TStatus = (stP, stI, stF);
const
NewStatus: array [TActionCode, TReportType, TStatus] of TStatus =
((((,,)),((,,))),(((,,)),((,,)))) // values of the new statuses here

Answer 3

There is one solution that uses a single-dimensional array.
unit XnResultStatusOverride;
interface
function XnCalcOverridenResultStatus(
actionCodeStr: string;
reportTypeStr: string;
currentStatusStr: string ): string;
implementation
uses SysUtils;
type
TActionCodes = ( ActionCodeA = 0, ActionCodeN = 1);
TReportTypes = (ReportTypeI = 0, ReportTypeF = 1);
TResultStatus = (ResultStatusP = 0, ResultStatusF = 1, ResultStatusI = 2);
const
DecisionMatrix: array[ 0 .. 15 ] of TResultStatus
=
(
ResultStatusF, // 0 A-I-P
ResultStatusF, // 1 A-I-F
ResultStatusF, // 2 A-I-I
ResultStatusF, // 3 N/A
ResultStatusP, // 4 A-F-P
ResultStatusP, // 5 A-F-F
ResultStatusF, // 6 A-F-I
ResultStatusF, // 7 N/A
ResultStatusF, // 8 N-I-P
ResultStatusF, // 9 N-I-F
ResultStatusP, // 10 N-I-I
ResultStatusF, // 11 N/A
ResultStatusF, // 12 N-F-P
ResultStatusI, // 13 N-F-F
ResultStatusF, // 14 N-F-I
ResultStatusF // 15 N/A
);
function ParseActionCodeString( value: string ): TActionCodes;
begin
if value = 'A' then
begin
result := ActionCodeA;
exit;
end;
if value = 'N' then
begin
result := ActionCodeN;
exit;
end;
raise Exception.Create('Invalid action code string' );
end;
function ParseReportTypeString( value: string ): TReportTypes;
begin
if value = 'I' then
begin
result := ReportTypeI;
exit;
end;
if value = 'F' then
begin
result := ReportTypeF;
exit;
end;
raise Exception.Create('Invalid report type string' );
end;
function ParseResultStatusString( value: string ): TResultStatus;
begin
if value = 'P' then
begin
result := ResultStatusP;
exit;
end;
if value = 'F' then
begin
result := ResultStatusF;
exit;
end;
if value = 'I' then
begin
result := ResultStatusI;
exit;
end;
raise Exception.Create('Invalid result status string' );
end;
function ResultStatusToString( value: TResultStatus ): string;
begin
if value = ResultStatusP then
begin
result := 'P';
exit;
end;
if value = ResultStatusF then
begin
result := 'F';
exit;
end;
if value = ResultStatusI then
begin
result := 'I';
exit;
end;
raise Exception.Create('Unknown TResultStatus enum member' );
end;
function XnCalcOverridenResultStatus(
actionCodeStr: string;
reportTypeStr: string;
currentStatusStr: string ): string;
var
actionCode: TActionCodes;
reportType: TReportTypes;
currentStatus:TResultStatus;
discriminant: integer;
newStatusInt: integer;
newStatus: TResultStatus;
begin
actionCode := ParseActionCodeString( actionCodeStr );
reportType := ParseReportTypeString( reportTypeStr );
currentStatus := ParseResultStatusString( currentStatusStr );
discriminant := integer(actionCode) * 8 + integer(reportType) * 4 + integer(currentStatus);
newStatusInt := DecisionMatrix[ discriminant ];
newStatus := TResultStatus( newStatusInt);
Result := ResultStatusToString( newStatus );
end;
end.