How do I make leap years work? - time

Question

I have some code here in TCL that tries to measure the time between two dates.
The two first work, but as you see the last one not working; it counts totally wrong, as there can only be 12 month in a year, but this has more than that.
Anyway, I think that the leap year is the problem, but I'm not sure. Can you help?
proc isTimeAgo {t1} {
set t2 "1387524660"
#set t2 [clock seconds]
set cnt [expr {(($t2 - $t1) / 31536000)}]
set cur [clock add $t1 $cnt years]
set res {}
foreach unit {years months weeks days hours minutes seconds} {
while {$cur <= $t2} {
set cur [clock add $cur 1 $unit]
incr cnt
}
set cur [clock add $cur -1 $unit]
incr cnt -1
if {$cnt} {
lappend res $cnt $unit
}
set cnt 0
}
return $res
}
puts "1: [isTimeAgo "1355988659"]"
puts "2: [isTimeAgo "1355988660"]"
puts "3: [isTimeAgo "1355988661"]"
proc days_per_month year {
set leap [expr {($year%4)==0 && (!($year%400) || ($year%100))}]
set days [list 31 [expr {$leap ? 29 : 28}] 31 30 31 30 31 31 30 31 30 31]
return $days
}
The result of this is:
1: 1 years 1 seconds <- Correct
2: 1 years <- Correct
3: 11 months 4 weeks 1 days 23 hours 59 minutes 59 seconds <- Wrong

Answer 1

Date and time arithmetic is astonishingly hard to get right because what people mean by it is so thoroughly uncertain. When adding an interval to a time, you've got to add the years before the months (because of leap years), the months before the days (because of varying month lengths), and the days before the times (because of DST changes). This is sufficiently tricky that we've got a command that handles the complexity: clock add (requires at least Tcl 8.5). Going in the reverse direction? It's a matter of trying each unit until you overshoot.
proc getInterval {from to} {
set result {}
foreach unit {year month week day hour minute second} {
set n 0
while 1 {
set new [clock add $from 1 $unit]
if {$new > $to} break
set from $new
incr n
}
lappend result $n $unit
}
return $result
}
Let's try that out:
% getInterval 1355988659 [clock seconds]
1 year 4 month 0 week 6 day 6 hour 52 minute 39 second
I suppose we could add in ensuring that from precedes to and omit items that are zero. I'll leave those as an exercise.
Be aware that you might need to change the locale and timezone used by clock add to get the answer you are expecting (using the -locale and -timezone options, respectively). See the documentation for exactly what this may affect and some examples.