How to remove from file specific content from another file? - shell

Question

I have a file foo.txt:
$cat foo.txt
<ul>
<li>
<p>something</p>
</li>
<li>
<p>something else</p>
</li>
</ul>
And a bar.txt:
$cat bar.txt
<li>
<p>something</p>
</li>
And I want the desired output:
<ul>
<li>
<p>something else</p>
</li>
</ul>
I have tried:
$sed '{/r bar.txt/} d' foo.txt
But it didn't work, and I cannot do:
$sed '/<li>/,/</li>/ d' foo.txt
because there are other elements.

Answer 1

This awk one-liner works for your example:
awk -v RS="" '{gsub(/\n/,"\x99")}NR==FNR{t=$0;next}{gsub(t,"");gsub(/\x99/,"\n");print}' bar foo
not exactly the same output (empty line), but you got the idea. see the short explanation below the example.
see the example below:
kent$ head foo bar
==> foo <==
<ul>
<li>
<p>something</p>
</li>
<li>
<p>something else</p>
</li>
</ul>
==> bar <==
<li>
<p>something</p>
</li>
kent$ awk -v RS="" '{gsub(/\n/,"\x99")}NR==FNR{t=$0;next}{gsub(t,"");gsub(/\x99/,"\n");print}' bar foo
<ul>
<li>
<p>something else</p>
</li>
</ul>
Add short explanation
The basic idea is, replace linebreak with invisible char (in example I used \x99), then we have two single line strings. we can do the match and replacement. after we processed the strings, replace all \x99 back to linebreak to get the original format. This idea works for sed too, but a bit complicated, you have to make a label and play with pattern/hold spaces...
In the example I just used RS="" (I am a bit lazy). you could use sprintf function to build the one-line string, it would be more generic, since both of your real files could have empty lines. (your example doesn't however)
The point is the invisible char replacement part.
Good luck!

Answer 2

sed is an excellent tool for simple subsitutions on a single line, for anything else use awk. Here is a GNU awk solution:
$ gawk -v RS='\0' -v ORS= 'NR==FNR{re=$0;next} {sub(re,"")} 1' bar.txt foo.txt
<ul>
<li>
<p>something else</p>
</li>
</ul>
If "bar.txt" can contain RE metacharacters and you find those causing undesirable matches in the sub() (unlikely when matching large amounts of text) then you need to switch to an index()+substr()s solution to work with strings instead of REs, e.g.:
$ gawk -v RS='\0' -v ORS= '
NR==FNR { str=$0; rlength=length(str); next }
rstart = index($0,str) { $0 = substr($0,1,rstart-1) substr($0,rstart+rlength) }
1' bar.txt foo.txt
<ul>
<li>
<p>something else</p>
</li>
</ul>