Batch that convert TIMECODE to frame number - windows

Question

in a batch there is a envoroment variable called %timecode% that, if timecode exist and is defined, output a string of this type:
HH:MM:SS:FF
for example 01:32:21:05
In PAL mode, 25fps, I would like convert this timecode in his correspondant frame number, for rxample in the case of 01:32:21:05 is 138530
so the convert processing should output 138530
Another examples: 00:00:00:00 ----------------> 0
00:00:00:01 ----------------> 1
........
00:00:00:24 ----------------> 24
00:00:01:00 ----------------> 25
00:00:01:01 ----------------> 26
and so on
How can I do?

Answer 1

#echo off
setlocal enableextensions disabledelayedexpansion
set "frameRate=25"
set "timecode=01:32:21:05"
for /f "tokens=1-4 delims=:" %%a in (
"100%timecode::0=: %"
) do set /a "frame=((%%a %% 100)*3600 + (%%b0)*60/10 + (%%c0)/10) * %frameRate% + (%%d0)/10"
echo %frame%
This code splits the timecode variable contents using the colons as delimiters. To account for zero prefixed fields (considered in octal form and problematic in the case of 08 or 09), missing or bad formatted data, some "tricks" are used.
To correct the hour part, the input data is prefixed with 100 and this field will be handled modulo 100.
To handle the problematic zero prefixed fields, a colon followed by a zero in the input data is replaced with the same colon followed by a space.
To handle problems with missing fields, when doing the calcs all extracted data is suffixed with a zero (mutiplying it by 10) and the the result of the operation in this field is divided by 10

Answer 2

#ECHO Off
SETLOCAL
SET "timecode=01:32:21:05"
IF DEFINED timecode (
SET /a result=((1%timecode:~0,2%-100^) * 90000^) + ((1%timecode:~3,2%-100^) * 1500^) + ((1%timecode:~6,2%-100^) * 25^) + (1%timecode:~-2%-100^)
) ELSE (SET "result=NOT defined")
ECHO result with timecode="%timecode%" is %result%
SET "timecode="
IF DEFINED timecode (
SET /a result=((1%timecode:~0,2%-100^) * 90000^) + ((1%timecode:~3,2%-100^) * 1500^) + ((1%timecode:~6,2%-100^) * 25^) + (1%timecode:~-2%-100^)
) ELSE (SET "result=NOT defined")
ECHO result with timecode="%timecode%" is %result%
GOTO :EOF
This should point you to a solution.
Note that the carets (^) are only required before the ) because the set command is within a block. If you were to choose to goto a label if timecode was undefined, then the carets would not be required.
I've cosen to calculate the sum using a straight-forward method; prepending a 1 to the two digits, then subtracting 100 (which takes care of the 08/09 problem - a leading 0 is defined as octal and cmd will object to non-octal characters) The routine could be made simpler by the use of magic numbers, but that would require more explanation.