predsort/3 unexpected behavior - sorting

Question

I have a problem sorting a list of tasks [t7, t1, t6, t2, t4, t3, t5] in Prolog. To sort this I want to use the predefined formula predsort/3 as it seems like the correct approach.
My custom predicate looks like this:
sort_dependency(<, T, T2) :-
depends_on(T,T2,_).
sort_dependency(>, T, T2) :-
depends_on(T2,T,_).
sort_dependency(>, T, T2) :-
T == T2;
not(depends_on(T,T2,_)),
not(depends_on(T2,T,_)).
When testing this I get the following:
?- predsort(sort_dependency, [t7, t1, t6, t2, t4, t3, t5], Sorted).
Sorted = [t5, t4, t3, t7, t2, t6, t1] .
This isn't correct. The correct answer should be something like [t1 , t2, t3, t4, t5, t6, t].
For testing purpose here are the facts of depends_on.
depends_on(t7,t2,0).
depends_on(t7,t6,0).
depends_on(t6,t4,0).
depends_on(t6,t5,0).
depends_on(t2,t1,0).
depends_on(t4,t3,0).
depends_on(t3,t1,0).
depends_on(t5,t3,0).
I tried switching different variables around be still can't get the expected result. Is keysort/2 a better option? Problem is I don't see how to implement keysort in combination with a custom predicate.

Answer 1

Topological sorting is what you actually want. There is top_sort/2 for this.
predsort/3 assumes a total order, but you can only provide a partial order.
In other words, predsort/3 will query your supplied comparison predicate. And it expects as answers <, = or >. So you have to produce one exact answers for all pairs of nodes. However, for some, (those that are incomparable) you cannot tell what the result should be. You can only guess, which will not produce a consistent total order.

Answer 2

I implemented the solution proposed by #false. The tasks are transformed to a graph, edges are set using depends_on and then we use top_sort/2 on the result.
Hope this is useful to some.
sort_tasks(ToSort, Sorted) :-
vertices_edges_to_ugraph(ToSort,[],Gr), %Gr is graph wiht nodes as the tasks
add_my_edges(Gr, ToSort, GrN),
top_sort(GrN,Sorted).
add_my_edges(Gr,[],Gr).
add_my_edges(Gr,[T|TR], GrReturn) :-
findall(X,depends_on(X,T,_),L), %L moet na T gebeuren
add_my_edge(Gr, T, L, GrN),
add_my_edges(GrN,TR,GrReturn).
add_my_edge(Gr, _,[], Gr).
add_my_edge(Gr, T, [LH|LR], GrReturn) :-
add_edges(Gr, [T-LH], GrN),
add_my_edge(GrN, T, LR, GrReturn).