output the rows with one non-empty column in csv using bash - bash

Question

Given a csv file, I want to output only the rows with exactly one non-empty column.
input file
"a","b","c"
"d","",""
output:
"d","",""
Can this be done in bash?

Answer 1

A simpler awk solution can be
$ awk '/^("",)*"."(,"")*$/' inputFile
"d","",""
What it does
/^("",)*"."(,"")*$/ patterns matches as
("",) number of empty columns
"." followed by ONE non empty column
(,"") further followed by number of empty columns
no action specified, hence takes the default action to print the entire record
EDIT
If there are more than one letter in a column
$ awk '/^("",)*"[^"]+"(,"")*$/' input
"d","",""
Thanks to Jotne

Answer 2

You can use sed for this:
sed -n '/^[",]*[^",]*[",]*$/p' file
To make sure it does not match blank lines we can add the +:
sed -n '/^[",]*"[^",]\+"[",]*$/p' file
It returns:
"d","",""
It is a matter of checking if there is one, and just one, block characters different than " or , in between these characters. -n inhibits the printing, whereas p prints the lines that accomplish the condition.

Answer 3

You could use gsub() to count the number of times an empty field is found, then subtract from NF and test equal to one. Here's one way using GNU AWK and the FPAT variable:
awk 'BEGIN { FPAT = "([^,]+)|(\"[^\"]+\")" } NF - gsub(/""/, "&") == 1' file
If you don't have embedded commas, you could simply write:
awk -F, 'NF - gsub(/""/, "&") == 1' file

Answer 4

A simplistic approach which assumes that no fields in the CSV file contain commas:
awk -F '[",]+' '{n=0;for(i=2;i<NF;++i)$i~/^$/||++n}n==1' file.txt
Set the input field separator to one or more double quotes and commas. Loop through all of the fields, incrementing n for every non-empty field. If the total number is exactly 1, print the line.
The reason that the loop goes from field 2 to NF-1 is that the first and last field are before and after the parts that you are interested in.
Very similar but ever-so-slightly shorter:
awk -F ',' '{n=0;for(i=1;i<=NF;++i)$i~/""/||++n}n==1' file.txt
Use the comma as the field separator and increment n for any fields that contain "". In this case, the loop goes through each field.

Answer 5

Through sed.
$ sed -rn '/^(".[^"]*"(,"")*|""(,"")*,".[^"]*"(,"")*)$/p' file
"d","",""
First part ".[^"]*"(,"")* matches these type of string "A","","" where the second part ""(,"")*,".[^"]*"(,"")* would match these type of string formats "","","A"
Example:
$ cat file
"a","b","c"
"d","",""
"","","A"
"A","","A"
"","A",""
"","A","A"
"A","A",""
$ sed -rn '/^(".[^"]*"(,"")*|""(,"")*,".[^"]*"(,"")*)$/p' file
"d","",""
"","","A"
"","A",""

Answer 6

This grep should be able to handle this:
grep -E '^("",)*"[^"]+"(,"")*$' file
"d","",""

Answer 7

Just split the line into fields and count how many are non-empty:
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==1' file
"d","",""
The loop starts at 2 and ends at NF-1 because there's no point checking the empty fields that will always exist before the first and after the last "real" fields (i.e. before the ^" and after the "$) when the line is split using an FS that includes the start-of-string (^) and end-of-string ($) RE metacharacters.
If you ever wanted to check different counts of non-empty fields, just change the number you compare c to:
$ cat file
"a","b","c"
"d","",""
"e","","f"
"","",""
.
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==0' file
"","",""
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==1' file
"d","",""
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==2' file
"e","","f"
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==3' file
"a","b","c"
$ awk -F'^"|","|"$' '{c=0; for (i=2; i<NF; i++) if ($i != "") ++c} c==4' file
$