Batch loop error - only 1 file is copied - windows

Question

I'm trying to run a bat file that:
creates a folder
searches for all files with .log extension
Copies and rename the files to MyFile_customString.log to another folder
So far I did this:
#echo off
set host_name=%1
set origin_path=%2
set destiny_path=%3
set destiny_host_path=%destiny_path%\%host_name%\
mkdir .\%destiny_host_path%
FOR %%G IN (%origin_path%/*.log) DO (
SET _fileName=%%G
SET _custom=%_fileName:.log=_%%host_name%.log%
xcopy /Y /F %origin_path%\%_fileName% %destiny_host_path%\%_custom%
)
And having MyTest.log and MyTest2.log files in origin_path only MyTest2.log file is copied to destiny_host_path
What am I missing?

Answer 1

You need SetLocal EnableDelayedExpansion at top of batch file after #echo
In your code:
FOR %%G IN (%origin_path%/*.log) DO (
SET _fileName=%%G
SET _custom=%_fileName:.log=_%%host_name%.log%
xcopy /Y /F %origin_path%\%_fileName% %destiny_host_path%\%_custom%
)
should be:
FOR %%G IN (%origin_path%/*.log) DO (
SET "_fileName=%%G"
FOR %%H in (!host_name!) Do (
SET "_custom=!_fileName:.log=_%%H.log!"
)
xcopy /Y /F !origin_path!\!_fileName! !destiny_host_path!\!_custom!
)

Answer 2

FOR %%G IN (%origin_path%\*.log) DO (
xcopy /Y /F "%origin_path%\%%G" "%destiny_host_path%\%%~nG_%host_name%.log"
)
(untested)
No need for delayedexpansion in this case.
See for /? |more from the prompt for information on the use of ~-modifiers to extract parts of filenames.
In your original, your %s were unbalanced (assuming that % had been correct in that context) in the set _custom line.
Tip: replace xcopy with echo xcopy temporarily to show rather than execute the command - easier to debug in case of an error...