awk: extracting columns based on column values - bash

Question

I have a file that looks somewhat like this:
C1 C2 C3 C4 C5
0 0 0 0 0
0 1 0 0 0
0 0 0 1 0
0 0 0 0 0
but much larger...
I want to extract only the columns that have all 0's in them, so my output file should look like this:
C1 C3 C5
0 0 0
0 0 0
0 0 0
0 0 0
Can this be done with a simple awk one-liner (similar to awk: print columns based on values of another column for example)? If no, is there another way to do this effectively using bash?

Answer 1

Try following awk
awk 'NR==1 {next} NR==FNR { for(i=1;i<=NF;i++) sum[i]+=$i; next } { for(i=1;i<=NF;i++) if (sum[i]==0) printf " %s", $i; print "" }' file{,}
Output
C1 C3 C5
0 0 0
0 0 0
0 0 0
0 0 0
Idea here is to iterated of file twice. Once it calculates sum of all columns and in next iteration it prints only columns having sum equal to zero.
This assumes all column entries have positive numbers only
Another, may be better, approach would be to set a flag if any entry in a column is non-zero. And then print only those columns for which correspondig flag is zero.
awk 'NR==1 {next} NR==FNR { for(i=1;i<=NF;i++) if ($i) flag[i]=1; next } { for(i=1;i<=NF;i++) if (!flag[i]) printf " %s", $i; print "" }' file{,}
This approach allows positive as well as negative numbers and removes any restriction.
Or as suggested by #fedorqui in a comment
awk 'NR==1 {next} NR==FNR { for(i=1;i<=NF;i++) if ($i) flag[i]=1; next } { for(i=1;i<=NF;i++) if (flag[i]) $i="" } 1' file{,}

Answer 2

this works for data with negative number or other strings like 'foo' or 'bar'
one-liner:
awk 'NR==1{next}NR==FNR{while(++i<=NF)if($i!="0")k[i];i=0;next}{while(++x<=NF)if(!(x in k))printf "%s ",$x;x=0;print ""}' file file
more readable:
awk 'NR==1{next}
NR==FNR{while(++i<=NF)if($i!="0")k[i];i=0;next}
{while(++x<=NF)
if(!(x in k)) printf "%s ",$x
x=0
print ""}' file file

Answer 3

A loooong solution.
Convert column to row
awk '{
for (f = 1; f <= NF; f++) { a[NR, f] = $f }
}
NF > nf { nf = NF }
END {
for (f = 1; f <= nf; f++) {
for (r = 1; r <= NR; r++) {
printf a[r, f] (r==NR ? RS : FS)
}
}
}' file >tmp1
Print only rows with only 0
awk '{for (i=2;i<=NF;i++) f+=$i} !f; {f=0}' tmp1 >tmp2
Convert back
awk '{
for (f = 1; f <= NF; f++) { a[NR, f] = $f }
}
NF > nf { nf = NF }
END {
for (f = 1; f <= nf; f++) {
for (r = 1; r <= NR; r++) {
printf a[r, f] (r==NR ? RS : FS)
}
}
}' tmp2
Gives
C1 C3 C5
0 0 0
0 0 0
0 0 0
0 0 0