VBscript with lists - vbscript

Question

I am trying to write a VBScript which will read a text file and build a dictionary which contains lists. Let me explain with an example:
The input file would be a simple text file of the sort:
Male,Peter
Male,Chris
Male,Stewie
Male,Brian
Female,Lois
Female,Meg
When I run my script, I would like a dictionary with the first column as the key, and the second column as the values
{'Male':['Peter,Chris,Stewie,Brian']}
{'Female':['Lois,Meg']}
The lack of dynamic arrays or lists in VBScript is making this a real pain. Any suggestion how I might tackle this?
Cheers

Answer 1

VBScript can use the System.Collections.ArrayList class provided by the .NET framework.
Set d = CreateObject("Scripting.Dictionary")
d.Add "Male", CreateObject("System.Collections.ArrayList")
d.Add "Female", CreateObject("System.Collections.ArrayList")
d("Male").Add "Peter"
d("Male").Add "Chris"
'...
d("Female").Add "Lois"
d("Female").Add "Meg"
'...
For processing the input file take a look at the code provided by #Rich.

Answer 2

Just to say, I'm not compete with posted answers for repo-point ;)
If you can convert my post to comment, feel free to do that.
I like Ansgar's idea (+1) as it based on single Dictionary and that seems to me quite enough to get back easy what is stored inside.
The need of .Exists may come in use in 2 cases - (a) if we don't know how many genders we have, and (b) if we don't know how they looks like (pronunciation). The rest is similar to Ansgar's idea.
Option Explicit
Const cGender = 0
Const cName = 1
Dim sGender, sName, sLine
Dim oFSO, oFile, oDict
Dim arrLine
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oDict = CreateObject("Scripting.Dictionary")
Set oFile = oFSO.OpenTextFile("persons_list.txt")
Do Until oFile.AtEndOfStream
sLine = oFile.ReadLine
If Len(sLine) Then
arrLine = Split(sLine, ",")
sGender = arrLine(cGender)
sName = arrLine(cName)
If Not oDict.Exists(sGender) Then
oDict.Add sGender, CreateObject("System.Collections.ArrayList")
End If
oDict(sGender).Add sName
End If
Loop
oFile.Close
Set oFile = Nothing
Set oFSO = Nothing
WScript.Echo "Genders:" & oDict.Count, vbNewLine & Join(oDict.Keys)
Dim sKey
For Each sKey In oDict
WScript.Echo sKey, oDict(sKey).Count, vbNewLine & Join(oDict(sKey).ToArray())
Next

Answer 3

I'm not too familiar with the dictionary object, but this might suffice?
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oDictionary = CreateObject("Scripting.Dictionary")
Const cGender = 0
Const cName = 1
Set oFile = oFso.OpenTextFile ("yourfile.txt", 1)
Do Until oFile.AtEndOfStream
sLine = oFile.Readline
If sLine <> "" Then
arrLine = split(sLine,",")
oDictionary.Add arrLine(cGender,0), arrLine(cName,0) 'hope i got these indexes the right way round
'or
oDictionary.Add arrLine(cGender), arrLine(cName) 'if its one dimentional
End If
Loop

Answer 4

As #Rich approach is faulty (-1) - you can't .Add a key twice and if you could, the names would be overwritten, not appended - and Ansgar's good idea (+1) is not really production ready without a hint wrt its practical use:
Const cGender = 0
Const cName = 1
Dim oFS : Set oFS = CreateObject("Scripting.FileSystemObject")
Dim dicDic : Set dicDic = CreateObject("Scripting.Dictionary")
Dim dicAl : Set dicAl = CreateObject("Scripting.Dictionary")
Dim dicCnt : Set dicCnt = CreateObject("Scripting.Dictionary")
Dim oFile, sLine, arrLine
Set oFile = oFS.OpenTextFile ("so14479571.txt")
Do Until oFile.AtEndOfStream
sLine = oFile.Readline()
If sLine <> "" Then
arrLine = Split(sLine,",")
dicCnt(arrLine(cGender)) = dicCnt(arrLine(cGender)) + 1
If Not dicDic.Exists(arrLine(cGender)) Then
Set dicDic(arrLine(cGender)) = CreateObject("Scripting.Dictionary")
End If
dicDic(arrLine(cGender))(arrLine(cName)) = Empty
If Not dicAl.Exists(arrLine(cGender)) Then
Set dicAl(arrLine(cGender)) = CreateObject("System.Collections.ArrayList")
End If
dicAl(arrLine(cGender)).Add arrLine(cName)
End If
Loop
Dim sKey, sKey2
WScript.Echo "genders:"
For Each sKey In dicCnt
WScript.Echo "", sKey, dicCnt(sKey)
Next
WScript.Echo "dic:"
For Each sKey In dicDic
WScript.Echo "", sKey
For Each sKey2 In dicDic(sKey)
WScript.Echo " ", sKey2
Next
Next
WScript.Echo "AL:"
For Each sKey In dicAl
WScript.Echo "", sKey & ":", Join(dicAl(sKey).ToArray())
Next
output:
genders:
Male 4
Female 2
dic:
Male
Peter
Chris
Stewie
Brian
Female
Lois
Meg
AL:
Male: Peter Chris Stewie Brian
Female: Lois Meg
The script should show:
How you can use assignment without .Exists for 'simple' values that can be autovivified (here a number)
That you need an .Exists check for values like Arrays, ArrayLists, or Dictionaries