Merge binary files based on dates in the filenames - windows

Question

I have multiple files in a directory with the formatL: data_yyyy_mm_dd_ss.info.dat
I am trying to write a batch script that will ask for user start/end date input (and assuming the user's input will match the format of the files yyyy_mm_dd) I then want the script to do a merge of all relevant files.
Ex Files: data_2013_12_01_32.info.dat; data_2013_12_02_44.info.dat; data_2013_12_03_22.info.dat; data_2013_12_04_33.info.dat; data_2013_12_05_52.info.dat; data_2013_12_06_12.info.dat
Ex Script:
#echo off
set /p start= Start Date:
set /p end= End Date:
copy /b ????
Ex User Input: 2013_12_02 and 2013_12_05
Ex Output: Merge files 2013_12_02 through 2013_12_05.
Thanks for any help in advance.

Answer 1

I'll assume you know what you are doing, and it is valid to concatenate your binary files.
The following should work, as long as all files that match the FOR filter are candidates for merging, and as long as the user always enters dates in the correct format (yyyy_mm_dd):
#echo off
setlocal
set /p start= Start Date:
set /p end= End Date:
set "out=output.info.dat"
for %%F in (data_????_??_??_??.info.dat) do (
for /f "tokens=1-3 delims=_" %%A in ("%%F") do (
if "%%A_%%B_%%C" geq "%start%" if "%%A_%%B_%%C" leq "%end%" (
copy /b "%out%"+"%%F" "%out%" /b
)
)
)
As an alternative to using COPY, you should be able to redirect the output of FINDSTR and get the same result.
#echo off
setlocal
set /p start= Start Date:
set /p end= End Date:
>output.info.dat (
for %%F in (data_????_??_??_??.info.dat) do (
for /f "tokens=1-3 delims=_" %%A in ("%%F") do (
if "%%A_%%B_%%C" geq "%start%" if "%%A_%%B_%%C" leq "%end%" (
findstr "^" "%%F"
)
)
)
)
I'm not sure which is faster, COPY or FINDSTR

Answer 2

It has no checks on almost anything. Be careful.
Ask for start and end date. Generate min and max files based on data input and iterate over the ordered list of files. If a file is found, it is readed with findstr (first option was type command, but it's 4 to 5 times slower) and all output redirected to final merged file.
#echo off
setlocal enableextensions disabledelayedexpansion
set /p "start=Start date :"
set /p "end=End date :"
set "start=data_%start%_00.info.dat"
set "end=data_%end%_99.info.dat"
>merged.info.dat (
for /f "tokens=*" %%f in ('dir /on /b "data_????_??_??_??.info.dat"') do (
if /i "%%f" geq "%start%" if /i "%%f" leq "%end%" findstr "^" "%%f"
)
)
For a long list of files, search can be abreviated. In this moment i don't know how to skip the initial non matching part of the list of files, but the final part can be easyly skipped
#echo off
setlocal enableextensions disabledelayedexpansion
set /p "start=Start date:"
set /p "end=End date:"
set "start=data_%start%_00.info.dat"
set "end=data_%end%_99.info.dat"
>output.info.dat (
for /f "tokens=*" %%f in ('dir /on /b "data_????_??_??_??.info.dat"') do (
if /i "%%f" geq "%start%" if /i "%%f" leq "%end%" ( findstr "^" "%%f" ) else ( goto :endMerge )
)
)
:endMerge