awk with duplicate values - bash

Question

File:
22 Hello
22 Hi
1 What
34 Where
21 is
44 How
44 are
44 you
Desired Output:
22 HelloHi
1 What
34 Where
21 is
44 Howareyou
If there are duplicate values in first field($1) the second field should have appended text
How to achieve this using awk?
Thanks

Answer 1

$ awk '
!seen[$1]++ { keys[++numKeys] = $1 }
{ str[$1] = str[$1] $2 }
END{
for (keyNr=1; keyNr<=numKeys; keyNr++) {
key = keys[keyNr]
print key, str[key]
}
}
' file
22 HelloHi
1 What
34 Where
21 is
44 Howareyou

Answer 2

Using awk:
awk '!($1 in a){a[$1]=$2;next} $1 in a{a[$1]=a[$1] $2} END{for (i in a) print i, a[i]}' file
22 HelloHi
44 Howareyou
34 Where
21 is
1 What
EDIT: To preserve the order:
awk '!($1 in a){b[++n]=$1; a[$1]=$2;next} $1 in a{a[$1] = a[$1] $2}
END{for (i=1; i<=n; i++) print b[i], a[b[i]]}' file
22 HelloHi
1 What
34 Where
21 is
44 Howareyou

Answer 3

To maintain the order, you need to keep track of it:
awk '
! seen[$1]++ {order[++n] = $1}
{value[$1] = value[$1] $2}
END {for (i=1; i<=n; i++) print order[i], value[order[i]]}
' <<END
22 Hello
22 Hi
1 What
34 Where
21 is
44 How
44 are
44 you
END
22 HelloHi
1 What
34 Where
21 is
44 Howareyou
If you know the values in the 1st column are contiguous, as in your sample text, then:
awk '
prev != $1 {printf "%s%s ", sep, $1; sep=RS}
{printf "%s", $2; prev = $1}
END {print ""}
'
A couple of other approaches:
perl -lane '
push #keys, $F[0] unless grep {$_ eq $F[0]} #keys;
$val{$F[0]} .= $F[1]
} END {
print "$_ $val{$_}" for #keys
' file
and, reaching way into the niche zone
#!/usr/bin/env tclsh
while {[gets stdin line] != -1} {dict append val {*}$line}
dict for {k v} $val {puts "$k $v"}

Answer 4

Here is an alternate solution in Python, as requested by #shellter:
from collections import defaultdict
with open("file") as infile:
d = defaultdict(str)
#Build dictionary of values
for line in infile:
line = line.strip()
k, _, v = line.partition(" ")
d[k] += v
#Print everything
for k, v in d.iteritems():
print k,v
Note that the ordering is not preserved in this solution. Here is an alternate solution that provides exactly the desired output:
from collections import defaultdict
with open("file") as infile:
d = defaultdict(str)
orig_order = []
#Build dictionary of values
for line in infile:
line = line.strip()
k, _, v = line.partition(" ")
d[k] += v
#Add to original order if not seen yet
if not k in orig_order:
orig_order.append(k)
#Print everything
for k in orig_order:
print k, d[k]
Note that these are quickly-crafted solution, I am sure it is possible without too much effort to either make them shorter or more flexible.

Answer 5

if the order is not important, this will work:
awk '{a[$1]=a[$1]$2}; END {for (i in a) {print a[i]}}' file
.. and if order is important:
awk '{if (!a[$1]) b[++i]=$1;a[$1]=a[$1]$2}; END {for (j=1;j<i;j++) {print a[b[j]]}}' file