Applescript & Rules in Mail - applescript

Question

I'm trying to execute the following Applescript within a Rule I set up in Mac Mail. I'm running OS 10.10.1 Yosemite on my iMac. My Rule looks for a particular email I receive every day, then instructs Mail to execute my Applescript. The Rule works perfectly when I manually highlight the email and click on "Apply Rules"; however, when I start up my computer in the morning and receive my first mail of the day. The Applescript program gets caught in never ending loop, which is evidenced by the whirling icon that appears in the menu bar. BTW: My automator routine works perfectly. My thinking is that the Applescript gets confused trying to execute while Mail is downloading all my mail???? Any suggestions?? Oh, I'm a novice...Thx
tell application "System Events"
tell process "Mail"
-- Select the Print menu item
click (first menu item of menu "File" of menu bar 1 whose name begins with "Print")
tell window 1
-- Wait until the print sheet appears
repeat until sheet 1 exists
end repeat
tell sheet 1
-- Click the PDF button
click menu button "PDF"
-- Select the PDF to SBS Dropbox menu item
click (first menu item of menu 1 of menu button "PDF" whose name begins with "PDF to SBS Dropbox")
end tell
end tell
end tell
end tell

Answer 1

First you need to use the Applescript handler called by mail rules:
on perform mail action with messages theMessages for rule theRule
Inside this handler you have access to the mails that matched your mail rule conditions and do whatever you like. Here is the skeleton you can use to add your code:
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
tell application "Mail"
repeat with thisMessage in theMessages
-- place your code here
end repeat
end tell
end perform mail action with messages
end using terms from
In your special case I think we can try to put your code inside the repeat-loop and let mail open the mail before execution and close it after printing:
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
tell application "Mail"
-- walk through all matching messages
repeat with thisMessage in theMessages
-- open the message
set openedMail to open thisMessage
-- perform your UI scripting
tell application "System Events"
tell process "Mail"
-- Select the Print menu item
click (first menu item of menu "File" of menu bar 1 whose name begins with "Print")
tell window 1
-- Wait until the print sheet appears
repeat 30 times
if sheet 1 exists then exit repeat
delay 0.5
end repeat
tell sheet 1
-- Click the PDF button
click menu button "PDF"
-- Select the PDF to SBS Dropbox menu item
click (first menu item of menu 1 of menu button "PDF" whose name begins with "PDF to SBS Dropbox")
end tell
end tell
end tell
end tell
-- close the message
close openedMail
end repeat
end tell
end perform mail action with messages
end using terms from
It's not tested yet! And I prevent the script from running in an infinite loop when trying to access the print sheet now.
Give it a try! Enjoy, Michael / Hamburg