Write data to MS Access using VB6 - vb6

Question

This is my first VB6 application. My problem is there is no helpful example of writing data (including current date & time) from a form to an Access database. Here's my code based on all my research from different websites.
If you can't understand my code or if it is wrong, please show me a working example.
Private Sub Command1_Click()
Dim conConnection As New ADODB.Connection
Dim cmdCommand As New ADODB.Command
Dim rstRecordSet As New ADODB.Recordset
Dim logInId As Integer
Dim guardId As String
Dim studentId As String
Dim laptopName As String
Dim laptopBrand As String
Dim logInDate As Date
Dim logInTime As Date
guardId = Text2.Text
studentId = Text3.Text
laptopName = Text4.Text
laptopBrand = Text5.Text
logInDate = DateVal(Now)
logInTime = TimeVal(Now)
conConnection.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & _
App.Path & "\" & "Database.accdb;Mode=Read|Write"
conConnection.CursorLocation = adUseClient
conConnection.Open
rstRecordSet.Open "laptopLoggedInLoggedOutInfo", conConnection
logInId = rstRecordSet.RecordCount
With cmdCommand
.ActiveConnection = conConnection
.CommandType = adCmdText
'f means field
.CommandText = "INSERT INTO laptopLoggedInLoggedOutInfo(f1,f2,f3,f4,f5,f6,f7) VALUES (?,?,?,?,?,?,?) "
.Prepared = True
.Parameters.Append .CreateParameter("f1", adInteger, adParamInput, , logInId + 1)
.Parameters.Append .CreateParameter("f2", adChar, adParamInput, 20, guardId)
.Parameters.Append .CreateParameter("f3", adChar, adParamInput, 20, studentId)
.Parameters.Append .CreateParameter("f4", adChar, adParamInput, 20, laptopName)
.Parameters.Append .CreateParameter("f5", adChar, adParamInput, 20, laptopBrand)
.Parameters.Append .CreateParameter("f6", adDate, adParamInput, , logInDate)
.Parameters.Append .CreateParameter("f7", adDate, adParamInput, , logInTime)
Set rstRecordSet = cmdCommand.Execute
End With
conConnection.Close
Set conConnection = Nothing
Set cmdCommand = Nothing
Set rstRecordSet = Nothing
End Sub

Answer 1

I've made in-line comments on your code:
Private Sub Command1_Click()
Whilst this doesn't matter for this particular example, generally don't declare object variables "As New". It is better if you instantiate them manually. Essentially, "As New" declared variables are checked every time you try to use a property or method on them, and if the variable Is Nothing, it creates a new instance. This may not necessarily be what you intend.
Dim conConnection As New ADODB.Connection
Dim cmdCommand As New ADODB.Command
Dim rstRecordSet As New ADODB.Recordset
Dim logInId As Integer
Dim guardId As String
Dim studentId As String
Dim laptopName As String
Dim laptopBrand As String
Dim logInDate As Date
Dim logInTime As Date
guardId = Text2.Text
studentId = Text3.Text
laptopName = Text4.Text
laptopBrand = Text5.Text
logInDate = DateVal(Now)
logInTime = TimeVal(Now)
Make sure that the Data Source substring is points to your Access database.
conConnection.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & _
App.Path & "\" & "Database.accdb;Mode=Read|Write"
conConnection.CursorLocation = adUseClient
conConnection.Open
I see that you are using a recordset just to receive a count of records in logInId. I really wouldn't use this as an ID. If you delete records from the table, then your ID will become smaller. Generally, if you want a unique ID, you must ensure that the ID always increments.
rstRecordSet.Open "laptopLoggedInLoggedOutInfo", conConnection
logInId = rstRecordSet.RecordCount
My suggestion: use "SELECT MAX(f1) FROM laptopLoggedInLoggedOutInfo", and retrieve the first value, ensuring that if the value is null, it returns zero, e.g.
rstRecordSet.Open "SELECT MAX(logInId) FROM laptopLoggedInLoggedOutInfo", conConnection
logInId = IIf(IsNull(rstRecordSet.Fields(0)), 0, IsNull(rstRecordSet.Fields(0)))
With cmdCommand
.ActiveConnection = conConnection
.CommandType = adCmdText
'f means field
Are these really your fieldnames: f1, f2, f2, etc.? I would be surprised. Replace them with the correct field names.
.CommandText = "INSERT INTO laptopLoggedInLoggedOutInfo(f1,f2,f3,f4,f5,f6,f7) VALUES (?,?,?,?,?,?,?) "
Note that the actual parameter names, e.g. f1,f2,f3, etc. seem not to matter. It is the order in the INSERT statement that matters.
.Prepared = True
.Parameters.Append .CreateParameter("f1", adInteger, adParamInput, , logInId + 1)
.Parameters.Append .CreateParameter("f2", adChar, adParamInput, 20, guardId)
.Parameters.Append .CreateParameter("f3", adChar, adParamInput, 20, studentId)
.Parameters.Append .CreateParameter("f4", adChar, adParamInput, 20, laptopName)
.Parameters.Append .CreateParameter("f5", adChar, adParamInput, 20, laptopBrand)
.Parameters.Append .CreateParameter("f6", adDate, adParamInput, , logInDate)
.Parameters.Append .CreateParameter("f7", adDate, adParamInput, , logInTime)
Don't use a return value in use the following line. And INSERT statement returns no values:
Set rstRecordSet = cmdCommand.Execute
Do this instead:
cmdCommand.Execute
End With
conConnection.Close
You probably don't need to set these variables to Nothing - VB does it for you, anyway. However, if you do, it is generally good practice to do this in reverse order of creation.
Set conConnection = Nothing
Set cmdCommand = Nothing
Set rstRecordSet = Nothing
End Sub

Answer 2

There really isn't much advantage in using ACE formats, you only limit portability. MDBs are almost always a better idea.
You also have a ton of code there for something this minimal. And don't forget to escape the DB path, you can use apostrophes or quotes in the connection string.
Make your "f1" field type IDENTITY ("autonumber").
Private Sub Command1_Click()
Dim cn As ADODB.Connection
Dim cm As ADODB.Command
Set cn = New ADODB.Connection
cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source='" _
& App.Path & "\Database.accdb';Mode=Read|Write"
Set cm = New ADODB.Command
With cm
.CommandType = adCmdText
'Assume "f1" is type IDENTITY ("Autonumber").
.CommandText = _
"INSERT INTO laptopLoggedInLoggedOutInfo(f2,f3,f4,f5,f6,f7) " _
& "VALUES (?,?,?,?,?,?)"
Set .ActiveConnection = cn
'Seriously? Give those TextBoxes names!
.Execute , _
Array(Text2.Text, Text3.Text, Text4.Text, Text5.Text, Date, Time()), _
adExecuteNoRecords
End With
End Sub