Quicktime Player recording with Applescript broken on Mavericks? - macos

Question

I have this simple code:
tell application "QuickTime Player"
activate
new screen recording
document "Screen Recording" start
delay 10
document "Screen Recording" stop
end tell
This records a 10-second movie on my 10.8 machine with no problem.
But on 10.9 mac-mini, QT hangs at the stop action above.
It hangs at the window with message "Finishing Recording".
I have to force quit it and still same thing. If I do these steps manually, they work. But with AppleScript or even same steps with Automator have same issue.
I upgraded to 10.9.2, but still same issue.
Is this a known bug? Any suggestions for a work around?
Thanks.

Answer 1

I do something like this to record the screen from CI and it always works for me:
set filePath to (path to desktop as string) & "ScreenRecordingFile.mov"
tell application "System Events" to tell process "Simulator"
set frontmost to true
end tell
tell application "QuickTime Player"
activate
set newScreenRecording to new screen recording
delay 1
tell application "System Events"
tell process "QuickTime Player"
set frontmost to true
key code 49
end tell
end tell
tell newScreenRecording
start
delay 15
stop
end tell
export document 1 in (file filePath) using settings preset "720p"
close document 1 saving no
end tell

Answer 2

I've ran into the same problem and found out, that the problem is not in the stop, but in the non-interactive start, so I've tried to start recording (pseudo)interactively and it worked out perfectly.
tell application "QuickTime Player"
activate
new screen recording
activate
tell application "System Events" to tell process "QuickTime Player"
key code 49
end tell
document "Screen Recording" start
delay 10
document "Screen Recording" stop
end tell
It still calls start instead of emulating click, because I haven't found a way to make it work.

Answer 3

Two tricks are needed:
Send a space key to the QuickTime Player before start to avoid the Finishing... dialog being stuck. (credits to #outring)
We need to simulate a mouse click. This is not easy, and we need to do it via CoreGraphics (aka Quartz). We can either write in Objective-C (need compilation), in Python (via PyObjc bridge) or Swift.
Somehow recording starts roughly 2 seconds after the mouse click, so we need to sleep 12 seconds for a 10-second video.
A working script will look like this:
tell application "QuickTime Player"
activate
new screen recording
tell application "System Events" to tell process "QuickTime Player" to key code 49
document "Screen Recording" start
do shell script "python -c 'import Quartz; mouse_location = Quartz.NSEvent.mouseLocation(); [ Quartz.CGEventPost(Quartz.kCGHIDEventTap, Quartz.CGEventCreateMouseEvent(None, mouse_action, mouse_location, Quartz.kCGMouseButtonLeft)) for mouse_action in [ Quartz.kCGEventLeftMouseDown, Quartz.kCGEventLeftMouseUp ] ]'"
delay 12
document "Screen Recording" stop
end tell