Dim or ReDim issue? - vbscript

Question

I have a questions about classic ASP:
Can anyone tell me what I am doing wrong in this snippet? If ORDERDATA() contains one entry only, it works fine. If more than one, it crashes. I am pretty sure it has to do with the Dim/ReDim of the CARTITEMS() variable, but I can't see what I'm doing wrong.
Some of the dimmed variables are used in other parts of the script, please ignore them.
Dim i,countOrderRows, orderdata, XXX
orderdata = Order_GetOrderData()
countOrderRows = ubound(orderdata,1)
Dim cartItems()
ReDim cartItems(countOrderRows-1)
Dim goodsList(), addr, klarnaresponse, resp, sql, item
ReDim goodsList(countOrderRows-1)
for i = 0 to countOrderRows - 1
Set item = Server.CreateObject("Scripting.Dictionary")
item.Add "reference", "XX1"
item.Add "name", orderdata(i,2)
item.Add "quantity", cint(orderdata(i,5))
item.Add "unit_price", (cint(orderdata(i,3)*100))
item.Add "discount_rate", 0
item.Add "tax_rate", 2500
Set cartItems(i) = item
Set item = nothing
next
Hope you guys can help!
Regards, Bob

Answer 1

countOrderRows = ubound(orderdata,1)
assigns the maximum 0-based index to countOrderRow, not the number of elements.
Later, you use countOrderRows as if it contained the number of elements:
ReDim cartItems(countOrderRows-1)
For an orderdata with only one element in dimension 1, this will do ReDim (..,-1), which is not what you intended, but hey!
Well, why this doesn't yield an error is a separate question ;)
And then, you use
for i = 0 to countOrderRows-1
to iterate. That´s wrong. UBound returns the maximum acceptable index. For one element, this is 0. Since countOrderRows equals 0, you are trying a
for i = 0 to -1
which again is not what you intended.
And that´s why things work (seem to work) for only one element: A for loop from 0 to -1 is executed zero times. If there is more than one element, the loop code is executed, and fails due to the wrong indexes and array sizes involved.
Note I intentionally did not just spit out corrected code, but tried to lead you into fixing this bug yourself.

Answer 2

Assuming that Order_GetOrderData() is a multidimensional array in the format
function Order_GetOrderData ()
dim myArray(0,5)
myArray(0, 0) = "XX1"
myArray(0, 1) = "G66T"
myArray(0, 2) = "An Item"
myArray(0, 3) = "3"
myArray(0, 4) = "0"
myArray(0, 5) = "100"
Order_GetOrderData = myArray
end function
Removing the -1 from countOrderRows in all three places it's used allowed me to return the item values for each iteration.
Dim i,countOrderRows, orderdata, XXX
orderdata = Order_GetOrderData()
countOrderRows = ubound(orderdata, 1)
Dim cartItems()
ReDim cartItems(countOrderRows)
Dim goodsList(), addr, klarnaresponse, resp, sql, item
ReDim goodsList(countOrderRows)
for i = 0 to countOrderRows
Set item = Server.CreateObject("Scripting.Dictionary")
item.Add "reference", "XX1"
item.Add "name", orderdata(i,2)
item.Add "quantity", cint(orderdata(i,5))
item.Add "unit_price", (cint(orderdata(i,3)*100))
item.Add "discount_rate", 0
item.Add "tax_rate", 2500
Set cartItems(i) = item
Set item = nothing
next
response.write cartItems(0).item("name")
response.write cartItems(1).item("name")
etc.
The reason for this being that ubound(orderdata, 1) returns the number of rows in a ZERO based form so subtracting 1 from this gave a negative value when only one result existed.
I am unsure why your code works when you pass it one item and not multiple items. The example provided using my assumed data works with multiple items as long as you are looking to return from the beginning of the data set, but will always fail if only one item is returned. It may have something to do with the format of the array returned by Order_GetOrderData()?