Filemaker has the ability to ake use of AppleScript.
From within Filemaker I want to create a new folder (with the name of a FileMaker field) that holds 6 subfolders.
I am a complete noob where it comes to Applescript.
This is my script so far:
tell application "FileMaker Pro Advanced"
set folder_name to cell "FolderName" of current record
end tell
tell application "Finder"
activate
make new folder at folder "Desktop" of folder "dick" of folder "Users" of startup disk with properties {name:folder_name}
end tell
tell application "Finder"
activate
make new folder at folder {name:folder_name} of folder "Desktop" of folder "dick" of folder "Users" of startup disk with properties {name:"subfolder"}
end tell
My problem is: the creation of "Subfolder1"
What is my mistake there?
Help is much appreciated
When you crate a new folder you can define various properties, but when refering to the folder just use the name, for example:
make new folder at folder folder_name of folder "Desktop" of folder "dick" of folder "Users" of startup disk with properties {name:"subfolder"}
Note that the result returned from making a new folder is a reference to that folder, so you can also do something like:
tell application "Finder"
set newFolder to (make new folder at folder "Desktop" of folder "dick" of folder "Users" of startup disk with properties {name:folder_name})
make new folder at newFolder with properties {name:"subfolder"}
end tell
Here is another approach:
set myPath to POSIX path of ((path to desktop as text) & folder_name & ":subfolder")
do shell script "mkdir -p " & myPath
Related
I am looking to write an AppleScript to move every file in every folder to another folder.
Currently, this is what I have:
tell application "Finder"
move (get every file of every folder of folder "Source_Folder" of desktop) to folder "Destination_Folder" of desktop
end tell
But this throws an error saying: error "Finder got an error: Can’t get document file \"ALGE71FL.cpg\" of folder \"Destination_Folder\" of folder \"Desktop\" of folder \"THIS_USER\" of folder \"Users\" of startup disk." number -1728 from document file "ALGE71FL.cpg" of folder "Destination_Folder" of folder "Desktop" of folder "THIS_USER" of folder "Users" of startup disk
Where ALGE71FL.cpg is the first file of interest.
Any solutions to this?
If you are looking to move only the files in the folders and not the folders themselves. This following AppleScript code is one way to achieve your goal.
activate
set searchFolder to choose folder with prompt "Choose The Folder To Search"
activate
set destinationFolder to choose folder with prompt "Choose The Folder To Move Files To"
tell application "Finder"
set theFiles to (files of entire contents of searchFolder) as alias list
move theFiles to destinationFolder
end tell
I have the below code, which works to copy the contents of Downloads to the desktop. What I would like to do is copy it to the newly created folder, the folder_name, which is the current date and time.
set folder_name to (current date)
set folder_name to folder_name as string
tell application "Finder"
set p to path to desktop
make new folder at p with properties {name:folder_name}
end tell
tell application "Finder"
move (files of alias "Macintosh HD:Users:XXXXX:Downloads") to desktop
end tell
Essentially, I'm not sure how to pass folder_name into the final path. I tried (desktop & folder_name)
Thanks
The make new folder command of the Finder returns the new folder.
And there is a relative path to the Downloads folder of the current user
set currentDate to (current date) as string
set downloadsFolder to path to downloads folder
tell application "Finder"
set currentFolder to make new folder at desktop with properties {name: currentDate}
move (files of downloadsFolder) to currentFolder
end tell
The error is with "desktop:_XNB_Extract:"
tell application "Finder"
set x to path to desktop
make new folder at x with properties {name:"_XNB_Extract"}
set y to path to "desktop:_XNB_Extract:"
make new folder at y with properties {name:"Packed"}
end tell
Easy vanilla AppleScript solution:
tell application "Finder"
set extractFolder to make new folder at desktop with properties {name:"_XNB_Extract"}
make new folder at extractFolder with properties {name:"Packed"}
end tell
You can even omit at desktop because the desktop folder is the root folder of the Finder.
I'm trying to copy all files from a folder to another.
This works only if I specify the full path including the name of the drive and the username.
This works:
tell application "Finder"
set a to folder "Macintosh HD:Users:Michael:Desktop:Files:"
set b to folder "Macintosh HD:Users:Michael:Desktop:Copies"
duplicate every file of a to b
end tell
But I want to have this compatible with any HDD naming and username.
So I'm looking for a relative path, equivalent to ~:Desktop.
The relative path equivalent is
set desktopFolder to path to desktop
tell application "Finder"
set a to folder "Files:" of desktopFolder
set b to folder "Copies:" of desktopFolder
duplicate every file of a to b
end tell
But the Finder has a property desktop which points always to the desktop folder of the current user.
tell application "Finder"
set a to folder "Files:" of desktop
set b to folder "Copies:" of desktop
duplicate every file of a to b
end tell
And – even shorter – the desktop folder of the current user is the "root" folder of the Finder
tell application "Finder"
duplicate every file of folder "Files" to folder "Copies"
end tell
Edit:
The equivalent to
~/Library/Containers/com.apple.iWork.Numbers/Data/Library/Application Support/User Templates
is
((path to library folder from user domain as text) & "Containers:com.apple.iWork.Numbers:Data:Library:Application Support:User Templates:")
I am trying to write a simple applescript to move the contents of a file into the package contents folder of an application. I tried using automator to do this, but I was unable to access the package contents of the application. I am very new to applescript but this is what I have written so far.
tell application "Finder"
set source_folder to (choose folder with prompt "Select the Step5 Folder:")
set target_folder to folder "MacintoshHD:Applications:BlueJ.app:Contents:Resources:Java:userlib"
copy every file in folder source_folder to folder target_folder
end tell
Right now I am getting the following error
error "Finder got an error: Can’t make folder \"userlib\" of folder \"Java\" of folder \"Resources\" of folder \"Contents\" of application file \"BlueJ.app\" of folder \"Applications\" of startup disk into type integer." number -1700 from folder "userlib" of folder "Java" of folder "Resources" of folder "Contents" of application file "BlueJ.app" of folder "Applications" of startup disk to integer
I have tried googling the error and I have not found anything that has been applicable to what I am writing.
Thanks
Try:
set source_folder to (choose folder with prompt "Select the Step5 Folder:")
set target_folder to "MacintoshHD:Applications:BlueJ.app:Contents:Resources:Java:userlib"
tell application "Finder" to duplicate files of source_folder to target_folder
You specified 'folder' twice... the error was for moving the file to: folder folder path