Batch script - files to folders - with addition - windows

Question

I'm working in a company that has far too many (millions) of record forms that all need organising.
Each file uses the following naming structure:
xxxxx-xx-xx-xxxxx e.g. 43144-02-40-21324.<ext>
I've used in the past a batch script that puts files into a folder of the same name, but I'm looking for something slightly different.
I'd eventually like to end up with the following folder structure:
C:\[root directory]\43144\02\40\21324.PDF
Is something like this possible?
My knowledge of batch scripts is non existant, does anyone have the ability to quickly throw this together?
Thanks in advance, David

Answer 1

#ECHO OFF
SETLOCAL
SET "sourcedir=."
SET "destdir=u:\temp"
FOR /f "tokens=1,2,3,*delims=-" %%a IN ('dir /b/a-d "%sourcedir%\*-*-*-*"') DO (
MD "%destdir%\%%a\%%b\%%c" 2>NUL
IF EXIST "%destdir%\%%a\%%b\%%c\%%d" (ECHO "%destdir%\%%a\%%b\%%c\%%d" already exists
) ELSE (
MOVE "%sourcedir%\%%a-%%b-%%c-%%d" "%destdir%\%%a\%%b\%%c\%%d" >nul
)
)
GOTO :EOF
This should set you on the right track - just need to set your source and destination directories...

Answer 2

Yes, this isn't very hard to do:
We need to loop over all the files
for %%F in (*.ext) ...
For simplicity reasons we look in the current folder, so set it appropriately beforehand. But you can also supply a folder to look in.
For every file found, just call a subroutine that does the work
... do call :process "%%~F"
Exit the main method
goto :eof
We need a subroutine now
rem :process <filename>
:process
Dissect the file name into its parts. Since those are all fixed-length we can just use substrings here.
set "Filename=%~1"
set "Part1=%Filename:~0,5%"
set "Part2=%Filename:~6,2%"
set "Part3=%Filename:~9,2%"
set "Rest=%Filename:~12%"
Now we should probably check whether the folder we need to copy this into already exists or not
if not exist C:\root\%Part1%\%Part2%\%Part3%\NUL mkdir C:\root\%Part1%\%Part2%\%Part3%
This will create every folder along the way if necessary. Very handy.
Rename and move the file now
move %1 C:\root\%Part1%\%Part2%\%Part3%\%Rest%
Exit the subroutine
goto :eof
This should be it, more or less (bugs in my implementation notwithstanding). So here again in full:
for %%F in (*.ext) do call :process "%%~F"
goto :eof
rem :process <filename>
:process
set "Filename=%~1"
set "Part1=%Filename:~0,5%"
set "Part2=%Filename:~6,2%"
set "Part3=%Filename:~9,2%"
set "Rest=%Filename:~12%"
if not exist C:\root\%Part1%\%Part2%\%Part3%\NUL mkdir C:\root\%Part1%\%Part2%\%Part3%
move %1 C:\root\%Part1%\%Part2%\%Part3%\%Rest%
goto :eof

Answer 3

You will have to iterate through files and for each file split name using FOR.
Then, you must ensure directories are created and copy/move your file to new path.
For %%f In (*.*) Do For /F "Tokens=1,2,3,4,5,6 Delims=-" %%i In ("%%f") Do Call :PutInPath %%f %%i %%j %%k %%k %%l
GoTo :EOF
:PutInPath
MD "C:\your dir\%2"
MD "C:\your dir\%2\%3"
MD "C:\your dir\%2\%3\%4"
REM You can use COPY, MOVE, REN, ...
COPY %1 "C:\your dir\%2\%3\%4\%5"
GoTo :EOF

Answer 4

#Echo off
SET extension=%1
setlocal enabledelayedexpansion
for %%f in ("*.%extension%") do (
SET substr=%%f
echo !substr!
copy !substr! !substr:~0,5!\!substr:~6,2!\!substr:~9,2!\!substr:~12,5!.%extension%
del !substr!
)
if the file format are fixed, we can do it like this!