CGShadingGetBounds() signature? - macos

Question

I am trying to get the signature of method CGShadingGetBounds()?
I tried, CG_EXTERN CGRect CGShadingGetBounds(CGShadingRef); but it does not seem to be a case.
Can someone help figure out the signature?
Below is the disassembly.
__text:000000000016BB76 public _CGShadingGetBounds
__text:000000000016BB76 _CGShadingGetBounds proc near ; CODE XREF: _log_LogShading+1B8p
__text:000000000016BB76 ; _dlr_DrawShading+1FEp ...
__text:000000000016BB76 push rbp
__text:000000000016BB77 mov rbp, rsp
__text:000000000016BB7A mov rax, rdi
__text:000000000016BB7D cmp byte ptr [rsi+28h], 0
__text:000000000016BB81 jz short loc_16BBAC
__text:000000000016BB83 movsd xmm0, qword ptr [rsi+30h]
__text:000000000016BB88 movsd qword ptr [rdi], xmm0
__text:000000000016BB8C movsd xmm0, qword ptr [rsi+38h]
__text:000000000016BB91 movsd qword ptr [rdi+8], xmm0
__text:000000000016BB96 movsd xmm0, qword ptr [rsi+40h]
__text:000000000016BB9B movsd qword ptr [rdi+10h], xmm0
__text:000000000016BBA0 movsd xmm0, qword ptr [rsi+48h]
__text:000000000016BBA5
__text:000000000016BBA5 loc_16BBA5: ; CODE XREF: _CGShadingGetBounds+5Ej
__text:000000000016BBA5 movsd qword ptr [rdi+18h], xmm0
__text:000000000016BBAA pop rbp
__text:000000000016BBAB retn
__text:000000000016BBAC ; ---------------------------------------------------------------------------
__text:000000000016BBAC
__text:000000000016BBAC loc_16BBAC: ; CODE XREF: _CGShadingGetBounds+Bj
__text:000000000016BBAC lea rcx, _CGRectInfinite
__text:000000000016BBB3 movsd xmm0, qword ptr [rcx]
__text:000000000016BBB7 movsd xmm1, qword ptr [rcx+8]
__text:000000000016BBBC movsd qword ptr [rdi], xmm0
__text:000000000016BBC0 movsd qword ptr [rdi+8], xmm1
__text:000000000016BBC5 movsd xmm0, qword ptr [rcx+10h]
__text:000000000016BBCA movsd qword ptr [rdi+10h], xmm0
__text:000000000016BBCF movsd xmm0, qword ptr [rcx+18h]
__text:000000000016BBD4 jmp short loc_16BBA5
__text:000000000016BBD4 _CGShadingGetBounds endp
My aim is to identify the bounds in which shading is going to happen.

Answer 1

I believe the signature you mentioned
CG_EXTERN CGRect CGShadingGetBounds(CGShadingRef);
is correct. For example if you try to reconstruct such function with a custom object, like this:
typedef struct
{
long a1, a2, a3, a4, a5;
char b6;
CGRect r;
} MyObj;
CGRect ReconstructFunc(MyObj *o)
{
if (o->b6) return o->r;
return CGRectNull;
}
of course, this does something different, but the "quick" path (where b6 is non-zero) is very very similar to the original function, in both assembly and in behaviour:
pushq %rbp
movq %rsp, %rbp
movq %rdi, %rax
cmpb $0, 40(%rsi)
je LBB0_2
movq 72(%rsi), %rcx
movq %rcx, 24(%rax)
movq 64(%rsi), %rcx
movq %rcx, 16(%rax)
movq 48(%rsi), %rcx
movq 56(%rsi), %rdx
movq %rdx, 8(%rax)
movq %rcx, (%rax)
popq %rbp
ret
... (continues)
This is basically the same at the assembly you posted. It also implies some "convention" obj-c and Mac GCC uses for compiling methods with CGRect structs. According to the x64 ABI parameters are passed in these registers: RDI, RSI, RDX, (and more). If you take a look at the first two, RDI and RSI, they clearly contains arguments, first one is a pointer to the output struct (CGRect), second one is the opaque struct (CGShadingReg).
Thus I believe that GCC on Mac translates this:
CGRect myrect = MyFuncReturningRect(param);
into this:
CGRect myrect;
MyFuncReturningRect(&myrect, param);
Anyway to sum it all up, I strongly believe your guessed signature is correct. If the function doesn't return values you expect, it is caused by some other factors (probably by the byte ptr [rsi+28h] value, which must be non-null to get some non-dummy information).