Exact details of how Empty works in VBScript - vbscript

Question

I'm new to VBScript and rather perplexed as to why the following code works:
set Adapters = GetObject("winmgmts:").InstancesOf("Win32_NetworkAdapterConfiguration")
for each Nic in Adapters
if Nic.IPEnabled then
MsgBox "IP Address: " & Nic.IPAddress(asdf), 4160, "IP Address"
end if
next
When the variable asdf is undefined, it works. If I define asdf to an invalid index (e.g. -1 or 4), I get an invalid index error.
I thought: Perhaps undefined variables default to 0 in VBS? Nope, I tried to print it and nothing is written.
Where is the functionality of passing an undefined variable as an array index returning the first item in the array documented? What are some other, similar oddities I may run into while programming in VBScript?
Edit: Some things I've discovered:
Undefined variables are equal to Empty by default in VBScript
Empty = 0 is true
Nic.IPAddress(Empty) also returns the first element of the array
MsgBox 0 will print 0, while MsgBox Empty will print nothing
I'm still having trouble finding any documentation stating that array indexing handles Empty quietly by returning the first element, explaining why it is equivalent to but printed differently from 0, and what other constructs handle Empty parameters (and what they do as a result).

Answer 1

The undefined variable is Empty and returning the Empty index of an array will also return the 0 index.
In the IPAddress array, there are two indexes, a 0 and a 1.
So this will have the same effect as your code:
MsgBox "IP Address: " & Nic.IPAddress(0), 4160, "IP Address"
And
MsgBox "IP Address: " & Nic.IPAddress(Empty), 4160, "IP Address"
And this will give you the IPv6 addresses:
MsgBox "IP Address: " & Nic.IPAddress(1), 4160, "IP Address"
Also, this will return both indexes of the array:
WScript.Echo Join(Nic.IPAddress,",")
Also, consider this example,
arr = Array("first","second","third")
WScript.Echo arr(Empty)
The output here will be first
See this post for VBScript Data Types:
"Empty : Variant is uninitialized. Value is 0 for numeric variables or a zero-length string ("") for string variables.`
http://msdn.microsoft.com/en-us/library/9e7a57cf(v=vs.84).aspx

Answer 2

Big thanks to Langstrom for providing this:
"Empty: Variant is uninitialized. Value is 0 for numeric variables or a zero-length string ("") for string variables."
Empty:
Nic.IPAddress(asdf) treats the parameter as an int, and CInt(Empty) is equal to 0, the index of the first element of the array.
MsgBox asdf treats the parameter as a string, and CStr(Empty) returns an empty string.
Any function that expects an integer and for which 0 is a valid value will work exactly the same as if 0 had been passed when called with an Empty parameter.
When comparing Empty = 0, Empty is treated as an integer because it being compared to an integer, so the expression is true.
When comparing Empty = "0", Empty is treated as a string, and so the expression is false. Therefore, Empty = "" is true.
Null:
Also, it is worth mentioning that Null is not equal to anything, including itself. Null = Null is false.