how to prevent password prompt pops up many times - applescript

Question

My code looks like:
set sourceFolder1 to (path to library folder as text) & "Frameworks:SDL.framework"
set sourceFolder2 to (path to library folder as text) & "Frameworks:SDL_ttf.framework"
set sourceFolder3 to (path to library folder as text) & "Frameworks:SDL_image.framework"
tell application "Finder"
if exists folder sourceFolder1 then
delete folder sourceFolder1
end if
if exists folder sourceFolder2 then
delete folder sourceFolder2
end if
if exists folder sourceFolder3 then
delete folder sourceFolder3
end if
end tell
When I test it, the password prompt pops up 3 times to ask for password. Is there a way to prevent the password prompt pops up more than once? Thanks.
LJ

Answer 1

The Finder is asking for password because you're trying to remove a file from a location that the user doesn't have delete privileges for.
One way to solve this would be to do the deletion via shell commands. Replace delete folder sourcefolder1 with:
do shell script ("rm -rf '" & posix path of sourcefolder1 & "'") ¬
with administrator privileges user name "username" password "password"
Then it won't ask at all. If you want it to ask once, remove everything from user name onward. It will remember the entry for the subsequent commands.
Update: per comment below, the need is to be able to move the item to the Trash rather than delete it outright as rm does. I couldn't think of any way to do it in straight AppleScript, because the administrator prompting is coming from the Finder, and AppleScript (as far as I know) can only perform a privileged action programmatically with the do shell script command. So I wrote a routine that should be equivalent to "Move To Trash" in the Finder:
to deleteItem(thisItem)
set thisItemPath to (POSIX path of thisItem)
set uid to (do shell script "id -u")
if thisItemPath starts with "/Volumes" then
set AppleScript's text item delimiters to "/"
set volName to text item 3 of thisItemPath
set AppleScript's text item delimiters to ""
set targetPath to ¬
("/Volumes/" & volName & "/.Trashes/" & uid)
else
set targetPath to ((POSIX path of (path to home folder)) & ".Trash")
end if
set moveToTrashCmd to ¬
("mkdir -p '" & targetPath & "'; " & ¬
"mv '" & thisItemPath & "' '" & targetPath & "'")
-- set global vars first for userName and password, or omit for prompt
do shell script moveToTrashCmd ¬
with administrator privileges user name userName password userPw
end if
end deleteItem
Here's a sample program that uses the routine:
global fileItems, userName, userPw
on run
set userPw to "password"
set AppleScript's text item delimiters to ":"
set userName to text item -2 of (path to home folder as string)
set AppleScript's text item delimiters to ""
try
fileItems
on error
set fileItems to ¬
(choose folder with prompt ¬
"Select folders to delete:" with multiple selections allowed)
end try
repeat with thisItem in fileItems
deleteItem(thisItem)
end repeat
end run
-- drag 'n' dropped files
on open docs
set fileItems to docs
run
end open

Answer 2

To prevent the password prompt pops up more than once : Use the delete command only once by putting all the folders or files in a list.
Like this:
set frmWKsList to {}
set librF to path to library folder as text
set end of frmWKsList to librF & "Frameworks:SDL.framework"
set end of frmWKsList to librF & "Frameworks:SDL_ttf.framework"
set end of frmWKsList to librF & "Frameworks:SDL_image.framework"
set foldersToDelete to {}
tell application "Finder"
repeat with i in frmWKsList
if exists folder i then set end of foldersToDelete to i as alias
end repeat
delete foldersToDelete
end tell