Multi-Row Function - oracle

Question

How to return a multi-row data from a function with cursor ?
Create or Replace function Get_Course_details(Stud_ID number)
return varchar2
Is
cursor C_1 is
select d.desc_english
from course_details d ,course_track c , students s
where D.COURSE_TRACK_ID = C.COURSE_TRACK_ID
and C.COURSE_TRACK_ID = s.STUDENT_ID
and s.student_ID=stud_ID;
cursor C_2 is
select count(d.desc_english)
from course_details d ,course_track c , students s
where D.COURSE_TRACK_ID = C.COURSE_TRACK_ID
and C.COURSE_TRACK_ID = s.STUDENT_ID
and s.student_ID=stud_ID;
var_1 varchar2(1000);
var_2 number;
Begin
open c_2;
fetch c_2
into var_2;
close c_2;
for x in (select d.desc_english
from course_details d ,course_track c , students s
where D.COURSE_TRACK_ID = C.COURSE_TRACK_ID
and C.COURSE_TRACK_ID = s.STUDENT_ID
and s.student_ID=stud_ID)
loop
open c_1;
fetch c_1
into var_1;
close c_1;
return var_1;
end loop;
end;

Answer 1

Okay, so as Justin pointed out there are few issues with your current function:
var_2 is never used.
You are trying to return multirow data, however, the function will return var_1 to the calling procedure on the very first iteration.
The below solution assumes you are trying to get an array of strings from a cursor that returns many rows. It is a generic demonstration, you will have modify it for you particular instance.
CREATE OR REPLACE FUNCTION string_array_from_cursor
RETURN dbms_sql.Varchar2_Table
IS
--Obviously this could be _ANY_ select query
CURSOR cursorToReturnManyRows IS
SELECT o.object_name
FROM user_objects o
WHERE o.OBJECT_TYPE = 'TABLE';
--This is an inbuilt index-by table (you could also use a varray,
-- associative array or nested table)
stringArray dbms_sql.Varchar2_Table;
BEGIN
--Use a FOR loop to iterate through the cursor,
-- at each iteration add the value as the next item in the array
FOR rec IN cursorToReturnManyRows LOOP
stringArray(stringArray.count + 1) := rec.object_name;
END LOOP;
--After the loop is complete return the array
RETURN stringArray;
END;
I suggest you compile the above function, and run it the below test window to see how it can apply to your instance.
DECLARE
stringArray dbms_sql.Varchar2_Table;
BEGIN
stringArray := string_array_from_cursor;
dbms_output.put_line(stringArray.count);
FOR i IN 1..stringArray.count LOOP
dbms_output.put_line(stringArray(i));
END LOOP;
END;

Answer 2

As an alternative you can return an opened SYS_REFCURSOR and let the caller fetch from the cursor:
CREATE OR REPLACE FUNCTION GET_COURSE_DETAIL_CURSOR(STUD_ID NUMBER)
RETURN SYS_REFCURSOR
IS
C_1 SYS_REFCURSOR;
BEGIN
OPEN C_1 FOR SELECT d.DESC_ENGLISH
FROM STUDENTS s
INNER JOIN COURSE_TRACK c
ON c.COURSE_TRACK_ID = s.STUDENT_ID
INNER JOIN COURSE_DETAILS d
ON d.COURSE_TRACK_ID = c.COURSE_TRACK_ID
WHERE S.STUDENT_ID = STUD_ID;
RETURN C_1;
END GET_COURSE_DETAIL_CURSOR;
The caller would, of course, be responsible for closing the cursor.
(And BTW - the join criteria c.COURSE_TRACK_ID = s.STUDENT_ID seems to be contradictory with the later join criteria d.COURSE_TRACK_ID = c.COURSE_TRACK_ID, but on the other hand I don't know your data. It just looks odd to me).
Share and enjoy.