Comparing elements/arguments of facts in KB against each other in Prolog? - prolog

Question

This is the knowledge base that is being used.
localLib('AHorowitz', 'Stolen Gods', 2011, 'Scorpia Rising', 448, 4).
localLib('AHorowitz', 'Night Visitors', 2000, 'Stormbreaker', 240, 2).
localLib('AHorowitz', 'Matador', 2003, 'Eagle Strike', 340, 6).
localLib('AJohnston', 'Night Visitors', 2000, 'Stormbreaker', 240, 2).
localLib('AJohnston'’, 'Matador', 2003, 'Eagle Strike', 340, 6).
localLib('RMuchamore', 'Basic Training', 2007, 'The Recruit', 342, 3).
localLib('MHaddon', '11.', 2004, 'The Curious Incident Of The Dog In The Night Time', 226, 5).
The key for the KB is as follows:
localLib(w, e, y, t, n, c) where
w = writer’s name
e = excerpt in text
y = year of text
t = title of text
n = no. of pages in excerpt
c = no. of acknowledgements
I have to write a rule to find what is the number of pages for a single longest excerpt that a given writer has published?
Though I understand the question and what the final output should look like I am having difficulty translating it into Prolog language.
The code I have written below is the start of the rule as I am stuck:
longestexcerpt(W, E, N):- localLib(W,E,_,_,N,_), sort(N,X).
Effectively I understand that we have to make Prolog check each no of pages in excerpt against one another therefore it is like a sorting algorithm however the sort function we have learned in lectures so far only involve sorting number in lists. How would I make Prolog check each excerpt length by the same author, say 'AHorowitz', then make it display the highest one, in this case n=448 (as Stolen Gods is the longest number of pages out of all Horowitz texts).
Help and guidance how to approach these kinds of problems would be really useful!

Answer 1

The other solution is also fine, but you can also do it like this:
% The longest excerpt for an author
longest_excerpt(W, E, N) :-
localLib(W, E, _, _, N, _),
\+ (localLib(W, _, _, _, N1, _),
N < N1).
This reads as follows: "There is a writer W with and excerpt E with length N, and there is not an excerpt from the same writer with a greater length".
\+ here is the negation: read it as, "succeeds when the goal fails." Here, the goal is a conjunction.
From the top level:
?- longest_excerpt(W, E, N).
W = 'AHorowitz',
E = 'Stolen Gods',
N = 448 ;
W = 'AJohnston',
E = 'Matador',
N = 340 ;
W = 'RMuchamore',
E = 'Basic Training',
N = 342 ;
W = 'MHaddon',
E = '11.',
N = 226.
There is nothing wrong with using setof/3, of course.
As for the solution from #lurker, it seems better, even if a bit less "declarative". I would have written it as:
longest_excerpt_1(W, E, N) :-
setof(N0-E0, Y^T^C^localLib(W, E0, _, _, N0, _), R),
last(N-E, R).

Answer 2

As you may have already discovered, here's a predicate which simply will be true for any association of an writer, excerpt, and page count:
longestexcerpt(W, E, N) :- localLib(W,E,_,_,N,_).
If you wanted to collect all of the solutions in a list for a given writer, you could do this:
writer_excerpts(Writer, ExcerptList) :-
setof( E-N, Y^T^C^localLib(Writer, E, Y, T, N, C), ExcerptList ).
The existential quantifiers, Y^T^C^ indicate that we don't want these values in the results. OK, that's great. Now we have the entire list of excerpts (in ExcerptList) for Writer, and setof/3 will sort each element, E-N, in a "natural order" (which will be collated by the term E). That is, ExcerptList will be a list of elements that look like 'Stolen Gods'-448, etc. A sample output looks like this:
| ?- writer_excerpts('AHorowitz', E).
E = ['Matador'-340,'Night Visitors'-240,'Stolen Gods'-448]
yes
Since you want the largest number of pages, you really want them ordered by decreasing page count. So you can swap this around as N-E for the list elements, which gives the order by increasing page count, and then reverse the list:
writer_excerpts(Writer, ExcerptList) :-
setof( N-E, Y^T^C^localLib(Writer, E, Y, T, N, C), EList),
reverse(EList, ExcerptList).
This yields:
| ?- writer_excerpts('AHorowitz', E).
E = [448-'Stolen Gods',340-'Matador',240-'Night Visitors']
yes
And finally, you only need to pick off the first element of the result of this predicate:
writers_most_excerpt_pages(Writer, Excerpt, Pages) :-
setof( N-E, Y^T^C^localLib(Writer, E, Y, T, N, C), EList),
reverse(EList, [Pages-Excerpt|_]).
Here, we are unifying the sorted list inline with [Pages-Excerpt|_] since we only care about the Pages-Excerpt info for the first element. We don't care about the tail (rest) of the list, so we just use _.