Best way to sort a SystemVerilog associative array? - sorting

Question

I have an associative array and I need to process the items in that array in a certain order. What's the best way to do that?
Here is an example. Suppose I have an associative array of people's names and their ages:
int age[string];
age["bob"] = 32;
age["timmy"] = 4;
age["tyrian"] = 31;
I need to process this array from youngest person to oldest. Currently, I'm creating another array for indexing and sorting that.
string sorted_age[$];
// Is there a more efficient way to do this sort?
foreach (age[i]) begin
bit inserted = 0;
foreach (sorted_age[j]) begin
if (age[i] < age[sorted_age[j]]) begin
sorted_age.insert(j, i);
inserted = 1;
break;
end
end
if (!inserted) begin
sorted_age.push_back(i);
end
end
Full example on EDA Playground: http://www.edaplayground.com/x/2_8

Answer 1

You could add one more queue then use the built in array methods. I haven't done a performance test (which could be simulator dependent), but it is fewer lines of code and easy to read.
string sorted_age[$];
int store_age [$];
store_age = age.unique(); // find all unique ages (no duplicates)
store_age.sort(); // sort by age
foreach(store_age[i]) begin
// multi entry puch_back
sorted_age = {sorted_age, age.find_index with (item==store_age[i])};
end
Full example on EDA Playground

Answer 2

You can use the sort() with functionality:
// Create an aray of people's names
string sorted_age[] = new [age.size()];
int index = 0;
foreach (age[i]) begin
sorted_age[index++] = i;
end
// Sort the array
sorted_age.sort() with (age[item]);
Full example on EDA Playground: http://www.edaplayground.com/x/3Mf