I'm trying to create an applescript that prompts for a job name, then a desired directory in which to create a folder with the job name. It then should create a series of subfolders within the initial folder with names such as "job name-Links" & "job name-PDFs" etc.
I've cobbled this script together from different sources & would like feedback on how to improve it, because I'm sure it's ugly as sin.
tell application "Finder"
activate
set jobNum to text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
set folderpath to POSIX path of (choose folder with prompt "Select client folder")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Links")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-PDFs")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Supplied")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Versions")
end tell
Any thoughts & comments would be greatly appreciated. This is my first attempt at a script. I thought I'd post this because I've hunted for this specific use case for ages and only found bits and pieces. Hopefully someone can help me out so other will find it useful too.
Another idea would be to create a template of the desired folder structure somewhere, then have the script copy that structure with the client prefix. A couple of benefits to this method are that you don't need to change the script if folders are added to the template (the handler will also add to existing structures), and you don't have to figure out how to script complex (or large) structures.
property template : "/path/to/template/folder" -- the folder structure to copy from
on run -- example
set jobNum to text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
set folderPath to (choose folder with prompt "Select a location for the client folder")
tell application "Finder" to try
set clientFolder to (make new folder at folderPath with properties {name:jobNum})
on error number -48 -- folder already exists
set clientFolder to (folderPath as text) & jobNum
end try
copyFolderStructure_toFolder_withPrefix_(template, clientFolder, jobNum)
end run
to copyFolderStructure_toFolder_withPrefix_(source, destination, additions) -- copy folder structure using mkdir
set {source, destination} to {source as text, destination as text}
if source begins with "/" then set source to POSIX file source
if destination begins with "/" then set destination to POSIX file destination
set {source, destination} to {source as alias, destination as alias}
set additions to additions as text
tell application "Finder" to set theFolders to (folders of entire contents of source) as alias list
set folderNames to ""
repeat with someFolder in theFolders -- set up the folder names parameter for the shell script
set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ":"}
set namePieces to text items of (text ((count (source as text)) + 1) thru -2 of (someFolder as text))
set AppleScript's text item delimiters to ("/" & additions)
set namePieces to space & quoted form of (additions & (namePieces as text))
set AppleScript's text item delimiters to tempTID
set folderNames to folderNames & namePieces
end repeat
do shell script "cd " & quoted form of POSIX path of destination & "; mkdir -p" & folderNames
end copyFolderStructure_toFolder_withPrefix_
You can do something like this:
set TID to AppleScript's text item delimiters
-- Ensure the answer is formatted properly
repeat
try
set theAnswer to text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
set AppleScript's text item delimiters to "-"
set {jobNum, jobDes} to {text item 1 of theAnswer, text item 2 of theAnswer}
exit repeat
on error
display dialog "Please enter your response in this format [JobNumber]-[Description]" buttons {"Cancel", "Try again"} default button "Try again"
end try
end repeat
set folderpath to POSIX path of (choose folder with prompt "Select client folder")
set folderNames to {"-Links", "-PDFs", "-Supplied", "-Versions"}
repeat with aName in folderNames
do shell script "mkdir -p " & quoted form of (folderpath & jobNum & "-" & jobDes & "/" & jobNum & "-" & jobDes & aName as text)
end repeat
set AppleScript's text item delimiters to TID
mkdir can create a hierarchy, just put these names in the {}
Example : '/destFolderPath/jobName/prefix'{"suffix1","suffix2","suffix3","suffix4"}
Here is the script.
set jName to my getJobNum()
set folderpath to POSIX path of (choose folder with prompt "Select client folder")
do shell script "mkdir -p " & (quoted form of (folderpath & jName & "/" & jName)) & "{\"-Links\",\"-PDFs\",\"-Supplied\",\"-Versions\"}"
on getJobNum()
activate
text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
tell the result to if it is not "" then return it
getJobNum() -- else text returned is empty
end getJobNum
Important, if you plan to have slashes in the name, you must replace them by the colon character, it's easy to add a handler in the script to replace them, otherwise it will create other subfolders.
I'm no scripter, but I was looking for the same kind of structured folder solution. After going over these other examples, I came up with a slightly modified version for setting up project folders for our group of designers.
set TID to AppleScript's text item delimiters
-- Ensure the answer is formatted properly
repeat
try
set theAnswer to text returned of (display dialog "Please create a job folder, with the name in this format:" default answer "JobNumber-JobCode-ClientDescription")
set AppleScript's text item delimiters to "-"
set {jobNum, JobCod, CliDes} to {text item 1 of theAnswer, text item 2 of theAnswer, text item 3 of theAnswer}
exit repeat
on error
display dialog "Please enter your job details in this format [JobNumber]-[JobCode]-[ClientDescription]" buttons {"Cancel", "Try again"} default button "Try again"
end try
end repeat
set folderpath to POSIX path of (choose folder with prompt "Where to create your project folder?")
set folderNames to {"Links", "Client_input", "SourceBuilds", "Review-Proofs"}
repeat with aName in folderNames
do shell script "mkdir -p " & quoted form of (folderpath & jobNum & "-" & JobCod & "-" & CliDes & "/" & aName as text)
end repeat
set AppleScript's text item delimiters to TID
I'm using a variant of jackjr300 script to generate a website folder template/
do shell script "mkdir -p " & (quoted form of (folderpath & jName & "/")) & "{\"codey\",\"js\",\"fonts\",\"images\"}"
Plus another run to generate the subfolders and populate those with an existing frameworks and scripts with a duplicate folder action.
Very handy Thanks ...!
The first thing you could do to improve your script is don’t use shell scripting. Shell scripting is like a jackhammer, but what you are doing only requires the tiniest hand-held hammer.
Here is your original script:
tell application "Finder"
activate
set jobNum to text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
set folderpath to POSIX path of (choose folder with prompt "Select client folder")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Links")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-PDFs")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Supplied")
do shell script "/bin/mkdir -p " & quoted form of folderpath & "/" & quoted form of (jobNum) & "/" & quoted form of (jobNum & "-Versions")
end tell
Compare to a “de-shelled” version, which is easier to read, write, and maintain:
tell application "Finder"
activate
set jobNum to text returned of (display dialog "Enter a job number:" default answer "[JobNumber]-[Description]")
set theClientFolder to (choose folder with prompt "Select client folder")
set theSubFolderNames to {"Links", "PDFs", "Supplied", "Versions"}
repeat with theSubFolderName in theSubFolderNames
make new folder at theClientFolder with properties {name:jobNum & "-" & theSubFolderName}
end repeat
end tell
Notice that the variable “folderpath” has changed to “theClientFolder” because choose folder does not return a path, it returns an alias object for the chosen folder. The command for telling Finder to make a new folder is “make new folder at [alias where you want the folder to be made]” so you don’t need to convert that alias into a path to make new folders inside of it.
Notice also that the names of the folders have been declared as variables in a list, which makes them easier to read or change later. Even somebody who does not know AppleScript could open this script and change the name of the “PDFs” folder to “Documents” or something like that.
Another improvement I could suggest would be to make the way that you’re gathering the input from the user a little more sophisticated. You seem to be asking for 2 items of information other than the client folder — job number and job description — so use 2 dialog boxes, because that will be easier for the user and less error-prone because you can give 2 actual examples of what you want them to input. You can also improve the appearance of those dialogs in a few ways. And you can add a little error handling — if the user cancels the dialogs you’re presenting, that generates errors. You can handle them gracefully by checking if the user clicked “OK” or not.
Here is a version of your script with the user input cleaned up a bit:
tell application "Finder"
activate
display dialog "Enter a job number:" default answer "100" buttons {"Cancel", "OK"} default button "OK" with title (the name as text) with icon note giving up after 180
if the button returned of the result is equal to "OK" then
set theJobNumber to the text returned of the result
display dialog "Enter a job description:" default answer "Photos" buttons {"Cancel", "OK"} default button "OK" with title (the name as text) with icon note giving up after 180
if the button returned of the result is equal to "OK" then
set theJobDescription to the text returned of the result
try
choose folder with prompt "Select client folder:" default location (the path to the desktop folder as alias) without multiple selections allowed, invisibles and showing package contents
set theClientFolder to the result
on error
set theClientFolder to ""
end try
if theClientFolder is not equal to "" then
set theSubFolderNames to {"Links", "PDFs", "Supplied", "Versions"}
repeat with theSubFolderName in theSubFolderNames
make new folder at theClientFolder with properties {name:theJobNumber & "-" & theJobDescription & "-" & theSubFolderName}
end repeat
end if
end if
end if
end tell
This will give you dialog boxes that say “Finder” at the top and include the Finder icon, which will give up after 180 seconds (to prevent at timeout error) and which, if the user presses “Cancel” at any point, will just die gracefully without generating any errors. You can tweak the default answers for the input dialogs so that they help the user put in the right input, for example, if job numbers are 4 digits, put a 4 digit number here. And the choose folder prompt will start by showing the Desktop — you can change that to another location if there is a disk or folder where you store all your client folders:
choose folder with prompt "Select client folder:" default location (disk "Clients" as alias) …
To be clear, shell scripting is awesome, but I recommend you only use “do shell script” to get at unique features of the UNIX layer, like PHP functions, Perl regex, and so on. Anything that is already available to you in the Mac layer is going to be easier and safer to use, and easier to read, write, and maintain in AppleScript. Especially really basic things like creating folders.
I have a solution that copies the folder from a template location. It also creates a shortcut that allows to email the design manager with the subject as the job number/project number
global jobNum
global newJobFolder
set jobNum to text returned of (display dialog "Enter a job number:" default answer "")
set jobName to text returned of (display dialog "Enter a job name:" default answer "")
set jobMgr to text returned of (display dialog "Enter account manager email:" default answer "")
set folderpath to (choose folder with prompt "Select client folder")
set newJobFolder to my newFold(jobNum, jobName, folderpath, jobMgr)
on newFold(theNumber, theName, thefolder, jobMgr)
set emailAddress to jobMgr
set emailSubject to theNumber & " -" & theName
set bodyText to ""
set emailLinkFileName to theNumber & " -" & theName
set subNameList to {"Designs", "Documents", "Received"}
set itemCount to count of subNameList
set linkBody to "mailto:" & emailAddress & "?subject=" & my
replace_chars(emailSubject, " ", "%20") & "&body=" & my
replace_chars(bodyText, " ", "%20")
tell application "Finder"
set newJobFolder to (make new folder at thefolder with properties ¬
{name:theNumber & " " & theName})
repeat with i from 1 to itemCount
set aSubFolder to make new folder at newJobFolder with properties {name:jobNum & " " & item i of subNameList}
set theMailto to make new internet location file to linkBody at aSubFolder with properties {name:emailLinkFileName, name extension:"mailloc"}
set the name extension of theMailto to "mailloc"
end repeat
duplicate file "Users:ace:Dropbox:Company:0000-1_E.xlsx" of startup disk to folder (jobNum & " Documents") of newJobFolder
set name of the result to jobNum & " E.xlsx"
set theMailto to make new internet location file to linkBody at newJobFolder with properties {name:emailLinkFileName, name extension:"mailloc"}
set the name extension of theMailto to "mailloc"
end tell
end newFold
-- Generic find and replace functionality
on replace_chars(this_text, search_string, replacement_string)
set AppleScript's text item delimiters to the search_string
set the item_list to every text item of this_text
set AppleScript's text item delimiters to the replacement_string
set this_text to the item_list as string
set AppleScript's text item delimiters to ""
return this_text
end replace_chars
Related
I want to create a simple AppleScript:
define a folder (that will get all the images, docs etc.)
read a file (.txt for example)
download all the URLs into the folder with their original name
Currently, my file has one URL by line, no separator.
I found several scripts but they always do something I don't want, don't need or doesn't work.
I found one that is very close to what I want, but it's editing the names in the loop.
I didn't succeed to split the URL and keep the last part.
Here it is:
property desktopPath : path to desktop as string
set n to 1
repeat with urlLine in paragraphs of (read alias (desktopPath & "filename.txt"))
set qURL to quoted form of urlLine
if qURL ≠ "''" then
set dest to quoted form of ¬
(POSIX path of desktopPath & "URLs/" & n & ".jpg")
do shell script "curl " & quoted form of urlLine & " > " & dest
set n to n + 1
end if
end repeat
If you have any other solution, I take.
Thanks in advance
I found a script that is working fine.
You just need to be sure about the txt file: the list inside should not have any text format.
Weirdly I have to do a copy/paste through a text editor to remove every text format.
1/ Put the txt file on your desktop, 2/ Create a "download" folder on your desktop, 3/ Start the script
set theList to (path to desktop as text) & "Download.txt" -- File name with the URLs
set theFolder to (path to desktop as text) & "download" -- Folder name between quotes
set theFolder to quoted form of POSIX path of theFolder
set theImages to read alias theList as list using delimiter linefeed
repeat with i from 1 to count of theImages
set thisItem to item i of theImages
do shell script "cd " & theFolder & "; " & "curl -O " & quoted form of thisItem
end repeat
someone please explain why this won't work. The script alone without the "if mainReturned = "File" then" works just fine but when I add it to another part of a script, things get weird. It highlights the word "on" on the 5th to last line of the script and then stops working etc. Please explain how I can fix it to add it to another script? The gist of the other script is basically if you enter a word the script will bring certain things up such as if I were to enter the work "File" it performs this. But it won't work. Its the format of if mainReturned = "File" then
nothing really this is kinda the only code I could minimize the script to
set SearchDir to choose folder
set SearchTerm to text returned of ¬
(display dialog "Enter your search term below:" default answer "" with icon file "Macintosh HD:Users:<insert user's name.:Documents:robot-icon.png")
set theResults to SpotlightSearch(SearchTerm, SearchDir)
if theResults is not {""} then
set theChoice to choose from list theResults with prompt ¬
"Here are the files that match the search term \"" & SearchTerm & ¬
"\" in directory \"" & SearchDir & "\":" cancel button name ¬
"Quit" OK button name "Reveal in Finder"
if theChoice is not false then
tell application "Finder"
activate
reveal (POSIX file theChoice) as alias
end tell
end if
else
display dialog "No Results Found." buttons ¬
{"Quit", "Search Again"} default button 2 with icon file "Macintosh HD:Users:<insert user's name>:Documents:robot-icon.png"
if button returned of result is "Quit" then exit repeat
end if
on SpotlightSearch(SearchTerm, SearchDir)
set theResults to paragraphs of ¬
(do shell script "mdfind " & quoted form of SearchTerm & ¬
" -onlyin " & quoted form of POSIX path of SearchDir)
end SpotlightSearch
my expected results is -
if mainReturned = "File" then
display dialog "Keyword '" & mainReturned & "' is being executed..." buttons {"OK"} default button 1 with title "Auto-Web" with icon file "Macintosh HD:Users:<insert user name>:Documents:robot-icon.png" giving up after 1
set SearchDir to choose folder
set SearchTerm to text returned of ¬
(display dialog "Enter your search term below:" default answer "" with icon file "Macintosh HD:Users:<insert user's name.:Documents:robot-icon.png")
set theResults to SpotlightSearch(SearchTerm, SearchDir)
if theResults is not {""} then
set theChoice to choose from list theResults with prompt ¬
"Here are the files that match the search term \"" & SearchTerm & ¬
"\" in directory \"" & SearchDir & "\":" cancel button name ¬
"Quit" OK button name "Reveal in Finder"
if theChoice is not false then
tell application "Finder"
activate
reveal (POSIX file theChoice) as alias
end tell
end if
else
display dialog "No Results Found." buttons ¬
{"Quit", "Search Again"} default button 2 with icon file "Macintosh HD:Users:<insert user's name>:Documents:robot-icon.png"
if button returned of result is "Quit" then exit repeat
end if
on SpotlightSearch(SearchTerm, SearchDir)
set theResults to paragraphs of ¬
(do shell script "mdfind " & quoted form of SearchTerm & ¬
" -onlyin " & quoted form of POSIX path of SearchDir)
end SpotlightSearch
but what really happens is the script highlights the word "on" the 5th to last line of the code and says Syntax Error:Expected “else”, etc. but found “on”. Can someone please make it so this code is compatible with what I am trying to do? It would be most appreciated
There isn't enough context to provide a functioning reply, but you are missing the corresponding end if statement for your added if mainReturned = "File" statement. It helps a bit if you format and/or comment your code to group things together so that you don't get lost.
The error is pretty clear: You have to balance the if statement with an end if before the SpotlightSearch handler
if mainReturned = "File" then
...
if theResults is not {""} then
...
else
...
end if
end if
on SpotlightSearch(SearchTerm, SearchDir)
set theResults to paragraphs of ¬
(do shell script "mdfind " & quoted form of SearchTerm & ¬
" -onlyin " & quoted form of POSIX path of SearchDir)
end SpotlightSearch
Thank y'all so much for your help and being willing to help!!! I have learned so much from y'all and I love this website and the kindness presented on it. I have found the answer. I needed to create a second script and input it into the applications script folder and then use the command run script file " THANK YOU FOR THE HELP!!!!!!
I need to make thousands of folders from columns from excel. I've looked around the internet and have got close, but I need the naming structure to be
"LASTNAME, FIRSTNAME - ID"
Each of those are in a separate column in excel.
I've tried the code below and it works, but the naming structure is not what I want it to be.
display dialog " --Make Lotsa' Folders--
This AppleScript will create multiple folders using names from a text file that you specify."
set destination to (choose folder with prompt "Where would you like to make the folders?")
set textFile to (choose file with prompt "Select the text file you wish to use")
set folderNames to paragraphs of (read textFile)
repeat with oneName in folderNames
tell application "Finder" to make new folder at destination with properties {name:oneName}
end repeat
display dialog "Your folders are done." buttons {"OK"}
https://imgur.com/a/T2ske
https://imgur.com/a/L2al5 This is what the folder filename would be.
Please try this:
set destination to (choose folder with prompt "Where would you like to make the folders?")
tell application "Microsoft Excel" to set usedRange to string value of used range of sheet 1
repeat with i from 2 to (count usedRange)
tell item i of usedRange to set folderName to item 1 & ", " & item 2 & " - " & item 3
tell application "Finder" to make new folder at destination with properties {name:folderName}
end repeat
display dialog "Your folders are done." buttons {"OK"}
As mentioned in the comments the Finder is very very slow while creating the folders one by one, this is a faster solution keeping the way to parse Excel (which is pretty fast by the way) but using the shell mkdir command with a composed parameter list to create the folders.
set destination to (choose folder with prompt "Where would you like to make the folders?")
tell application "Microsoft Excel" to set usedRange to string value of used range of sheet 1
set nameList to {}
repeat with i from 2 to (count usedRange)
tell item i of usedRange to set end of nameList to "'" & item 1 & ", " & item 2 & " - " & item 3 & "'"
end repeat
set {TID, text item delimiters} to {text item delimiters, ","}
set mkdirParams to "/{" & (nameList as text) & "}"
set text item delimiters to TID
do shell script "/bin/mkdir " & quoted form of POSIX path of destination & mkdirParams
display dialog "Your folders are done." buttons {"OK"}
I am looking to make an automator workflow, or applescript (but I am not familiar with the language yet) that can use a list of names (spreadsheet or a .csv) to search a directory and its sub-directories for those specific file names (with varying extensions) and copy that image to a folder created for these images.
I've found a script that seems to be somewhat similar to what I need, but it doesn't search within sub-directories, so I've yet to actually find any images with it.
After extensive research, I've found 2 different scripts that seem to be what I need, but neither of them seem to search sub-directories. Below are the 2 scripts I've tried. If anyone could help me get these to search sub-directories, I would really appreciate it!
Script 1:
set thePhotos to paragraphs of (read (choose file with prompt "Choose a text file"))
set theSourceFolder to (choose folder with prompt "Choose source folder")
set theDestination to (choose folder with prompt "Choose destination folder")
set dupeList to {}
repeat with theName in thePhotos
try
set end of dupeList to alias ((theSourceFolder as text) & theName)
end try
end repeat
tell application "Finder" to duplicate dupeList to theDestination with replacing
set theCount1 to (count of dupeList) as text
set theCount2 to (count of thePhotos) as text
display dialog (theCount1 & " of " & theCount2 & " items copied to " & (theDestination as text)) buttons {"OK"}
Script 2
set fileContents to read (choose file with prompt "Choose a comma-delimited text file")
set theText to result
set AppleScript's text item delimiters to ","
set theTextItems to text items of theText
set AppleScript's text item delimiters to {""}
theTextItems
set theSourceFolder to (choose folder with prompt "Choose source folder") as string
set theDestination to (choose folder with prompt "Choose destination folder")
repeat with theEPSName in theTextItems
tell application "Finder"
set theEPSFile to theSourceFolder & theEPSName
move file theEPSFile to folder theDestination with replacing
end tell
end repeat
So it lets me choose the .csv to use, choose the directory to save and choose the directory to search. How can I get this script to search within sub-directories? And to someone who understands Applescript, does this look like it will function as needed?
Thank you in advance! I really appreciate any help on this, as it is my first Applescript experience, but I am excited to learn it!
This is a very fast solution using the shell and Spotlight searching.
The script creates a search criteria string
'kMDItemFSName == picture1.png || kMDItemFSName == picture2.jpg || ...'
then performs the search and copies all files by passing the found items to the cp command.
There might be a caveat if the name list is too long and exceeds the maximum length of shell parameters.
set theNames to paragraphs of (read (choose file with prompt "Choose a text file" of type "txt"))
set sourceFolder to quoted form of POSIX path of (choose folder with prompt "Choose source folder")
set destinationFolder to quoted form of POSIX path of (choose folder with prompt "Choose destination folder")
set nameList to {}
repeat with aName in theNames
set end of nameList to "kMDItemFSName == " & quoted form of aName
end repeat
set {TID, text item delimiters} to {text item delimiters, " || "}
set nameFilter to quoted form of (nameList as text)
set text item delimiters to TID
do shell script "mdfind -onlyin " & sourceFolder & " -0 " & nameFilter & " | xargs -0 -J {} cp {} " & destinationFolder
I'm trying to make an Applescript that takes a list of names and makes a set of folders from it. And then copies files from a choosen folder into each of these newly created folders.
I have search for the answer, but didn't understand them. So if you could be so kind to explaine what and why I should change the code, it would be a great learning experience for me.
set destinationFolder to choose folder
set {text returned:textReturned} to display dialog "enter folder names" default answer return & return & return
if textReturned is "" then return
set folderWithFiles to (choose folder with prompt "Where are the files at?")
repeat with aLine in (get paragraphs of textReturned)
if contents of aLine is not "" then
do shell script "/bin/mkdir -p " & quoted form of (POSIX path of dest inationFolder & aLine)
set folderNew to aLine & ":" as alias
set dest to folderNew on destinationFolder -- as alias
tell application "Finder"
duplicate every file of folderWithFiles to dest
end tell
end if
end repeat
Thanks in advance
Updated: posted answer to myself
Got help from StefanK at macscripter.net
Here is the complete code:
set destinationFolder to choose folder
set {text returned:textReturned} to display dialog "enter folder names" default answer return & return & return
if textReturned is "" then return
try
set theFiles to (choose file with prompt "Where are the files at?" with multiple selections allowed)
end try
repeat with aLine in (get paragraphs of textReturned)
if contents of aLine is not "" then
set newFolder to (destinationFolder as text) & aLine
do shell script "/bin/mkdir -p " & quoted form of POSIX path of newFolder
try
tell application "Finder" to duplicate theFiles to folder newFolder
end try
end if
end repeat