How do I add an AVPlayer to a QWidget? - macos

Question

On Mac, I want to use AVPlayer to play video in my Qt 4.8 application since it has features that Phonon::VideoPlayer doesn't have.
How do I add the AVPlayerLayer to a QWidget so it becomes visible? I'm doing the following:
pimpl->player = [[AVPlayer alloc] initWithURL:[NSURL fileURLWithPath:videoFile]];
pimpl->player.actionAtItemEnd = AVPlayerActionAtItemEndPause;
pimpl->player.rate = 0;
pimpl->playerLayer = [[AVPlayerLayer playerLayerWithPlayer:pimpl->player] retain];
[pimpl->playerLayer setFrame: CGRectMake(0, 0, rect().width(), rect().height())];
NSView* view = (NSView*)winId();
[[view layer] addSublayer:pimpl->playerLayer];
When I play my video, I hear it, but I don't see it. Any idea what I'm doing wrong?

Answer 1

Rather than using winId(), use QMacCocoaViewContainer, but QMacCocoaViewContainer has a bug which will cause the NSView to not be displayed in Qt 4.8 unless setAttribute(Qt::WA_NativeWindow); is set.
As well, the NSView may not have a layer, so a layer need to be created.
[pimpl->view setWantsLayer:YES];
[pimpl->view makeBackingLayer];
So in total it looks like:
pimpl->view = [[NSView alloc] initWithFrame: CGRectMake(0, 0, w, h)];
[pimpl->view setHidden:NO];
[pimpl->view setNeedsDisplay:YES];
[pimpl->view setWantsLayer:YES];
[pimpl->view makeBackingLayer];
viewFrame = new QMacCocoaViewContainer(NULL, this);
viewFrame->setGeometry(rect());
viewFrame->setVisible(true);
viewFrame->setCocoaView(pimpl->view);
NSString* videoFile = [NSString stringWithCString:filename.toUtf8().data() encoding:NSUTF8StringEncoding];
pimpl->player = [[AVPlayer alloc] initWithURL:[NSURL fileURLWithPath:videoFile]];
pimpl->player.actionAtItemEnd = AVPlayerActionAtItemEndPause;
pimpl->player.rate = 0;
pimpl->playerLayer = [[AVPlayerLayer playerLayerWithPlayer:pimpl->player] retain];
[pimpl->playerLayer setFrame: CGRectMake(0, 0, w, h)];
[pimpl->playerLayer setHidden: NO];
CALayer* layer = [pimpl->view layer];
[layer addSublayer:pimpl->playerLayer];