Method not applicable? - processing

Question

When I add the parameter "Color" to owl it says that the method owl is not applicable??
I want the owl to change into random colors any suggestions? This is an exercises from Reas and Fry's processing book.
void setup ( ) {
size(700,500);
background(200);
smooth( );
frameRate(10);
}
void pick () {
color (random(255),random(255),random(255));
}
void draw ( ) {
owl(35,100);
}
void owl (int x, int y, color z) {
pick ();
stroke(0) ;
strokeWeight(70) ;
line(x, -35+y, x, -65+y) ; // body
noStroke() ;
fill(255) ;
ellipse(-17.5+x, -65+y, 35, 35) ; // left eye dome
ellipse( 17.5+x, -65+y, 35, 35) ; // right eye dome
arc(0+x, -65+y, 70, 70, 0, PI) ;
fill(0) ;
ellipse(-14+x, -65+y, 8, 8) ; // left eye
ellipse( 14+x, -65+y, 8, 8) ; // right eye
quad(0+x, -58+y, 4+x, -51+y, x, -44+y, -4+x, -51+y) ;
}

Answer 1

v.k. is actually right, although he did not tell you why the colour does not change. The problem is of course that you are calling owl with two parameters while it needs three. As far as I understand you want to pick the random colour with the pick() method, thus you don't need the third parameter in there.
void owl (int x, int y, color z) {
should be
void owl (int x, int y) {
Also you need to somehow fill (or stroke) things with the random colour you have correctly created. The problem is, as long as you don't pass it in a fill() or a stroke() method, it will not colour anything... So you need to have that colour somehow in the owl() method, you thus return it from the pick() command and use it like this:
color pick () {
return color (random(255),random(255),random(255));
}
and you retrieve it in the owl method and store it in a variable so that you can use it:
color z = pick();
then to change the colour of the eyes you change
fill(0);
to:
fill(z);
Here's the final code in case I have confused you:
void setup ( ) {
size(700,500);
background(200);
smooth( );
frameRate(10);
}
color pick () {
return color (random(255),random(255),random(255));
}
void draw ( ) {
owl(35,100);
}
void owl (int x, int y) {
color z = pick();
stroke(0) ;
strokeWeight(70) ;
line(x, -35+y, x, -65+y) ; // body
noStroke() ;
fill(255) ;
ellipse(-17.5+x, -65+y, 35, 35) ; // left eye dome
ellipse( 17.5+x, -65+y, 35, 35) ; // right eye dome
arc(0+x, -65+y, 70, 70, 0, PI) ;
fill(z) ;
ellipse(-14+x, -65+y, 8, 8) ; // left eye
ellipse( 14+x, -65+y, 8, 8) ; // right eye
quad(0+x, -58+y, 4+x, -51+y, x, -44+y, -4+x, -51+y) ;
}

Answer 2

color is a Processing Datatype for colors. It is aware of colorMode(). The problem is simple, your own method is expecting 3 parameters void owl (int x, int y, color z) {... and you are calling it with 2 owl(35,100). If you say:
owl(35,100, color(random(255),random(255),)random(255));
it will work.