Gnuplot tic frequency - bash

Question

For a very large data-set, how can gnuplot be used to only put tic marks/labels on the x axis for just the first and last data point?

Answer 1

With gnuplot 4.6 and up, you can use the commands
stats 'data.dat'
set xtics \
(sprintf("%.2g",STATS_min_x) STATS_min_x, \
sprintf("%.2g",STATS_max_x) STATS_max_x)
plot 'data.dat'
With other versions of gnuplot, you can use this similar sequence of commands:
# this setting makes sure we don't make an output right away
set terminal unknown
plot 'data.dat'
set xtics \
(sprintf("%.2g",GPVAL_DATA_X_MIN) GPVAL_DATA_X_MIN, \
sprintf("%.2g",GPVAL_DATA_X_MAX) GPVAL_DATA_X_MAX)
set terminal <actual terminal>
replot
The set xtics command takes comma-separated pairs of strings with data values, all inside parentheses.
(Here I assume you want the minimum and maximum, not the first and last, data points.)
For more info you can run these at the gnuplot command line:
help set format
help set stats
show variables all

Answer 2

I'm adding another answer because my other one really answered a different question, but may be useful. To answer the question,
How to mark the x tics for the first and last data points?
here is my method:
#!/usr/bin/env gnuplot
set terminal png
set output 'test.png'
# define a function to get the first and last values.
# this assumes the file has not changed since first running 'stats',
# (and contains at least one data point)
# `plot/stats 'data.dat' using (firstlast($x))`
# should be interchangable with
# `plot/stats 'data.dat' using x
# that is, the resulting variables should be the same
firstlast(x) = ($0==0) ? (first=$1, last=$1, $1) : (last=$1, $1)
# run stats to find the first and last values
# just on x data column
stats 'data.dat' u (firstlast($1)) nooutput
# set the x tics to the first and last x points
set xtics \
(sprintf("%.2g (first)", first) first, \
sprintf("%.2g (last)", last) last)
print first
print last
plot 'data.dat'
I used this example data file:
data.dat
1 1
2 2
3 3
4 2
0 3
and got this output: