Pig grouping users while maintaining other fields - hadoop

Question

I guess this question is similar to this one:
Selecting fields after grouping in Pig
but here is my question for the following made up sample data:
user_name, movie_name, company, rating
Jim, Jaws, A, 4
Jim, Baseball, B, 4
Matt, Halo, A, 5
Matt, Baseball, B, 4
Matt, History of Chairs, B, 3.5
Pat, History of Chairs, B, 3
John, History of Chairs, B, 2
Frank, Battle Tanks, A, 3
Frank, History of Chairs, B, 5
How can I group together all movies a user has seen without losing the other information like company, and rating.
I want to add the cross of all ratings a user gave from movie company A and movie company B.
Jim, Jaws, Baseball, 8
Matt, Halo, Baseball, 9
Frank, Battle Tanks, History of Chairs, 8
would be the output in the format:
user, companyA, companyB, rating
I started with a load followed by
r1 = LOAD 'data.csv' USING PigStorage(',') as (user_name:chararray, movie_name:chararray, company_name:chararray, rating:int);
r2 = group r1 by user_name;
r3 = foreach r2 generate group as user_name, flatten(r1);
r4A = filter r3 by company_name == 'A';
r4B = filter r3 by company_name == 'B';
but then I have something like
(Frank,Frank,Battle Tanks,A,3)
I then plan to do a cross of r4A and r4B and sum of the ratings. But I'm not sure if the repeated user_name will increase the inefficiencies.
Is this the proper approach? Any ideas to make this better?
Any help would be appreciated!

Answer 1

Can you try this?
input:
Jim,Jaws,A,4
Jim,Baseball,B,4
Matt,Halo,A,5
Matt,Baseball,B,4
Matt,History of Chairs,B,3.5
Pat,History of Chairs,B,3
John,History of Chairs,B,2
Frank,Battle Tanks,A,3
Frank,History of Chairs,B,5
PigScript:
A = LOAD 'input' USING PigStorage(',') AS (user_name:chararray, movie_name:chararray, company:chararray, rating:float);
B = GROUP A BY user_name;
C = FOREACH B {
filterCompanyA = FILTER A BY company=='A';
sumA = SUM(filterCompanyA.rating);
filterCompanyB = FILTER A BY company=='B';
sumB = SUM(filterCompanyB.rating);
GENERATE group AS user,
FLATTEN(REPLACE(BagToString(filterCompanyA.movie_name),'_',',')) AS companyA,
FLATTEN(REPLACE(BagToString(filterCompanyB.movie_name),'_',',')) AS companyB,
(((sumA is null)?0:sumA)+((sumB is null)?0:sumB)) AS Rating;
}
D = FOREACH C GENERATE user,companyA,companyB,Rating;
DUMP D;
Output:
(Jim,Jaws,Baseball,8.0)
(Pat,,History of Chairs,3.0)
(John,,History of Chairs,2.0)
(Matt,Halo,Baseball,History of Chairs,12.5)
(Frank,Battle Tanks,History of Chairs,8.0)
In the above output Pat and John haven't seen any movie in the CompanyA, so that output is null ie empty